// Tencent is pleased to support the open source community by making ncnn available.
//
// Copyright (C) 2020 THL A29 Limited, a Tencent company. All rights reserved.
//
// Licensed under the BSD 3-Clause License (the "License"); you may not use this file except
// in compliance with the License. You may obtain a copy of the License at
//
// https://opensource.org/licenses/BSD-3-Clause
//
// Unless required by applicable law or agreed to in writing, software distributed
// under the License is distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR
// CONDITIONS OF ANY KIND, either express or implied. See the License for the
// specific language governing permissions and limitations under the License.

#version 450

#if NCNN_fp16_storage
#extension GL_EXT_shader_16bit_storage: require
struct sfpvec8 { f16vec4 abcd; f16vec4 efgh; };
#endif
#if NCNN_fp16_arithmetic
#extension GL_EXT_shader_explicit_arithmetic_types_float16: require
#endif

layout (constant_id = 0) const int axis = 0;

#define shape_constant_id_offset 1
layout (constant_id = shape_constant_id_offset + 0) const int dims = 0;
layout (constant_id = shape_constant_id_offset + 1) const int w = 0;
layout (constant_id = shape_constant_id_offset + 2) const int h = 0;
layout (constant_id = shape_constant_id_offset + 3) const int d = 0;
layout (constant_id = shape_constant_id_offset + 4) const int c = 0;
layout (constant_id = shape_constant_id_offset + 5) const int cstep = 0;

layout (constant_id = shape_constant_id_offset + 6) const int outdims = 0;
layout (constant_id = shape_constant_id_offset + 7) const int outw = 0;
layout (constant_id = shape_constant_id_offset + 8) const int outh = 0;
layout (constant_id = shape_constant_id_offset + 9) const int outd = 0;
layout (constant_id = shape_constant_id_offset + 10) const int outc = 0;
layout (constant_id = shape_constant_id_offset + 11) const int outcstep = 0;

#if NCNN_image_shader
layout (binding = 0) uniform unfp sampler3D bottom_blob_3d;
layout (binding = 1, imfmtc1) writeonly uniform unfp image3D top_blob_3d;
#else
layout (binding = 0) readonly buffer bottom_blob { sfpvec8 bottom_blob_data[]; };
layout (binding = 1) writeonly buffer top_blob { sfp top_blob_data[]; };
#endif

layout (push_constant) uniform parameter
{
    int dims;
    int w;
    int h;
    int d;
    int c;
    int cstep;

    int outdims;
    int outw;
    int outh;
    int outd;
    int outc;
    int outcstep;

    int offset;
} p;

