game-data/plugins/Skript/scripts/economy.sk

command /balance [<player>]:
    aliases: /bal, /money
    trigger:
        if arg-1 is set:
            set {_target} to arg-1
        else:
            set {_target} to player
        set {_emeralds} to number of emeralds in {_target}'s inventory
        send "&8&m                              "
        send "&6&l$ &eBalance for &c%{_target}%"
        send "&7Emeralds: &a%{_emeralds}%"
        send "&8&m                              "

command /pay <player> <integer>:
    trigger:
        if arg-2 is less than 1:
            send "&cAmount must be at least 1!"
            stop
        if arg-1 is player:
            send "&cYou can't pay yourself!"
            stop
        set {_has} to number of emeralds in player's inventory
        if {_has} is less than arg-2:
            send "&cYou don't have enough emeralds!"
            stop
        remove arg-2 of emerald from player's inventory
        give arg-2 of emerald to arg-1
        send "&aSent &e%arg-2% emeralds &ato &e%arg-1%&a!"
        send "&a%player% &esent you &a%arg-2% emeralds&e!" to arg-1