void main()
{
    int gx = int(gl_GlobalInvocationID.x);
    int gy = int(gl_GlobalInvocationID.y);
    int gz = int(gl_GlobalInvocationID.z);

    if (gx >= psc(w) || gy >= psc(h) * psc(d) || gz >= psc(c))
        return;

    int positive_axis = axis < 0 ? psc(dims) + axis : axis;

    ivec3 gxyz;

    if (psc(dims) == 4)
    {
        int yd = gy / psc(h);
        int yh = gy % psc(h);

        ivec4 gxydz = ivec4(gx, yh, yd, gz);
        gxydz[psc(dims) - 1] *= 8;
        gxydz[psc(dims) - 1 - positive_axis] += p.offset;

        gxyz = ivec3(gxydz.r, gxydz.g + gxydz.b * psc(outh), gxydz.a);
    }
    else
    {
        gxyz = ivec3(gx, gy, gz);
        gxyz[psc(dims) - 1] *= 8;
        gxyz[psc(dims) - 1 - positive_axis] += p.offset;
    }

#if NCNN_image_shader
    afpvec8 v = image3d_ld8(bottom_blob_3d, ivec3(gx, gy, gz));

    if (psc(dims) == 1)
    {
        image3d_st1(top_blob_3d, ivec3(gxyz.x + 0, 0, 0), v[0].r);
        image3d_st1(top_blob_3d, ivec3(gxyz.x + 1, 0, 0), v[0].g);
        image3d_st1(top_blob_3d, ivec3(gxyz.x + 2, 0, 0), v[0].b);
        image3d_st1(top_blob_3d, ivec3(gxyz.x + 3, 0, 0), v[0].a);
        image3d_st1(top_blob_3d, ivec3(gxyz.x + 4, 0, 0), v[1].r);
        image3d_st1(top_blob_3d, ivec3(gxyz.x + 5, 0, 0), v[1].g);
        image3d_st1(top_blob_3d, ivec3(gxyz.x + 6, 0, 0), v[1].b);
        image3d_st1(top_blob_3d, ivec3(gxyz.x + 7, 0, 0), v[1].a);
    }
    else if (psc(dims) == 2)
    {
        if (positive_axis == 0)
        {
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 0, 0), v[0].r);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 1, 0), v[0].g);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 2, 0), v[0].b);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 3, 0), v[0].a);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 4, 0), v[1].r);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 5, 0), v[1].g);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 6, 0), v[1].b);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 7, 0), v[1].a);
        }
        if (positive_axis == 1)
        {
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 0, gxyz.y, 0), v[0].r);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 1, gxyz.y, 0), v[0].g);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 2, gxyz.y, 0), v[0].b);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 3, gxyz.y, 0), v[0].a);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 4, gxyz.y, 0), v[1].r);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 5, gxyz.y, 0), v[1].g);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 6, gxyz.y, 0), v[1].b);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 7, gxyz.y, 0), v[1].a);
        }
    }
    else // if (psc(dims) == 3)
    {
        if (positive_axis == 0)
        {
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y, gxyz.z + 0), v[0].r);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y, gxyz.z + 1), v[0].g);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y, gxyz.z + 2), v[0].b);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y, gxyz.z + 3), v[0].a);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y, gxyz.z + 4), v[1].r);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y, gxyz.z + 5), v[1].g);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y, gxyz.z + 6), v[1].b);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y, gxyz.z + 7), v[1].a);
        }
        if (positive_axis == 1)
        {
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 0, gxyz.z), v[0].r);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 1, gxyz.z), v[0].g);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 2, gxyz.z), v[0].b);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 3, gxyz.z), v[0].a);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 4, gxyz.z), v[1].r);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 5, gxyz.z), v[1].g);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 6, gxyz.z), v[1].b);
            image3d_st1(top_blob_3d, ivec3(gxyz.x, gxyz.y + 7, gxyz.z), v[1].a);
        }
        if (positive_axis == 2)
        {
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 0, gxyz.y, gxyz.z), v[0].r);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 1, gxyz.y, gxyz.z), v[0].g);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 2, gxyz.y, gxyz.z), v[0].b);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 3, gxyz.y, gxyz.z), v[0].a);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 4, gxyz.y, gxyz.z), v[1].r);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 5, gxyz.y, gxyz.z), v[1].g);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 6, gxyz.y, gxyz.z), v[1].b);
            image3d_st1(top_blob_3d, ivec3(gxyz.x + 7, gxyz.y, gxyz.z), v[1].a);
        }
    }
#else
    const int gi = gz * psc(cstep) + gy * psc(w) + gx;

    int v_offset_0 = gxyz.z * psc(outcstep) + gxyz.y * psc(outw) + gxyz.x;

    ivec4 gxydz4;

    if (psc(dims) == 4)
    {
        gxydz4 = ivec4(1, psc(outw), psc(outw) * psc(outh), psc(outcstep));
    }
    else
    {
        gxydz4 = ivec4(1, psc(outw), psc(outcstep), 0);
    }

    ivec4 v_offset = v_offset_0 + ivec4(0, 1, 2, 3) * gxydz4[psc(dims) - 1 - positive_axis];
    ivec4 vv_offset = v_offset + 4 * gxydz4[psc(dims) - 1 - positive_axis];

    buffer_cp8to1(top_blob_data, v_offset, vv_offset, bottom_blob_data, gi);
#endif
}