Add files using upload-large-folder tool

.gitattributes

@@ -526,3 +526,5 @@ janus/lib/python3.10/site-packages/numpy/random/_bounded_integers.cpython-310-x8
 janus/lib/python3.10/lib-dynload/_codecs_tw.cpython-310-x86_64-linux-gnu.so filter=lfs diff=lfs merge=lfs -text
 janus/lib/ossl-modules/legacy.so filter=lfs diff=lfs merge=lfs -text
 janus/lib/python3.10/lib-dynload/_decimal.cpython-310-x86_64-linux-gnu.so filter=lfs diff=lfs merge=lfs -text
+janus/lib/sqlite3.44.2/libsqlite3.44.2.so filter=lfs diff=lfs merge=lfs -text
+janus/lib/itcl4.2.4/libitcl4.2.4.so filter=lfs diff=lfs merge=lfs -text

janus/lib/itcl4.2.4/libitcl4.2.4.so

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:b4dec209d072b6ea25863993f95c4fcf0023974e0d01d06a5705173db1313379
+size 318912

janus/lib/pkgconfig/python-3.10.pc

@@ -0,0 +1,13 @@
+# See: man pkg-config
+prefix=/root/envs/janus
+exec_prefix=${prefix}
+libdir=${exec_prefix}/lib
+includedir=${prefix}/include
+
+Name: Python
+Description: Build a C extension for Python
+Requires:
+Version: 3.10
+Libs.private: -lcrypt -lpthread -ldl  -lutil -lm
+Libs:
+Cflags: -I${includedir}/python3.10

janus/lib/sqlite3.44.2/libsqlite3.44.2.so

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:2ccfe88e9e8b573a4d312a3cf85f51de60783ab649a4ca9a4ae69b13c3f87ef1
+size 1596704

janus/lib/tk8.6/demos/aniwave.tcl

@@ -0,0 +1,104 @@
+# aniwave.tcl --
+#
+# This demonstration script illustrates how to adjust canvas item
+# coordinates in a way that does something fairly similar to waveform
+# display.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .aniwave
+catch {destroy $w}
+toplevel $w
+wm title $w "Animated Wave Demonstration"
+wm iconname $w "aniwave"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "This demonstration contains a canvas widget with a line item inside it. The animation routines work by adjusting the coordinates list of the line; a trace on a variable is used so updates to the variable result in a change of position of the line."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+# Create a canvas large enough to hold the wave. In fact, the wave
+# sticks off both sides of the canvas to prevent visual glitches.
+pack [canvas $w.c -width 300 -height 200 -background black] -padx 10 -pady 10 -expand yes
+
+# Ensure that this this is an array
+array set animationCallbacks {}
+
+# Creates a coordinates list of a wave. This code does a very sketchy
+# job and relies on Tk's line smoothing to make things look better.
+set waveCoords {}
+for {set x -10} {$x<=300} {incr x 5} {
+    lappend waveCoords $x 100
+}
+lappend waveCoords $x 0 [incr x 5] 200
+
+# Create a smoothed line and arrange for its coordinates to be the
+# contents of the variable waveCoords.
+$w.c create line $waveCoords -tags wave -width 1 -fill green -smooth 1
+proc waveCoordsTracer {w args} {
+    global waveCoords
+    # Actual visual update will wait until we have finished
+    # processing; Tk does that for us automatically.
+    $w.c coords wave $waveCoords
+}
+trace add variable waveCoords write [list waveCoordsTracer $w]
+
+# Basic motion handler. Given what direction the wave is travelling
+# in, it advances the y coordinates in the coordinate-list one step in
+# that direction.
+proc basicMotion {} {
+    global waveCoords direction
+    set oc $waveCoords
+    for {set i 1} {$i<[llength $oc]} {incr i 2} {
+	if {$direction eq "left"} {
+	    lset waveCoords $i [lindex $oc \
+		    [expr {$i+2>[llength $oc] ? 1 : $i+2}]]
+	} else {
+	    lset waveCoords $i \
+		    [lindex $oc [expr {$i-2<0 ? "end" : $i-2}]]
+	}
+    }
+}
+
+# Oscillation handler. This detects whether to reverse the direction
+# of the wave by checking to see if the peak of the wave has moved off
+# the screen (whose size we know already.)
+proc reverser {} {
+    global waveCoords direction
+    if {[lindex $waveCoords 1] < 10} {
+	set direction "right"
+    } elseif {[lindex $waveCoords end] < 10} {
+	set direction "left"
+    }
+}
+
+# Main animation "loop". This calls the two procedures that handle the
+# movement repeatedly by scheduling asynchronous calls back to itself
+# using the [after] command. This procedure is the fundamental basis
+# for all animated effect handling in Tk.
+proc move {} {
+    basicMotion
+    reverser
+
+    # Theoretically 100 frames-per-second (==10ms between frames)
+    global animationCallbacks
+    set animationCallbacks(simpleWave) [after 10 move]
+}
+
+# Initialise our remaining animation variables
+set direction "left"
+set animateAfterCallback {}
+# Arrange for the animation loop to stop when the canvas is deleted
+bind $w.c <Destroy> {
+    after cancel $animationCallbacks(simpleWave)
+    unset animationCallbacks(simpleWave)
+}
+# Start the animation processing
+move

janus/lib/tk8.6/demos/arrow.tcl

@@ -0,0 +1,241 @@
+# arrow.tcl --
+#
+# This demonstration script creates a canvas widget that displays a
+# large line with an arrowhead whose shape can be edited interactively.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+# arrowSetup --
+# This procedure regenerates all the text and graphics in the canvas
+# window.  It's called when the canvas is initially created, and also
+# whenever any of the parameters of the arrow head are changed
+# interactively.
+#
+# Arguments:
+# c -		Name of the canvas widget.
+
+proc arrowSetup c {
+    upvar #0 demo_arrowInfo v
+
+    # Remember the current box, if there is one.
+
+    set tags [$c gettags current]
+    if {$tags != ""} {
+	set cur [lindex $tags [lsearch -glob $tags box?]]
+    } else {
+	set cur ""
+    }
+
+    # Create the arrow and outline.
+
+    $c delete all
+    eval {$c create line $v(x1) $v(y) $v(x2) $v(y)  -arrow last \
+	    -width [expr {10*$v(width)}] -arrowshape [list \
+	    [expr {10*$v(a)}] [expr {10*$v(b)}] [expr {10*$v(c)}]]} \
+	    $v(bigLineStyle)
+    set xtip [expr {$v(x2)-10*$v(b)}]
+    set deltaY [expr {10*$v(c)+5*$v(width)}]
+    $c create line $v(x2) $v(y) $xtip [expr {$v(y)+$deltaY}] \
+	    [expr {$v(x2)-10*$v(a)}] $v(y) $xtip [expr {$v(y)-$deltaY}] \
+	    $v(x2) $v(y) -width 2 -capstyle round -joinstyle round
+
+    # Create the boxes for reshaping the line and arrowhead.
+
+    eval {$c create rect [expr {$v(x2)-10*$v(a)-5}] [expr {$v(y)-5}] \
+	    [expr {$v(x2)-10*$v(a)+5}] [expr {$v(y)+5}] \
+	    -tags {box1 box}} $v(boxStyle)
+    eval {$c create rect [expr {$xtip-5}] [expr {$v(y)-$deltaY-5}] \
+	    [expr {$xtip+5}] [expr {$v(y)-$deltaY+5}] \
+	    -tags {box2 box}} $v(boxStyle)
+    eval {$c create rect [expr {$v(x1)-5}] [expr {$v(y)-5*$v(width)-5}] \
+	    [expr {$v(x1)+5}] [expr {$v(y)-5*$v(width)+5}] \
+	    -tags {box3 box}} $v(boxStyle)
+    if {$cur != ""} {
+	eval $c itemconfigure $cur $v(activeStyle)
+    }
+
+    # Create three arrows in actual size with the same parameters
+
+    $c create line [expr {$v(x2)+50}] 0 [expr {$v(x2)+50}] 1000 \
+	    -width 2
+    set tmp [expr {$v(x2)+100}]
+    $c create line $tmp [expr {$v(y)-125}] $tmp [expr {$v(y)-75}] \
+	    -width $v(width) \
+	    -arrow both -arrowshape "$v(a) $v(b) $v(c)"
+    $c create line [expr {$tmp-25}] $v(y) [expr {$tmp+25}] $v(y) \
+	    -width $v(width) \
+	    -arrow both -arrowshape "$v(a) $v(b) $v(c)"
+    $c create line [expr {$tmp-25}] [expr {$v(y)+75}] [expr {$tmp+25}] \
+	    [expr {$v(y)+125}] -width $v(width) \
+	    -arrow both -arrowshape "$v(a) $v(b) $v(c)"
+
+    # Create a bunch of other arrows and text items showing the
+    # current dimensions.
+
+    set tmp [expr {$v(x2)+10}]
+    $c create line $tmp [expr {$v(y)-5*$v(width)}] \
+	    $tmp [expr {$v(y)-$deltaY}] \
+	    -arrow both -arrowshape $v(smallTips)
+    $c create text [expr {$v(x2)+15}] [expr {$v(y)-$deltaY+5*$v(c)}] \
+	    -text $v(c) -anchor w
+    set tmp [expr {$v(x1)-10}]
+    $c create line $tmp [expr {$v(y)-5*$v(width)}] \
+	    $tmp [expr {$v(y)+5*$v(width)}] \
+	    -arrow both -arrowshape $v(smallTips)
+    $c create text [expr {$v(x1)-15}] $v(y) -text $v(width) -anchor e
+    set tmp [expr {$v(y)+5*$v(width)+10*$v(c)+10}]
+    $c create line [expr {$v(x2)-10*$v(a)}] $tmp $v(x2) $tmp \
+	    -arrow both -arrowshape $v(smallTips)
+    $c create text [expr {$v(x2)-5*$v(a)}] [expr {$tmp+5}] \
+	    -text $v(a) -anchor n
+    set tmp [expr {$tmp+25}]
+    $c create line [expr {$v(x2)-10*$v(b)}] $tmp $v(x2) $tmp \
+	    -arrow both -arrowshape $v(smallTips)
+    $c create text [expr {$v(x2)-5*$v(b)}] [expr {$tmp+5}] \
+	    -text $v(b) -anchor n
+
+    $c create text $v(x1) 310 -text "-width  $v(width)" \
+	    -anchor w -font {Helvetica 18}
+    $c create text $v(x1) 330 -text "-arrowshape  {$v(a)  $v(b)  $v(c)}" \
+	    -anchor w -font {Helvetica 18}
+
+    incr v(count)
+}
+
+set w .arrow
+catch {destroy $w}
+toplevel $w
+wm title $w "Arrowhead Editor Demonstration"
+wm iconname $w "arrow"
+positionWindow $w
+set c $w.c
+
+label $w.msg -font $font -wraplength 5i -justify left -text "This widget allows you to experiment with different widths and arrowhead shapes for lines in canvases.  To change the line width or the shape of the arrowhead, drag any of the three boxes attached to the oversized arrow.  The arrows on the right give examples at normal scale.  The text at the bottom shows the configuration options as you'd enter them for a canvas line item."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+canvas $c -width 500 -height 350 -relief sunken -borderwidth 2
+pack $c -expand yes -fill both
+
+set demo_arrowInfo(a) 8
+set demo_arrowInfo(b) 10
+set demo_arrowInfo(c) 3
+set demo_arrowInfo(width) 2
+set demo_arrowInfo(motionProc) arrowMoveNull
+set demo_arrowInfo(x1) 40
+set demo_arrowInfo(x2) 350
+set demo_arrowInfo(y) 150
+set demo_arrowInfo(smallTips) {5 5 2}
+set demo_arrowInfo(count) 0
+if {[winfo depth $c] > 1} {
+    if {[tk windowingsystem] eq "aqua"} {
+	set demo_arrowInfo(bigLineStyle) "-fill systemSelectedTextBackgroundColor"
+    } else {
+	set demo_arrowInfo(bigLineStyle) "-fill LightSeaGreen"
+    }
+    set demo_arrowInfo(boxStyle) "-fill {} -width 1"
+    set demo_arrowInfo(activeStyle) "-fill red -width 1"
+} else {
+    # Main widget program sets variable tk_demoDirectory
+    set demo_arrowInfo(bigLineStyle) "-fill black \
+	-stipple @[file join $tk_demoDirectory images grey.25]"
+    set demo_arrowInfo(boxStyle) "-fill {} -outline black -width 1"
+    set demo_arrowInfo(activeStyle) "-fill black -outline black -width 1"
+}
+arrowSetup $c
+$c bind box <Enter> "$c itemconfigure current $demo_arrowInfo(activeStyle)"
+$c bind box <Leave> "$c itemconfigure current $demo_arrowInfo(boxStyle)"
+$c bind box <B1-Enter> " "
+$c bind box <B1-Leave> " "
+$c bind box1 <Button-1> {set demo_arrowInfo(motionProc) arrowMove1}
+$c bind box2 <Button-1> {set demo_arrowInfo(motionProc) arrowMove2}
+$c bind box3 <Button-1> {set demo_arrowInfo(motionProc) arrowMove3}
+$c bind box <B1-Motion> "\$demo_arrowInfo(motionProc) $c %x %y"
+bind $c <ButtonRelease-1> "arrowSetup $c"
+
+# arrowMove1 --
+# This procedure is called for each mouse motion event on box1 (the
+# one at the vertex of the arrow).  It updates the controlling parameters
+# for the line and arrowhead.
+#
+# Arguments:
+# c -		The name of the canvas window.
+# x, y -	The coordinates of the mouse.
+
+proc arrowMove1 {c x y} {
+    upvar #0 demo_arrowInfo v
+    set newA [expr {($v(x2)+5-round([$c canvasx $x]))/10}]
+    if {$newA < 0} {
+	set newA 0
+    }
+    if {$newA > 25} {
+	set newA 25
+    }
+    if {$newA != $v(a)} {
+	$c move box1 [expr {10*($v(a)-$newA)}] 0
+	set v(a) $newA
+    }
+}
+
+# arrowMove2 --
+# This procedure is called for each mouse motion event on box2 (the
+# one at the trailing tip of the arrowhead).  It updates the controlling
+# parameters for the line and arrowhead.
+#
+# Arguments:
+# c -		The name of the canvas window.
+# x, y -	The coordinates of the mouse.
+
+proc arrowMove2 {c x y} {
+    upvar #0 demo_arrowInfo v
+    set newB [expr {($v(x2)+5-round([$c canvasx $x]))/10}]
+    if {$newB < 0} {
+	set newB 0
+    }
+    if {$newB > 25} {
+	set newB 25
+    }
+    set newC [expr {($v(y)+5-round([$c canvasy $y])-5*$v(width))/10}]
+    if {$newC < 0} {
+	set newC 0
+    }
+    if {$newC > 20} {
+	set newC 20
+    }
+    if {($newB != $v(b)) || ($newC != $v(c))} {
+	$c move box2 [expr {10*($v(b)-$newB)}] [expr {10*($v(c)-$newC)}]
+	set v(b) $newB
+	set v(c) $newC
+    }
+}
+
+# arrowMove3 --
+# This procedure is called for each mouse motion event on box3 (the
+# one that controls the thickness of the line).  It updates the
+# controlling parameters for the line and arrowhead.
+#
+# Arguments:
+# c -		The name of the canvas window.
+# x, y -	The coordinates of the mouse.
+
+proc arrowMove3 {c x y} {
+    upvar #0 demo_arrowInfo v
+    set newWidth [expr {($v(y)+2-round([$c canvasy $y]))/5}]
+    if {$newWidth < 0} {
+	set newWidth 0
+    }
+    if {$newWidth > 20} {
+	set newWidth 20
+    }
+    if {$newWidth != $v(width)} {
+	$c move box3 0 [expr {5*($v(width)-$newWidth)}]
+	set v(width) $newWidth
+    }
+}

janus/lib/tk8.6/demos/bind.tcl

@@ -0,0 +1,78 @@
+# bind.tcl --
+#
+# This demonstration script creates a text widget with bindings set
+# up for hypertext-like effects.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .bind
+catch {destroy $w}
+toplevel $w
+wm title $w "Text Demonstration - Tag Bindings"
+wm iconname $w "bind"
+positionWindow $w
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+text $w.text -yscrollcommand "$w.scroll set" -setgrid true \
+	-width 60 -height 24 -font $font -wrap word
+ttk::scrollbar $w.scroll -command "$w.text yview"
+pack $w.scroll -side right -fill y
+pack $w.text -expand yes -fill both
+
+# Set up display styles.
+
+if {[winfo depth $w] > 1} {
+    set bold "-background #43ce80 -relief raised -borderwidth 1"
+    set normal "-background {} -relief flat"
+} else {
+    set bold "-foreground white -background black"
+    set normal "-foreground {} -background {}"
+}
+
+# Add text to widget.
+
+$w.text insert 0.0 {\
+The same tag mechanism that controls display styles in text widgets can also be used to associate Tcl commands with regions of text, so that mouse or keyboard actions on the text cause particular Tcl commands to be invoked.  For example, in the text below the descriptions of the canvas demonstrations have been tagged.  When you move the mouse over a demo description the description lights up, and when you press button 1 over a description then that particular demonstration is invoked.
+
+}
+$w.text insert end \
+{1. Samples of all the different types of items that can be created in canvas widgets.} d1
+$w.text insert end \n\n
+$w.text insert end \
+{2. A simple two-dimensional plot that allows you to adjust the positions of the data points.} d2
+$w.text insert end \n\n
+$w.text insert end \
+{3. Anchoring and justification modes for text items.} d3
+$w.text insert end \n\n
+$w.text insert end \
+{4. An editor for arrow-head shapes for line items.} d4
+$w.text insert end \n\n
+$w.text insert end \
+{5. A ruler with facilities for editing tab stops.} d5
+$w.text insert end \n\n
+$w.text insert end \
+{6. A grid that demonstrates how canvases can be scrolled.} d6
+
+# Create bindings for tags.
+
+foreach tag {d1 d2 d3 d4 d5 d6} {
+    $w.text tag bind $tag <Enter> "$w.text tag configure $tag $bold"
+    $w.text tag bind $tag <Leave> "$w.text tag configure $tag $normal"
+}
+# Main widget program sets variable tk_demoDirectory
+$w.text tag bind d1 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory items.tcl]}
+$w.text tag bind d2 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory plot.tcl]}
+$w.text tag bind d3 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory ctext.tcl]}
+$w.text tag bind d4 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory arrow.tcl]}
+$w.text tag bind d5 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory ruler.tcl]}
+$w.text tag bind d6 <Button-1> {source -encoding utf-8 [file join $tk_demoDirectory cscroll.tcl]}
+
+$w.text mark set insert 0.0
+$w.text configure -state disabled

janus/lib/tk8.6/demos/bitmap.tcl

@@ -0,0 +1,52 @@
+# bitmap.tcl --
+#
+# This demonstration script creates a toplevel window that displays
+# all of Tk's built-in bitmaps.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+# bitmapRow --
+# Create a row of bitmap items in a window.
+#
+# Arguments:
+# w -		The window that is to contain the row.
+# args -	The names of one or more bitmaps, which will be displayed
+#		in a new row across the bottom of w along with their
+#		names.
+
+proc bitmapRow {w args} {
+    frame $w
+    pack $w -side top -fill both
+    set i 0
+    foreach bitmap $args {
+	frame $w.$i
+	pack $w.$i -side left -fill both -pady .25c -padx .25c
+	label $w.$i.bitmap -bitmap $bitmap
+	label $w.$i.label -text $bitmap -width 9
+	pack $w.$i.label $w.$i.bitmap -side bottom
+	incr i
+    }
+}
+
+set w .bitmap
+catch {destroy $w}
+toplevel $w
+wm title $w "Bitmap Demonstration"
+wm iconname $w "bitmap"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "This window displays all of Tk's built-in bitmaps, along with the names you can use for them in Tcl scripts."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+frame $w.frame
+bitmapRow $w.frame.0 error gray12 gray25 gray50 gray75
+bitmapRow $w.frame.1 hourglass info question questhead warning
+pack $w.frame -side top -expand yes -fill both

janus/lib/tk8.6/demos/browse

@@ -0,0 +1,66 @@
+#!/bin/sh
+# the next line restarts using wish \
+exec wish8.6 "$0" ${1+"$@"}
+
+# browse --
+# This script generates a directory browser, which lists the working
+# directory and allows you to open files or subdirectories by
+# double-clicking.
+
+package require Tk
+
+# Create a scrollbar on the right side of the main window and a listbox
+# on the left side.
+
+scrollbar .scroll -command ".list yview"
+pack .scroll -side right -fill y
+listbox .list -yscroll ".scroll set" -relief sunken -width 20 -height 20 \
+	-setgrid yes
+pack .list -side left -fill both -expand yes
+wm minsize . 1 1
+
+# The procedure below is invoked to open a browser on a given file;  if the
+# file is a directory then another instance of this program is invoked; if
+# the file is a regular file then the Mx editor is invoked to display
+# the file.
+
+set browseScript [file join [pwd] $argv0]
+proc browse {dir file} {
+    global env browseScript
+    if {[string compare $dir "."] != 0} {set file $dir/$file}
+    switch [file type $file] {
+	directory {
+	    exec [info nameofexecutable] $browseScript $file &
+	}
+	file {
+	    if {[info exists env(EDITOR)]} {
+		eval exec $env(EDITOR) $file &
+	    } else {
+		exec xedit $file &
+	    }
+	}
+	default {
+	    puts stdout "\"$file\" isn't a directory or regular file"
+	}
+    }
+}
+
+# Fill the listbox with a list of all the files in the directory.
+
+if {$argc>0} {set dir [lindex $argv 0]} else {set dir "."}
+foreach i [lsort [glob * .* *.*]] {
+    if {[file type $i] eq "directory"} {
+	# Safe to do since it is still a directory.
+	append i /
+    }
+    .list insert end $i
+}
+
+# Set up bindings for the browser.
+
+bind all <Control-c> {destroy .}
+bind .list <Double-Button-1> {foreach i [selection get] {browse $dir $i}}
+
+# Local Variables:
+# mode: tcl
+# End:

janus/lib/tk8.6/demos/check.tcl

@@ -0,0 +1,71 @@
+# check.tcl --
+#
+# This demonstration script creates a toplevel window containing
+# several checkbuttons.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .check
+catch {destroy $w}
+toplevel $w
+wm title $w "Checkbutton Demonstration"
+wm iconname $w "check"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "Four checkbuttons are displayed below.  If you click on a button, it will toggle the button's selection state and set a Tcl variable to a value indicating the state of the checkbutton.  The first button also follows the state of the other three.  If only some of the three are checked, the first button will display the tri-state mode. Click the \"See Variables\" button to see the current values of the variables."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w [list safety wipers brakes sober]]
+pack $btns -side bottom -fill x
+
+checkbutton $w.b0 -text "Safety Check" -variable safety -relief flat \
+    -onvalue "all" \
+    -offvalue "none" \
+    -tristatevalue "partial"
+checkbutton $w.b1 -text "Wipers OK" -variable wipers -relief flat
+checkbutton $w.b2 -text "Brakes OK" -variable brakes -relief flat
+checkbutton $w.b3 -text "Driver Sober" -variable sober -relief flat
+pack $w.b0 -side top -pady 2 -anchor w
+pack $w.b1 $w.b2 $w.b3 -side top -pady 2 -anchor w -padx 15
+
+## This code makes $w.b0 function as a tri-state button; it's not
+## needed at all for just straight yes/no buttons.
+
+set in_check 0
+proc tristate_check {n1 n2 op} {
+    global safety wipers brakes sober in_check
+    if {$in_check} {
+	return
+    }
+    set in_check 1
+    if {$n1 eq "safety"} {
+	if {$safety eq "none"} {
+	    set wipers 0
+	    set brakes 0
+	    set sober 0
+	} elseif {$safety eq "all"} {
+	    set wipers 1
+	    set brakes 1
+	    set sober 1
+	}
+    } else {
+	if {$wipers == 1 && $brakes == 1 && $sober == 1} {
+	    set safety all
+	} elseif {$wipers == 1 || $brakes == 1 || $sober == 1} {
+	    set safety partial
+	} else {
+	    set safety none
+	}
+    }
+    set in_check 0
+}
+
+trace add variable wipers write tristate_check
+trace add variable brakes write tristate_check
+trace add variable sober  write tristate_check
+trace add variable safety write tristate_check

janus/lib/tk8.6/demos/colors.tcl

@@ -0,0 +1,99 @@
+# colors.tcl --
+#
+# This demonstration script creates a listbox widget that displays
+# many of the colors from the X color database.  You can click on
+# a color to change the application's palette.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .colors
+catch {destroy $w}
+toplevel $w
+wm title $w "Listbox Demonstration (colors)"
+wm iconname $w "Listbox"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "A listbox containing several color names is displayed below, along with a scrollbar.  You can scan the list either using the scrollbar or by dragging in the listbox window with button 2 pressed.  If you double-click button 1 on a color, then the application's color palette will be set to match that color"
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+frame $w.frame -borderwidth 10
+pack $w.frame -side top -expand yes -fill y
+
+scrollbar $w.frame.scroll -command "$w.frame.list yview"
+listbox $w.frame.list -yscroll "$w.frame.scroll set" \
+	-width 20 -height 16 -setgrid 1
+pack $w.frame.list $w.frame.scroll -side left -fill y -expand 1
+
+bind $w.frame.list <Double-Button-1> {
+    tk_setPalette [selection get]
+}
+$w.frame.list insert 0 gray60 gray70 gray80 gray85 gray90 gray95 \
+    snow1 snow2 snow3 snow4 seashell1 seashell2 \
+    seashell3 seashell4 AntiqueWhite1 AntiqueWhite2 AntiqueWhite3 \
+    AntiqueWhite4 bisque1 bisque2 bisque3 bisque4 PeachPuff1 \
+    PeachPuff2 PeachPuff3 PeachPuff4 NavajoWhite1 NavajoWhite2 \
+    NavajoWhite3 NavajoWhite4 LemonChiffon1 LemonChiffon2 \
+    LemonChiffon3 LemonChiffon4 cornsilk1 cornsilk2 cornsilk3 \
+    cornsilk4 ivory1 ivory2 ivory3 ivory4 honeydew1 honeydew2 \
+    honeydew3 honeydew4 LavenderBlush1 LavenderBlush2 \
+    LavenderBlush3 LavenderBlush4 MistyRose1 MistyRose2 \
+    MistyRose3 MistyRose4 azure1 azure2 azure3 azure4 \
+    SlateBlue1 SlateBlue2 SlateBlue3 SlateBlue4 RoyalBlue1 \
+    RoyalBlue2 RoyalBlue3 RoyalBlue4 blue1 blue2 blue3 blue4 \
+    DodgerBlue1 DodgerBlue2 DodgerBlue3 DodgerBlue4 SteelBlue1 \
+    SteelBlue2 SteelBlue3 SteelBlue4 DeepSkyBlue1 DeepSkyBlue2 \
+    DeepSkyBlue3 DeepSkyBlue4 SkyBlue1 SkyBlue2 SkyBlue3 \
+    SkyBlue4 LightSkyBlue1 LightSkyBlue2 LightSkyBlue3 \
+    LightSkyBlue4 SlateGray1 SlateGray2 SlateGray3 SlateGray4 \
+    LightSteelBlue1 LightSteelBlue2 LightSteelBlue3 \
+    LightSteelBlue4 LightBlue1 LightBlue2 LightBlue3 \
+    LightBlue4 LightCyan1 LightCyan2 LightCyan3 LightCyan4 \
+    PaleTurquoise1 PaleTurquoise2 PaleTurquoise3 PaleTurquoise4 \
+    CadetBlue1 CadetBlue2 CadetBlue3 CadetBlue4 turquoise1 \
+    turquoise2 turquoise3 turquoise4 cyan1 cyan2 cyan3 cyan4 \
+    DarkSlateGray1 DarkSlateGray2 DarkSlateGray3 \
+    DarkSlateGray4 aquamarine1 aquamarine2 aquamarine3 \
+    aquamarine4 DarkSeaGreen1 DarkSeaGreen2 DarkSeaGreen3 \
+    DarkSeaGreen4 SeaGreen1 SeaGreen2 SeaGreen3 SeaGreen4 \
+    PaleGreen1 PaleGreen2 PaleGreen3 PaleGreen4 SpringGreen1 \
+    SpringGreen2 SpringGreen3 SpringGreen4 green1 green2 \
+    green3 green4 chartreuse1 chartreuse2 chartreuse3 \
+    chartreuse4 OliveDrab1 OliveDrab2 OliveDrab3 OliveDrab4 \
+    DarkOliveGreen1 DarkOliveGreen2 DarkOliveGreen3 \
+    DarkOliveGreen4 khaki1 khaki2 khaki3 khaki4 \
+    LightGoldenrod1 LightGoldenrod2 LightGoldenrod3 \
+    LightGoldenrod4 LightYellow1 LightYellow2 LightYellow3 \
+    LightYellow4 yellow1 yellow2 yellow3 yellow4 gold1 gold2 \
+    gold3 gold4 goldenrod1 goldenrod2 goldenrod3 goldenrod4 \
+    DarkGoldenrod1 DarkGoldenrod2 DarkGoldenrod3 DarkGoldenrod4 \
+    RosyBrown1 RosyBrown2 RosyBrown3 RosyBrown4 IndianRed1 \
+    IndianRed2 IndianRed3 IndianRed4 sienna1 sienna2 sienna3 \
+    sienna4 burlywood1 burlywood2 burlywood3 burlywood4 wheat1 \
+    wheat2 wheat3 wheat4 tan1 tan2 tan3 tan4 chocolate1 \
+    chocolate2 chocolate3 chocolate4 firebrick1 firebrick2 \
+    firebrick3 firebrick4 brown1 brown2 brown3 brown4 salmon1 \
+    salmon2 salmon3 salmon4 LightSalmon1 LightSalmon2 \
+    LightSalmon3 LightSalmon4 orange1 orange2 orange3 orange4 \
+    DarkOrange1 DarkOrange2 DarkOrange3 DarkOrange4 coral1 \
+    coral2 coral3 coral4 tomato1 tomato2 tomato3 tomato4 \
+    OrangeRed1 OrangeRed2 OrangeRed3 OrangeRed4 red1 red2 red3 \
+    red4 DeepPink1 DeepPink2 DeepPink3 DeepPink4 HotPink1 \
+    HotPink2 HotPink3 HotPink4 pink1 pink2 pink3 pink4 \
+    LightPink1 LightPink2 LightPink3 LightPink4 PaleVioletRed1 \
+    PaleVioletRed2 PaleVioletRed3 PaleVioletRed4 maroon1 \
+    maroon2 maroon3 maroon4 VioletRed1 VioletRed2 VioletRed3 \
+    VioletRed4 magenta1 magenta2 magenta3 magenta4 orchid1 \
+    orchid2 orchid3 orchid4 plum1 plum2 plum3 plum4 \
+    MediumOrchid1 MediumOrchid2 MediumOrchid3 MediumOrchid4 \
+    DarkOrchid1 DarkOrchid2 DarkOrchid3 DarkOrchid4 purple1 \
+    purple2 purple3 purple4 MediumPurple1 MediumPurple2 \
+    MediumPurple3 MediumPurple4 thistle1 thistle2 thistle3 \
+    thistle4

janus/lib/tk8.6/demos/combo.tcl

@@ -0,0 +1,61 @@
+# combo.tcl --
+#
+# This demonstration script creates several combobox widgets.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .combo
+catch {destroy $w}
+toplevel $w
+wm title $w "Combobox Demonstration"
+wm iconname $w "combo"
+positionWindow $w
+
+ttk::label $w.msg -font $font -wraplength 5i -justify left -text "Three different\
+	combo-boxes are displayed below. You can add characters to the first\
+	one by pointing, clicking and typing, just as with an entry; pressing\
+	Return will cause the current value to be added to the list that is\
+	selectable from the drop-down list, and you can choose other values\
+	by pressing the Down key, using the arrow keys to pick another one,\
+	and pressing Return again. The second combo-box is fixed to a\
+	particular value, and cannot be modified at all. The third one only\
+	allows you to select values from its drop-down list of Australian\
+	cities."
+pack $w.msg -side top -fill x
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w {firstValue secondValue ozCity}]
+pack $btns -side bottom -fill x
+
+ttk::frame $w.f
+pack $w.f -fill both -expand 1
+set w $w.f
+
+set australianCities {
+    Canberra Sydney Melbourne Perth Adelaide Brisbane
+    Hobart Darwin "Alice Springs"
+}
+set secondValue unchangable
+set ozCity Sydney
+
+ttk::labelframe $w.c1 -text "Fully Editable"
+ttk::combobox $w.c1.c -textvariable firstValue
+ttk::labelframe $w.c2 -text Disabled
+ttk::combobox $w.c2.c -textvariable secondValue -state disabled
+ttk::labelframe $w.c3 -text "Defined List Only"
+ttk::combobox $w.c3.c -textvariable ozCity -state readonly \
+	-values $australianCities
+bind $w.c1.c <Return> {
+    if {[%W get] ni [%W cget -values]} {
+	%W configure -values [concat [%W cget -values] [list [%W get]]]
+    }
+}
+
+pack $w.c1 $w.c2 $w.c3 -side top -pady 5 -padx 10
+pack $w.c1.c -pady 5 -padx 10
+pack $w.c2.c -pady 5 -padx 10
+pack $w.c3.c -pady 5 -padx 10

janus/lib/tk8.6/demos/cscroll.tcl

@@ -0,0 +1,172 @@
+# cscroll.tcl --
+#
+# This demonstration script creates a simple canvas that can be
+# scrolled in two dimensions.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .cscroll
+catch {destroy $w}
+toplevel $w
+wm title $w "Scrollable Canvas Demonstration"
+wm iconname $w "cscroll"
+positionWindow $w
+set c $w.c
+
+label $w.msg -font $font -wraplength 4i -justify left -text "This window displays a canvas widget that can be scrolled either using the scrollbars or by dragging with button 2 in the canvas.  If you click button 1 on one of the rectangles, its indices will be printed on stdout."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+frame $w.grid
+scrollbar $w.hscroll -orient horizontal -command "$c xview"
+scrollbar $w.vscroll -command "$c yview"
+canvas $c -relief sunken -borderwidth 2 -scrollregion {-11c -11c 50c 20c} \
+	-xscrollcommand "$w.hscroll set" \
+	-yscrollcommand "$w.vscroll set"
+pack $w.grid -expand yes -fill both -padx 1 -pady 1
+grid rowconfig    $w.grid 0 -weight 1 -minsize 0
+grid columnconfig $w.grid 0 -weight 1 -minsize 0
+
+grid $c -padx 1 -in $w.grid -pady 1 \
+    -row 0 -column 0 -rowspan 1 -columnspan 1 -sticky news
+grid $w.vscroll -in $w.grid -padx 1 -pady 1 \
+    -row 0 -column 1 -rowspan 1 -columnspan 1 -sticky news
+grid $w.hscroll -in $w.grid -padx 1 -pady 1 \
+    -row 1 -column 0 -rowspan 1 -columnspan 1 -sticky news
+
+
+set bg [lindex [$c config -bg] 4]
+for {set i 0} {$i < 20} {incr i} {
+    set x [expr {-10 + 3*$i}]
+    for {set j 0; set y -10} {$j < 10} {incr j; incr y 3} {
+	$c create rect ${x}c ${y}c [expr {$x+2}]c [expr {$y+2}]c \
+		-fill $bg -tags rect
+	$c create text [expr {$x+1}]c [expr {$y+1}]c -text "$i,$j" \
+	    -anchor center -tags text
+    }
+}
+
+$c bind all <Enter> "scrollEnter $c"
+$c bind all <Leave> "scrollLeave $c"
+$c bind all <Button-1> "scrollButton $c"
+if {([tk windowingsystem] eq "aqua") && ![package vsatisfies [package provide Tk] 8.7-]} {
+    bind $c <Button-3> "$c scan mark %x %y"
+    bind $c <B3-Motion> "$c scan dragto %x %y"
+    bind $c <MouseWheel> {
+	%W yview scroll [expr {-%D}] units
+    }
+    bind $c <Option-MouseWheel> {
+	%W yview scroll [expr {-10*%D}] units
+    }
+    bind $c <Shift-MouseWheel> {
+	%W xview scroll [expr {-%D}] units
+    }
+    bind $c <Shift-Option-MouseWheel> {
+	%W xview scroll [expr {-10*%D}] units
+    }
+} else {
+    bind $c <Button-2> "$c scan mark %x %y"
+    bind $c <B2-Motion> "$c scan dragto %x %y"
+    # We must make sure that positive and negative movements are rounded
+    # equally to integers, avoiding the problem that
+    #     (int)1/-30 = -1,
+    # but
+    #     (int)-1/-30 = 0
+    # The following code ensure equal +/- behaviour.
+    bind $c <MouseWheel> {
+	if {%D >= 0} {
+	    %W yview scroll [expr {%D/-30}] units
+	} else {
+	    %W yview scroll [expr {(%D-29)/-30}] units
+	}
+    }
+    bind $c <Option-MouseWheel> {
+	if {%D >= 0} {
+	    %W yview scroll [expr {%D/-3}] units
+	} else {
+	    %W yview scroll [expr {(%D-2)/-3}] units
+	}
+    }
+    bind $c <Shift-MouseWheel> {
+	if {%D >= 0} {
+	    %W xview scroll [expr {%D/-30}] units
+	} else {
+	    %W xview scroll [expr {(%D-29)/-30}] units
+	}
+    }
+    bind $c <Shift-Option-MouseWheel> {
+	if {%D >= 0} {
+	    %W xview scroll [expr {%D/-3}] units
+	} else {
+	    %W xview scroll [expr {(%D-2)/-3}] units
+	}
+    }
+}
+
+if {[tk windowingsystem] eq "x11" && ![package vsatisfies [package provide Tk] 8.7-]} {
+    # Support for mousewheels on Linux/Unix commonly comes through mapping
+    # the wheel to the extended buttons.  If you have a mousewheel, find
+    # Linux configuration info at:
+    #	https://linuxreviews.org/HOWTO_change_the_mouse_speed_in_X
+    bind $c <Button-4> {
+	if {!$tk_strictMotif} {
+	    %W yview scroll -5 units
+	}
+    }
+    bind $c <Shift-Button-4> {
+	if {!$tk_strictMotif} {
+	    %W xview scroll -5 units
+	}
+    }
+    bind $c <Button-5> {
+	if {!$tk_strictMotif} {
+	    %W yview scroll 5 units
+	}
+    }
+    bind $c <Shift-Button-5> {
+	if {!$tk_strictMotif} {
+	    %W xview scroll 5 units
+	}
+    }
+}
+
+
+proc scrollEnter canvas {
+    global oldFill
+    set id [$canvas find withtag current]
+    if {[lsearch [$canvas gettags current] text] >= 0} {
+	set id [expr {$id-1}]
+    }
+    set oldFill [lindex [$canvas itemconfig $id -fill] 4]
+    if {[winfo depth $canvas] > 1} {
+	if {[tk windowingsystem] eq "aqua"} {
+	    $canvas itemconfigure $id -fill systemSelectedTextBackgroundColor
+	} else {
+	    $canvas itemconfigure $id -fill LightSeaGreen
+	}
+    }
+}
+
+proc scrollLeave canvas {
+    global oldFill
+    set id [$canvas find withtag current]
+    if {[lsearch [$canvas gettags current] text] >= 0} {
+	set id [expr {$id-1}]
+    }
+    $canvas itemconfigure $id -fill $oldFill
+}
+
+proc scrollButton canvas {
+    set id [$canvas find withtag current]
+    if {[lsearch [$canvas gettags current] text] < 0} {
+	set id [expr {$id+1}]
+    }
+    puts stdout "You buttoned at [lindex [$canvas itemconf $id -text] 4]"
+}

janus/lib/tk8.6/demos/ctext.tcl

@@ -0,0 +1,176 @@
+# ctext.tcl --
+#
+# This demonstration script creates a canvas widget with a text
+# item that can be edited and reconfigured in various ways.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .ctext
+catch {destroy $w}
+toplevel $w
+wm title $w "Canvas Text Demonstration"
+wm iconname $w "Text"
+positionWindow $w
+set c $w.c
+
+label $w.msg -font $font -wraplength 5i -justify left -text "This window displays a string of text to demonstrate the text facilities of canvas widgets.  You can click in the boxes to adjust the position of the text relative to its positioning point or change its justification, and on a pie slice to change its angle.  The text also supports the following simple bindings for editing:
+  1. You can point, click, and type.
+  2. You can also select with button 1.
+  3. You can copy the selection to the mouse position with button 2.
+  4. Backspace and Control+h delete the selection if there is one;
+     otherwise they delete the character just before the insertion cursor.
+  5. Delete deletes the selection if there is one; otherwise it deletes
+     the character just after the insertion cursor."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+canvas $c -relief flat -borderwidth 0 -width 500 -height 350
+pack $w.c -side top -expand yes -fill both
+
+set textFont {Helvetica 24}
+
+$c create rectangle 245 195 255 205 -outline black -fill red
+
+# First, create the text item and give it bindings so it can be edited.
+
+$c addtag text withtag [$c create text 250 200 -text "This is just a string of text to demonstrate the text facilities of canvas widgets. Bindings have been defined to support editing (see above)." -width 440 -anchor n -font $textFont -justify left]
+$c bind text <Button-1> "textB1Press $c %x %y"
+$c bind text <B1-Motion> "textB1Move $c %x %y"
+$c bind text <Shift-Button-1> "$c select adjust current @%x,%y"
+$c bind text <Shift-B1-Motion> "textB1Move $c %x %y"
+$c bind text <Key> "textInsert $c %A"
+$c bind text <Return> "textInsert $c \\n"
+$c bind text <Control-h> "textBs $c"
+$c bind text <BackSpace> "textBs $c"
+$c bind text <Delete> "textDel $c"
+if {[tk windowingsystem] eq "aqua" && ![package vsatisfies [package provide Tk] 8.7-]} {
+    $c bind text <Button-3> "textPaste $c @%x,%y"
+} else {
+    $c bind text <Button-2> "textPaste $c @%x,%y"
+}
+
+# Next, create some items that allow the text's anchor position
+# to be edited.
+
+proc mkTextConfigBox {w x y option value color} {
+    set item [$w create rect $x $y [expr {$x+30}] [expr {$y+30}] \
+	    -outline black -fill $color -width 1]
+    $w bind $item <Button-1> "$w itemconf text $option $value"
+    $w addtag config withtag $item
+}
+proc mkTextConfigPie {w x y a option value color} {
+    set item [$w create arc $x $y [expr {$x+90}] [expr {$y+90}] \
+	    -start [expr {$a-15}] -extent 30 -outline black -fill $color \
+	    -width 1]
+    $w bind $item <Button-1> "$w itemconf text $option $value"
+    $w addtag config withtag $item
+}
+
+set x 50
+set y 50
+set color LightSkyBlue1
+mkTextConfigBox $c $x $y -anchor se $color
+mkTextConfigBox $c [expr {$x+30}] [expr {$y   }] -anchor s      $color
+mkTextConfigBox $c [expr {$x+60}] [expr {$y   }] -anchor sw     $color
+mkTextConfigBox $c [expr {$x   }] [expr {$y+30}] -anchor e      $color
+mkTextConfigBox $c [expr {$x+30}] [expr {$y+30}] -anchor center $color
+mkTextConfigBox $c [expr {$x+60}] [expr {$y+30}] -anchor w      $color
+mkTextConfigBox $c [expr {$x   }] [expr {$y+60}] -anchor ne     $color
+mkTextConfigBox $c [expr {$x+30}] [expr {$y+60}] -anchor n      $color
+mkTextConfigBox $c [expr {$x+60}] [expr {$y+60}] -anchor nw     $color
+set item [$c create rect \
+	[expr {$x+40}] [expr {$y+40}] [expr {$x+50}] [expr {$y+50}] \
+	-outline black -fill red]
+$c bind $item <Button-1> "$c itemconf text -anchor center"
+$c create text [expr {$x+45}] [expr {$y-5}] \
+	-text {Text Position}  -anchor s  -font {Times 20}  -fill brown
+
+# Now create some items that allow the text's angle to be changed.
+
+set x 205
+set y 50
+set color Yellow
+mkTextConfigPie $c $x $y   0 -angle  90 $color
+mkTextConfigPie $c $x $y  30 -angle 120 $color
+mkTextConfigPie $c $x $y  60 -angle 150 $color
+mkTextConfigPie $c $x $y  90 -angle 180 $color
+mkTextConfigPie $c $x $y 120 -angle 210 $color
+mkTextConfigPie $c $x $y 150 -angle 240 $color
+mkTextConfigPie $c $x $y 180 -angle 270 $color
+mkTextConfigPie $c $x $y 210 -angle 300 $color
+mkTextConfigPie $c $x $y 240 -angle 330 $color
+mkTextConfigPie $c $x $y 270 -angle   0 $color
+mkTextConfigPie $c $x $y 300 -angle  30 $color
+mkTextConfigPie $c $x $y 330 -angle  60 $color
+$c create text [expr {$x+45}] [expr {$y-5}] \
+	-text {Text Angle}  -anchor s  -font {Times 20}  -fill brown
+
+# Lastly, create some items that allow the text's justification to be
+# changed.
+
+set x 350
+set y 50
+set color SeaGreen2
+mkTextConfigBox $c $x $y -justify left $color
+mkTextConfigBox $c [expr {$x+30}] $y -justify center $color
+mkTextConfigBox $c [expr {$x+60}] $y -justify right $color
+$c create text [expr {$x+45}] [expr {$y-5}] \
+	-text {Justification}  -anchor s  -font {Times 20}  -fill brown
+
+$c bind config <Enter> "textEnter $c"
+$c bind config <Leave> "$c itemconf current -fill \$textConfigFill"
+
+set textConfigFill {}
+
+proc textEnter {w} {
+    global textConfigFill
+    set textConfigFill [lindex [$w itemconfig current -fill] 4]
+    $w itemconfig current -fill black
+}
+
+proc textInsert {w string} {
+    if {$string == ""} {
+	return
+    }
+    catch {$w dchars text sel.first sel.last}
+    $w insert text insert $string
+}
+
+proc textPaste {w pos} {
+    catch {
+	$w insert text $pos [selection get]
+    }
+}
+
+proc textB1Press {w x y} {
+    $w icursor current @$x,$y
+    $w focus current
+    focus $w
+    $w select from current @$x,$y
+}
+
+proc textB1Move {w x y} {
+    $w select to current @$x,$y
+}
+
+proc textBs {w} {
+    if {![catch {$w dchars text sel.first sel.last}]} {
+	return
+    }
+    set char [expr {[$w index text insert] - 1}]
+    if {$char >= 0} {$w dchar text $char}
+}
+
+proc textDel {w} {
+    if {![catch {$w dchars text sel.first sel.last}]} {
+	return
+    }
+    $w dchars text insert
+}

janus/lib/tk8.6/demos/en.msg

@@ -0,0 +1,97 @@
+::msgcat::mcset en "Widget Demonstration"
+::msgcat::mcset en "tkWidgetDemo"
+::msgcat::mcset en "&File"
+::msgcat::mcset en "About..."
+::msgcat::mcset en "&About..."
+::msgcat::mcset en "<F1>"
+::msgcat::mcset en "&Quit"
+::msgcat::mcset en "Meta+Q"		;# Displayed hotkey
+::msgcat::mcset en "Meta-q"		;# Actual binding sequence
+::msgcat::mcset en "Ctrl+Q"		;# Displayed hotkey
+::msgcat::mcset en "Control-q"		;# Actual binding sequence
+::msgcat::mcset en "Variable values"
+::msgcat::mcset en "Variable values:"
+::msgcat::mcset en "OK"
+::msgcat::mcset en "Run the \"%s\" sample program"
+::msgcat::mcset en "Dismiss"
+::msgcat::mcset en "Rerun Demo"
+::msgcat::mcset en "Demo code: %s"
+::msgcat::mcset en "About Widget Demo"
+::msgcat::mcset en "Tk widget demonstration application"
+::msgcat::mcset en "Copyright © %s"
+::msgcat::mcset en "
+    @@title
+    Tk Widget Demonstrations
+    @@newline
+    @@normal
+    @@newline
+
+    This application provides a front end for several short scripts
+    that demonstrate what you can do with Tk widgets.  Each of the
+    numbered lines below describes a demonstration;  you can click on
+    it to invoke the demonstration.  Once the demonstration window
+    appears, you can click the
+    @@bold
+    See Code
+    @@normal
+    button to see the Tcl/Tk code that created the demonstration.  If
+    you wish, you can edit the code and click the
+    @@bold
+    Rerun Demo
+    @@normal
+    button in the code window to reinvoke the demonstration with the
+    modified code.
+    @@newline
+"
+::msgcat::mcset en "Labels, buttons, checkbuttons, and radiobuttons"
+::msgcat::mcset en "Labels (text and bitmaps)"
+::msgcat::mcset en "Labels and UNICODE text"
+::msgcat::mcset en "Buttons"
+::msgcat::mcset en "Check-buttons (select any of a group)"
+::msgcat::mcset en "Radio-buttons (select one of a group)"
+::msgcat::mcset en "A 15-puzzle game made out of buttons"
+::msgcat::mcset en "Iconic buttons that use bitmaps"
+::msgcat::mcset en "Two labels displaying images"
+::msgcat::mcset en "A simple user interface for viewing images"
+::msgcat::mcset en "Labelled frames"
+::msgcat::mcset en "Listboxes"
+::msgcat::mcset en "The 50 states"
+::msgcat::mcset en "Colors: change the color scheme for the application"
+::msgcat::mcset en "A collection of famous and infamous sayings"
+::msgcat::mcset en "Entries and Spin-boxes"
+::msgcat::mcset en "Entries without scrollbars"
+::msgcat::mcset en "Entries with scrollbars"
+::msgcat::mcset en "Validated entries and password fields"
+::msgcat::mcset en "Spin-boxes"
+::msgcat::mcset en "Simple Rolodex-like form"
+::msgcat::mcset en "Text"
+::msgcat::mcset en "Basic editable text"
+::msgcat::mcset en "Text display styles"
+::msgcat::mcset en "Hypertext (tag bindings)"
+::msgcat::mcset en "A text widget with embedded windows"
+::msgcat::mcset en "A search tool built with a text widget"
+::msgcat::mcset en "Canvases"
+::msgcat::mcset en "The canvas item types"
+::msgcat::mcset en "A simple 2-D plot"
+::msgcat::mcset en "Text items in canvases"
+::msgcat::mcset en "An editor for arrowheads on canvas lines"
+::msgcat::mcset en "A ruler with adjustable tab stops"
+::msgcat::mcset en "A building floor plan"
+::msgcat::mcset en "A simple scrollable canvas"
+::msgcat::mcset en "Scales"
+::msgcat::mcset en "Horizontal scale"
+::msgcat::mcset en "Vertical scale"
+::msgcat::mcset en "Paned Windows"
+::msgcat::mcset en "Horizontal paned window"
+::msgcat::mcset en "Vertical paned window"
+::msgcat::mcset en "Menus"
+::msgcat::mcset en "Menus and cascades (sub-menus)"
+::msgcat::mcset en "Menu-buttons"
+::msgcat::mcset en "Common Dialogs"
+::msgcat::mcset en "Message boxes"
+::msgcat::mcset en "File selection dialog"
+::msgcat::mcset en "Color picker"
+::msgcat::mcset en "Miscellaneous"
+::msgcat::mcset en "The built-in bitmaps"
+::msgcat::mcset en "A dialog box with a local grab"
+::msgcat::mcset en "A dialog box with a global grab"

janus/lib/tk8.6/demos/entry3.tcl

@@ -0,0 +1,185 @@
+# entry3.tcl --
+#
+# This demonstration script creates several entry widgets whose
+# permitted input is constrained in some way.  It also shows off a
+# password entry.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .entry3
+catch {destroy $w}
+toplevel $w
+wm title $w "Constrained Entry Demonstration"
+wm iconname $w "entry3"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 5i -justify left -text "Four different\
+	entries are displayed below.  You can add characters by pointing,\
+	clicking and typing, though each is constrained in what it will\
+	accept.  The first only accepts 32-bit integers or the empty string\
+	(checking when focus leaves it) and will flash to indicate any\
+	problem.  The second only accepts strings with fewer than ten\
+	characters and sounds the bell when an attempt to go over the limit\
+	is made.  The third accepts US phone numbers, mapping letters to\
+	their digit equivalent and sounding the bell on encountering an\
+	illegal character or if trying to type over a character that is not\
+	a digit.  The fourth is a password field that accepts up to eight\
+	characters (silently ignoring further ones), and displaying them as\
+	asterisk characters."
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+# focusAndFlash --
+# Error handler for entry widgets that forces the focus onto the
+# widget and makes the widget flash by exchanging the foreground and
+# background colours at intervals of 200ms (i.e. at approximately
+# 2.5Hz).
+#
+# Arguments:
+# W -		Name of entry widget to flash
+# fg -		Initial foreground colour
+# bg -		Initial background colour
+# count -	Counter to control the number of times flashed
+
+proc focusAndFlash {W fg bg {count 9}} {
+    focus -force $W
+    if {$count<1} {
+	$W configure -foreground $fg -background $bg
+    } else {
+	if {$count%2} {
+	    $W configure -foreground $bg -background $fg
+	} else {
+	    $W configure -foreground $fg -background $bg
+	}
+	after 200 [list focusAndFlash $W $fg $bg [expr {$count-1}]]
+    }
+}
+
+labelframe $w.l1 -text "Integer Entry"
+# Alternatively try using {string is digit} for arbitrary length numbers,
+# and not just 32-bit ones.
+entry $w.l1.e -validate focus -vcmd {string is integer %P}
+$w.l1.e configure -invalidcommand \
+	"focusAndFlash %W [$w.l1.e cget -fg] [$w.l1.e cget -bg]"
+pack $w.l1.e -fill x -expand 1 -padx 1m -pady 1m
+
+labelframe $w.l2 -text "Length-Constrained Entry"
+entry $w.l2.e -validate key -invcmd bell -vcmd {expr {[string length %P]<10}}
+pack $w.l2.e -fill x -expand 1 -padx 1m -pady 1m
+
+### PHONE NUMBER ENTRY ###
+# Note that the source to this is quite a bit longer as the behaviour
+# demonstrated is a lot more ambitious than with the others.
+
+# Initial content for the third entry widget
+set entry3content "1-(000)-000-0000"
+# Mapping from alphabetic characters to numbers.  This is probably
+# wrong, but it is the only mapping I have; the UK doesn't really go
+# for associating letters with digits for some reason.
+set phoneNumberMap {}
+foreach {chars digit} {abc 2 def 3 ghi 4 jkl 5 mno 6 pqrs 7 tuv 8 wxyz 9} {
+    foreach char [split $chars ""] {
+	lappend phoneNumberMap $char $digit [string toupper $char] $digit
+    }
+}
+
+# validatePhoneChange --
+# Checks that the replacement (mapped to a digit) of the given
+# character in an entry widget at the given position will leave a
+# valid phone number in the widget.
+#
+# W -	  The entry widget to validate
+# vmode - The widget's validation mode
+# idx -	  The index where replacement is to occur
+# char -  The character (or string, though that will always be
+#	  refused) to be overwritten at that point.
+
+proc validatePhoneChange {W vmode idx char} {
+    global phoneNumberMap entry3content
+    if {$idx < 0} {return 1}
+    after idle [list $W configure -validate $vmode -invcmd bell]
+    if {
+	!($idx<3 || $idx==6 || $idx==7 || $idx==11 || $idx>15) &&
+	[string match {[0-9A-Za-z]} $char]
+    } then {
+	$W delete $idx
+	$W insert $idx [string map $phoneNumberMap $char]
+	after idle [list phoneSkipRight $W -1]
+	return 1
+    }
+    return 0
+}
+
+# phoneSkipLeft --
+# Skip over fixed characters in a phone-number string when moving left.
+#
+# Arguments:
+# W -	The entry widget containing the phone-number.
+
+proc phoneSkipLeft {W} {
+    set idx [$W index insert]
+    if {$idx == 8} {
+	# Skip back two extra characters
+	$W icursor [incr idx -2]
+    } elseif {$idx == 7 || $idx == 12} {
+	# Skip back one extra character
+	$W icursor [incr idx -1]
+    } elseif {$idx <= 3} {
+	# Can't move any further
+	bell
+	return -code break
+    }
+}
+
+# phoneSkipRight --
+# Skip over fixed characters in a phone-number string when moving right.
+#
+# Arguments:
+# W -	The entry widget containing the phone-number.
+# add - Offset to add to index before calculation (used by validation.)
+
+proc phoneSkipRight {W {add 0}} {
+    set idx [$W index insert]
+    if {$idx+$add == 5} {
+	# Skip forward two extra characters
+	$W icursor [incr idx 2]
+    } elseif {$idx+$add == 6 || $idx+$add == 10} {
+	# Skip forward one extra character
+	$W icursor [incr idx]
+    } elseif {$idx+$add == 15 && !$add} {
+	# Can't move any further
+	bell
+	return -code break
+    }
+}
+
+labelframe $w.l3 -text "US Phone-Number Entry"
+entry $w.l3.e -validate key  -invcmd bell  -textvariable entry3content \
+	-vcmd {validatePhoneChange %W %v %i %S}
+# Click to focus goes to the first editable character...
+bind $w.l3.e <FocusIn> {
+    if {"%d" ne "NotifyAncestor"} {
+	%W icursor 3
+	after idle {%W selection clear}
+    }
+}
+bind $w.l3.e <<PrevChar>> {phoneSkipLeft  %W}
+bind $w.l3.e <<NextChar>> {phoneSkipRight %W}
+pack $w.l3.e -fill x -expand 1 -padx 1m -pady 1m
+
+labelframe $w.l4 -text "Password Entry"
+entry $w.l4.e -validate key -show "*" -vcmd {expr {[string length %P]<=8}}
+pack $w.l4.e -fill x -expand 1 -padx 1m -pady 1m
+
+lower [frame $w.mid]
+grid $w.l1 $w.l2 -in $w.mid -padx 3m -pady 1m -sticky ew
+grid $w.l3 $w.l4 -in $w.mid -padx 3m -pady 1m -sticky ew
+grid columnconfigure $w.mid {0 1} -uniform 1
+pack $w.msg -side top
+pack $w.mid -fill both -expand 1

janus/lib/tk8.6/demos/fontchoose.tcl

@@ -0,0 +1,67 @@
+# fontchoose.tcl --
+#
+# Show off the stock font selector dialog
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .fontchoose
+catch {destroy $w}
+toplevel $w
+wm title $w "Font Selection Dialog"
+wm iconname $w "fontchooser"
+positionWindow $w
+
+catch {font create FontchooseDemoFont {*}[font actual TkDefaultFont]}
+
+# The font chooser needs to be configured and then shown.
+proc SelectFont {parent} {
+    tk fontchooser configure -font FontchooseDemoFont \
+        -command ApplyFont -parent $parent
+    tk fontchooser show
+}
+
+proc ApplyFont {font} {
+    font configure FontchooseDemoFont {*}[font actual $font]
+}
+
+# When the visibility of the fontchooser changes, the following event is fired
+# to the parent widget.
+#
+bind $w <<TkFontchooserVisibility>> {
+    if {[tk fontchooser configure -visible]} {
+        %W.f.font state disabled
+    } else {
+        %W.f.font state !disabled
+    }
+}
+
+
+set f [ttk::frame $w.f -relief sunken -padding 2]
+
+text $f.msg -font FontchooseDemoFont -width 40 -height 6 -borderwidth 0 \
+    -yscrollcommand [list $f.vs set]
+ttk::scrollbar $f.vs -command [list $f.msg yview]
+
+$f.msg insert end "Press the buttons below to choose a new font for the\
+  text shown in this window.\n" {}
+
+ttk::button $f.font -text "Set font ..." -command [list SelectFont $w]
+
+grid $f.msg $f.vs -sticky news
+grid $f.font -    -sticky e
+grid columnconfigure $f 0 -weight 1
+grid rowconfigure $f 0 -weight 1
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+
+grid $f -sticky news
+grid $btns -sticky ew
+grid columnconfigure $w 0 -weight 1
+grid rowconfigure $w 0 -weight 1
+update idletasks
+grid propagate $f 0

janus/lib/tk8.6/demos/hello

@@ -0,0 +1,22 @@
+#!/bin/sh
+# the next line restarts using wish \
+exec wish8.6 "$0" ${1+"$@"}
+
+# hello --
+# Simple Tk script to create a button that prints "Hello, world".
+# Click on the button to terminate the program.
+
+package require Tk
+
+# The first line below creates the button, and the second line
+# asks the packer to shrink-wrap the application's main window
+# around the button.
+
+button .hello -text "Hello, world" -command {
+    puts stdout "Hello, world"; destroy .
+}
+pack .hello
+
+# Local Variables:
+# mode: tcl
+# End:

janus/lib/tk8.6/demos/hscale.tcl

@@ -0,0 +1,45 @@
+# hscale.tcl --
+#
+# This demonstration script shows an example with a horizontal scale.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .hscale
+catch {destroy $w}
+toplevel $w
+wm title $w "Horizontal Scale Demonstration"
+wm iconname $w "hscale"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 3.5i -justify left -text "An arrow and a horizontal scale are displayed below.  If you click or drag mouse button 1 in the scale, you can change the length of the arrow."
+pack $w.msg -side top -padx .5c
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+frame $w.frame -borderwidth 10
+pack $w.frame -side top -fill x
+
+canvas $w.frame.canvas -width 50 -height 50 -bd 0 -highlightthickness 0
+$w.frame.canvas create polygon 0 0 1 1 2 2 -fill DeepSkyBlue3 -tags poly
+$w.frame.canvas create line 0 0 1 1 2 2 0 0 -fill black -tags line
+scale $w.frame.scale -orient horizontal -length 284 -from 0 -to 250 \
+	-command "setWidth $w.frame.canvas" -tickinterval 50
+pack $w.frame.canvas -side top -expand yes -anchor s -fill x  -padx 15
+pack $w.frame.scale -side bottom -expand yes -anchor n
+$w.frame.scale set 75
+
+proc setWidth {w width} {
+    incr width 21
+    set x2 [expr {$width - 30}]
+    if {$x2 < 21} {
+	set x2 21
+    }
+    $w coords poly 20 15 20 35 $x2 35 $x2 45 $width 25 $x2 5 $x2 15 20 15
+    $w coords line 20 15 20 35 $x2 35 $x2 45 $width 25 $x2 5 $x2 15 20 15
+}

janus/lib/tk8.6/demos/items.tcl

@@ -0,0 +1,302 @@
+# items.tcl --
+#
+# This demonstration script creates a canvas that displays the
+# canvas item types.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .items
+catch {destroy $w}
+toplevel $w
+wm title $w "Canvas Item Demonstration"
+wm iconname $w "Items"
+positionWindow $w
+set c $w.frame.c
+
+label $w.msg -font $font -wraplength 5i -justify left -text "This window contains a canvas widget with examples of the various kinds of items supported by canvases.  The following operations are supported:\n  Left-Button drag:\tmoves item under pointer.\n  Middle-Button drag:\trepositions view.\n  Right-Button drag:\tstrokes out area.\n  Ctrl+f:\t\tprints items under area."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+frame $w.frame
+pack $w.frame -side top -fill both -expand yes
+
+canvas $c -scrollregion {0c 0c 30c 24c} -width 15c -height 10c \
+	-relief sunken -borderwidth 2 \
+	-xscrollcommand "$w.frame.hscroll set" \
+	-yscrollcommand "$w.frame.vscroll set"
+ttk::scrollbar $w.frame.vscroll -command "$c yview"
+ttk::scrollbar $w.frame.hscroll -orient horizontal -command "$c xview"
+
+grid $c -in $w.frame \
+    -row 0 -column 0 -rowspan 1 -columnspan 1 -sticky news
+grid $w.frame.vscroll \
+    -row 0 -column 1 -rowspan 1 -columnspan 1 -sticky news
+grid $w.frame.hscroll \
+    -row 1 -column 0 -rowspan 1 -columnspan 1 -sticky news
+grid rowconfig    $w.frame 0 -weight 1 -minsize 0
+grid columnconfig $w.frame 0 -weight 1 -minsize 0
+
+# Display a 3x3 rectangular grid.
+
+$c create rect 0c 0c 30c 24c -width 2
+$c create line 0c 8c 30c 8c -width 2
+$c create line 0c 16c 30c 16c -width 2
+$c create line 10c 0c 10c 24c -width 2
+$c create line 20c 0c 20c 24c -width 2
+
+set font1 {Helvetica 12}
+set font2 {Helvetica 24 bold}
+if {[winfo depth $c] > 1} {
+    set blue DeepSkyBlue3
+    set red red
+    set bisque bisque3
+    set green SeaGreen3
+} else {
+    set blue black
+    set red black
+    set bisque black
+    set green black
+}
+
+# Set up demos within each of the areas of the grid.
+
+$c create text 5c .2c -text Lines -anchor n
+$c create line 1c 1c 3c 1c 1c 4c 3c 4c -width 2m -fill $blue \
+	-cap butt -join miter -tags item
+$c create line 4.67c 1c 4.67c 4c -arrow last -tags item
+$c create line 6.33c 1c 6.33c 4c -arrow both -tags item
+$c create line 5c 6c 9c 6c 9c 1c 8c 1c 8c 4.8c 8.8c 4.8c 8.8c 1.2c \
+	8.2c 1.2c 8.2c 4.6c 8.6c 4.6c 8.6c 1.4c 8.4c 1.4c 8.4c 4.4c \
+	-width 3 -fill $red -tags item
+# Main widget program sets variable tk_demoDirectory
+$c create line 1c 5c 7c 5c 7c 7c 9c 7c -width .5c \
+	-stipple @[file join $tk_demoDirectory images gray25.xbm] \
+	-arrow both -arrowshape {15 15 7} -tags item
+$c create line 1c 7c 1.75c 5.8c 2.5c 7c 3.25c 5.8c 4c 7c -width .5c \
+	-cap round -join round -tags item
+
+$c create text 15c .2c -text "Curves (smoothed lines)" -anchor n
+$c create line 11c 4c 11.5c 1c 13.5c 1c 14c 4c -smooth on \
+	-fill $blue -tags item
+$c create line 15.5c 1c 19.5c 1.5c 15.5c 4.5c 19.5c 4c -smooth on \
+	-arrow both -width 3 -tags item
+$c create line 12c 6c 13.5c 4.5c 16.5c 7.5c 18c 6c \
+	16.5c 4.5c 13.5c 7.5c 12c 6c -smooth on -width 3m -cap round \
+	-stipple @[file join $tk_demoDirectory images gray25.xbm] \
+	-fill $red -tags item
+
+$c create text 25c .2c -text Polygons -anchor n
+$c create polygon 21c 1.0c 22.5c 1.75c 24c 1.0c 23.25c 2.5c \
+	24c 4.0c 22.5c 3.25c 21c 4.0c 21.75c 2.5c -fill $green \
+	-outline {} -width 4 -tags item
+$c create polygon 25c 4c 25c 4c 25c 1c 26c 1c 27c 4c 28c 1c \
+	29c 1c 29c 4c 29c 4c -fill $red -outline {} -smooth on -tags item
+$c create polygon 22c 4.5c 25c 4.5c 25c 6.75c 28c 6.75c \
+	28c 5.25c 24c 5.25c 24c 6.0c 26c 6c 26c 7.5c 22c 7.5c \
+	-stipple @[file join $tk_demoDirectory images gray25.xbm] \
+	-fill $blue -outline {} -tags item
+
+$c create text 5c 8.2c -text Rectangles -anchor n
+$c create rectangle 1c 9.5c 4c 12.5c -outline $red -width 3m -tags item
+$c create rectangle 0.5c 13.5c 4.5c 15.5c -fill $green -tags item
+$c create rectangle 6c 10c 9c 15c -outline {} \
+	-stipple @[file join $tk_demoDirectory images gray25.xbm] \
+	-fill $blue -tags item
+
+$c create text 15c 8.2c -text Ovals -anchor n
+$c create oval 11c 9.5c 14c 12.5c -outline $red -width 3m -tags item
+$c create oval 10.5c 13.5c 14.5c 15.5c -fill $green -tags item
+$c create oval 16c 10c 19c 15c -outline {} \
+	-stipple @[file join $tk_demoDirectory images gray25.xbm] \
+	-fill $blue -tags item
+
+$c create text 25c 8.2c -text Text -anchor n
+$c create rectangle 22.4c 8.9c 22.6c 9.1c
+$c create text 22.5c 9c -anchor n -font $font1 -width 4c \
+	-text "A short string of text, word-wrapped, justified left, and anchored north (at the top).  The rectangles show the anchor points for each piece of text." -tags item
+$c create rectangle 25.4c 10.9c 25.6c 11.1c
+$c create text 25.5c 11c -anchor w -font $font1 -fill $blue \
+	-text "Several lines,\n each centered\nindividually,\nand all anchored\nat the left edge." \
+	-justify center -tags item
+$c create rectangle 24.9c 13.9c 25.1c 14.1c
+catch {
+$c create text 25c 14c -font $font2 -anchor c -fill $red -angle 15 \
+	-text "Angled characters" -tags item
+}
+
+$c create text 5c 16.2c -text Arcs -anchor n
+$c create arc 0.5c 17c 7c 20c -fill $green -outline black \
+	-start 45 -extent 270 -style pieslice -tags item
+$c create arc 6.5c 17c 9.5c 20c -width 4m -style arc \
+	-outline $blue -start -135 -extent 270 -tags item \
+	-outlinestipple @[file join $tk_demoDirectory images gray25.xbm]
+$c create arc 0.5c 20c 9.5c 24c -width 4m -style pieslice \
+	-fill {} -outline $red -start 225 -extent -90 -tags item
+$c create arc 5.5c 20.5c 9.5c 23.5c -width 4m -style chord \
+	-fill $blue -outline {} -start 45 -extent 270  -tags item
+
+$c create text 15c 16.2c -text "Bitmaps and Images" -anchor n
+catch {
+image create photo items.ousterhout \
+    -file [file join $tk_demoDirectory images ouster.png]
+image create photo items.ousterhout.active -format "png -alpha 0.5" \
+    -file [file join $tk_demoDirectory images ouster.png]
+$c create image 13c 20c -tags item -image items.ousterhout \
+    -activeimage items.ousterhout.active
+}
+$c create bitmap 17c 18.5c -tags item \
+	-bitmap @[file join $tk_demoDirectory images noletter.xbm]
+$c create bitmap 17c 21.5c -tags item \
+	-bitmap @[file join $tk_demoDirectory images letters.xbm]
+
+$c create text 25c 16.2c -text Windows -anchor n
+button $c.button -text "Press Me" -command "butPress $c $red"
+$c create window 21c 18c -window $c.button -anchor nw -tags item
+entry $c.entry -width 20 -relief sunken
+$c.entry insert end "Edit this text"
+$c create window 21c 21c -window $c.entry -anchor nw -tags item
+scale $c.scale -from 0 -to 100 -length 6c -sliderlength .4c \
+	-width .5c -tickinterval 0
+$c create window 28.5c 17.5c -window $c.scale -anchor n -tags item
+$c create text 21c 17.9c -text Button: -anchor sw
+$c create text 21c 20.9c -text Entry: -anchor sw
+$c create text 28.5c 17.4c -text Scale: -anchor s
+
+# Set up event bindings for canvas:
+
+$c bind item <Enter> "itemEnter $c"
+$c bind item <Leave> "itemLeave $c"
+if {[tk windowingsystem] eq "aqua" && ![package vsatisfies [package provide Tk] 8.7-]} {
+    bind $c <Button-2> "itemMark $c %x %y"
+    bind $c <B2-Motion> "itemStroke $c %x %y"
+    bind $c <Button-3> "$c scan mark %x %y"
+    bind $c <B3-Motion> "$c scan dragto %x %y"
+} else {
+    bind $c <Button-2> "$c scan mark %x %y"
+    bind $c <B2-Motion> "$c scan dragto %x %y"
+    bind $c <Button-3> "itemMark $c %x %y"
+    bind $c <B3-Motion> "itemStroke $c %x %y"
+}
+bind $c <<NextChar>> "itemsUnderArea $c"
+bind $c <Button-1> "itemStartDrag $c %x %y"
+bind $c <B1-Motion> "itemDrag $c %x %y"
+
+# Utility procedures for highlighting the item under the pointer:
+
+proc itemEnter {c} {
+    global restoreCmd
+
+    if {[winfo depth $c] == 1} {
+	set restoreCmd {}
+	return
+    }
+    set type [$c type current]
+    if {$type == "window" || $type == "image"} {
+	set restoreCmd {}
+	return
+    } elseif {$type == "bitmap"} {
+	set bg [lindex [$c itemconf current -background] 4]
+	set restoreCmd [list $c itemconfig current -background $bg]
+	$c itemconfig current -background SteelBlue2
+	return
+    } elseif {$type == "image"} {
+	set restoreCmd [list $c itemconfig current -state normal]
+	$c itemconfig current -state active
+	return
+    }
+    set fill [lindex [$c itemconfig current -fill] 4]
+    if {(($type == "rectangle") || ($type == "oval") || ($type == "arc"))
+	    && ($fill == "")} {
+	set outline [lindex [$c itemconfig current -outline] 4]
+	set restoreCmd "$c itemconfig current -outline $outline"
+	$c itemconfig current -outline SteelBlue2
+    } else {
+	set restoreCmd "$c itemconfig current -fill $fill"
+	$c itemconfig current -fill SteelBlue2
+    }
+}
+
+proc itemLeave {c} {
+    global restoreCmd
+
+    eval $restoreCmd
+}
+
+# Utility procedures for stroking out a rectangle and printing what's
+# underneath the rectangle's area.
+
+proc itemMark {c x y} {
+    global areaX1 areaY1
+    set areaX1 [$c canvasx $x]
+    set areaY1 [$c canvasy $y]
+    $c delete area
+}
+
+proc itemStroke {c x y} {
+    global areaX1 areaY1 areaX2 areaY2
+    set x [$c canvasx $x]
+    set y [$c canvasy $y]
+    if {($areaX1 != $x) && ($areaY1 != $y)} {
+	$c delete area
+	$c addtag area withtag [$c create rect $areaX1 $areaY1 $x $y \
+		-outline black]
+	set areaX2 $x
+	set areaY2 $y
+    }
+}
+
+proc itemsUnderArea {c} {
+    global areaX1 areaY1 areaX2 areaY2
+    set area [$c find withtag area]
+    set items ""
+    foreach i [$c find enclosed $areaX1 $areaY1 $areaX2 $areaY2] {
+	if {[lsearch [$c gettags $i] item] >= 0} {
+	    lappend items $i
+	}
+    }
+    puts stdout "Items enclosed by area: $items"
+    set items ""
+    foreach i [$c find overlapping $areaX1 $areaY1 $areaX2 $areaY2] {
+	if {[lsearch [$c gettags $i] item] >= 0} {
+	    lappend items $i
+	}
+    }
+    puts stdout "Items overlapping area: $items"
+}
+
+set areaX1 0
+set areaY1 0
+set areaX2 0
+set areaY2 0
+
+# Utility procedures to support dragging of items.
+
+proc itemStartDrag {c x y} {
+    global lastX lastY
+    set lastX [$c canvasx $x]
+    set lastY [$c canvasy $y]
+}
+
+proc itemDrag {c x y} {
+    global lastX lastY
+    set x [$c canvasx $x]
+    set y [$c canvasy $y]
+    $c move current [expr {$x-$lastX}] [expr {$y-$lastY}]
+    set lastX $x
+    set lastY $y
+}
+
+# Procedure that's invoked when the button embedded in the canvas
+# is invoked.
+
+proc butPress {w color} {
+    set i [$w create text 25c 18.1c -text "Oooohhh!!" -fill $color -anchor n]
+    after 500 "$w delete $i"
+}

janus/lib/tk8.6/demos/ixset

@@ -0,0 +1,328 @@
+#!/bin/sh
+# the next line restarts using wish \
+exec wish8.6 "$0" ${1+"$@"}
+
+# ixset --
+# A nice interface to "xset" to change X server settings
+#
+# History :
+#   91/11/23 : pda@masi.ibp.fr, jt@ratp.fr : design
+#   92/08/01 : pda@masi.ibp.fr : cleaning
+
+package require Tk
+
+#
+# Button actions
+#
+
+proc quit {} {
+    destroy .
+}
+
+proc ok {} {
+    writesettings
+    quit
+}
+
+proc cancel {} {
+    readsettings
+    dispsettings
+    .buttons.apply configure -state disabled
+    .buttons.cancel configure -state disabled
+}
+
+proc apply {} {
+    writesettings
+    .buttons.apply configure -state disabled
+    .buttons.cancel configure -state disabled
+}
+
+#
+# Read current settings
+#
+
+proc readsettings {} {
+    global kbdrep ;	set kbdrep	"on"
+    global kbdcli ;	set kbdcli	0
+    global bellvol ;	set bellvol	100
+    global bellpit ;	set bellpit	440
+    global belldur ;	set belldur	100
+    global mouseacc ;	set mouseacc	"3/1"
+    global mousethr ;	set mousethr	4
+    global screenbla ;	set screenbla	"blank"
+    global screentim ;	set screentim	600
+    global screencyc ;	set screencyc	600
+
+    set xfd [open "|xset q" r]
+    while {[gets $xfd line] >= 0} {
+	switch -- [lindex $line 0] {
+	    auto {
+		set rpt [lindex $line 1]
+		if {$rpt eq "repeat:"} {
+		    set kbdrep [lindex $line 2]
+		    set kbdcli [lindex $line 6]
+		}
+	    }
+	    bell {
+		set bellvol [lindex $line 2]
+		set bellpit [lindex $line 5]
+		set belldur [lindex $line 8]
+	    }
+	    acceleration: {
+		set mouseacc [lindex $line 1]
+		set mousethr [lindex $line 3]
+	    }
+	    prefer {
+		set bla [lindex $line 2]
+		set screenbla [expr {$bla eq "yes" ? "blank" : "noblank"}]
+	    }
+	    timeout: {
+		set screentim [lindex $line 1]
+		set screencyc [lindex $line 3]
+	    }
+	}
+    }
+    close $xfd
+
+    # puts stdout [format "Key REPEAT = %s\n" $kbdrep]
+    # puts stdout [format "Key CLICK  = %s\n" $kbdcli]
+    # puts stdout [format "Bell VOLUME = %s\n" $bellvol]
+    # puts stdout [format "Bell PITCH = %s\n" $bellpit]
+    # puts stdout [format "Bell DURATION = %s\n" $belldur]
+    # puts stdout [format "Mouse ACCELERATION = %s\n" $mouseacc]
+    # puts stdout [format "Mouse THRESHOLD = %s\n" $mousethr]
+    # puts stdout [format "Screen BLANCK = %s\n" $screenbla]
+    # puts stdout [format "Screen TIMEOUT = %s\n" $screentim]
+    # puts stdout [format "Screen CYCLE = %s\n" $screencyc]
+}
+
+
+#
+# Write settings into the X server
+#
+
+proc writesettings {} {
+    global kbdrep kbdcli  bellvol bellpit belldur
+    global mouseacc mousethr  screenbla screentim screencyc
+
+    set bellvol		[.bell.vol get]
+    set bellpit		[.bell.val.pit.entry get]
+    set belldur		[.bell.val.dur.entry get]
+
+    if {$kbdrep eq "on"} {
+	set kbdcli	[.kbd.val.cli get]
+    } else {
+	set kbdcli	"off"
+    }
+
+    set mouseacc	[.mouse.hor.acc.entry get]
+    set mousethr	[.mouse.hor.thr.entry get]
+
+    set screentim	[.screen.tim.entry get]
+    set screencyc	[.screen.cyc.entry get]
+
+    exec xset \
+	b $bellvol $bellpit $belldur \
+	c $kbdcli \
+	r $kbdrep \
+	m $mouseacc $mousethr \
+	s $screentim $screencyc \
+	s $screenbla
+}
+
+
+#
+# Sends all settings to the window
+#
+
+proc dispsettings {} {
+    global kbdrep kbdcli  bellvol bellpit belldur
+    global mouseacc mousethr  screenbla screentim screencyc
+
+    .bell.vol set $bellvol
+    .bell.val.pit.entry delete 0 end
+    .bell.val.pit.entry insert 0 $bellpit
+    .bell.val.dur.entry delete 0 end
+    .bell.val.dur.entry insert 0 $belldur
+
+    .kbd.val.onoff [expr {$kbdrep eq "on" ? "select" : "deselect"}]
+    .kbd.val.cli set $kbdcli
+
+    .mouse.hor.acc.entry delete 0 end
+    .mouse.hor.acc.entry insert 0 $mouseacc
+    .mouse.hor.thr.entry delete 0 end
+    .mouse.hor.thr.entry insert 0 $mousethr
+
+    .screen.blank [expr {$screenbla eq "blank" ? "select" : "deselect"}]
+    .screen.pat   [expr {$screenbla ne "blank" ? "select" : "deselect"}]
+    .screen.tim.entry delete 0 end
+    .screen.tim.entry insert 0 $screentim
+    .screen.cyc.entry delete 0 end
+    .screen.cyc.entry insert 0 $screencyc
+}
+
+
+#
+# Create all windows, and pack them
+#
+
+proc labelentry {path text length {range {}}} {
+    frame $path
+    label $path.label -text $text
+    if {[llength $range]} {
+	spinbox $path.entry -width $length -relief sunken \
+		-from [lindex $range 0] -to [lindex $range 1]
+    } else {
+	entry $path.entry -width $length -relief sunken
+    }
+    pack $path.label -side left
+    pack $path.entry -side right -expand y -fill x
+}
+
+proc createwindows {} {
+    #
+    # Buttons
+    #
+
+    frame .buttons
+    button .buttons.ok	   -default active -command ok     -text "Ok"
+    button .buttons.apply  -default normal -command apply  -text "Apply" \
+	    -state disabled
+    button .buttons.cancel -default normal -command cancel -text "Cancel" \
+	    -state disabled
+    button .buttons.quit   -default normal -command quit   -text "Quit"
+
+    pack .buttons.ok .buttons.apply .buttons.cancel .buttons.quit \
+	    -side left -expand yes -pady 5
+
+    bind . <Return> {.buttons.ok   flash; .buttons.ok   invoke}
+    bind . <Escape> {.buttons.quit flash; .buttons.quit invoke}
+    bind . <Button-1> {
+	if {![string match .buttons* %W]} {
+	    .buttons.apply  configure -state normal
+	    .buttons.cancel configure -state normal
+	}
+    }
+    bind . <Key> {
+	if {![string match .buttons* %W]} {
+	    switch -glob %K {
+		Return - Escape - Tab - *Shift* {}
+		default {
+		    .buttons.apply  configure -state normal
+		    .buttons.cancel configure -state normal
+		}
+	    }
+	}
+    }
+
+    #
+    # Bell settings
+    #
+
+    labelframe .bell -text "Bell Settings" -padx 1.5m -pady 1.5m
+    scale .bell.vol \
+	    -from 0 -to 100 -length 200 -tickinterval 20 \
+	    -label "Volume (%)" -orient horizontal
+
+    frame .bell.val
+    labelentry .bell.val.pit "Pitch (Hz)"    6 {25 20000}
+    labelentry .bell.val.dur "Duration (ms)" 6 {1 10000}
+    pack .bell.val.pit -side left -padx 5
+    pack .bell.val.dur -side right -padx 5
+    pack .bell.vol .bell.val -side top -expand yes
+
+    #
+    # Keyboard settings
+    #
+
+    labelframe .kbd -text "Keyboard Repeat Settings" -padx 1.5m -pady 1.5m
+
+    frame .kbd.val
+    checkbutton .kbd.val.onoff \
+	    -text "On" \
+	    -onvalue "on" -offvalue "off" -variable kbdrep \
+	    -relief flat
+    scale .kbd.val.cli \
+	    -from 0 -to 100 -length 200 -tickinterval 20 \
+	    -label "Click Volume (%)" -orient horizontal
+    pack .kbd.val.onoff -side left -fill x -expand yes -padx {0 1m}
+    pack .kbd.val.cli -side left -expand yes -fill x -padx {1m 0}
+
+    pack .kbd.val -side top -expand yes -pady 2 -fill x
+
+    #
+    # Mouse settings
+    #
+
+    labelframe .mouse -text "Mouse Settings" -padx 1.5m -pady 1.5m
+
+    frame .mouse.hor
+    labelentry .mouse.hor.acc "Acceleration" 5
+    labelentry .mouse.hor.thr "Threshold (pixels)" 3 {1 2000}
+
+    pack .mouse.hor.acc -side left -padx {0 1m}
+    pack .mouse.hor.thr -side right -padx {1m 0}
+
+    pack .mouse.hor -side top -expand yes
+
+    #
+    # Screen Saver settings
+    #
+
+    labelframe .screen -text "Screen-saver Settings" -padx 1.5m -pady 1.5m
+
+    radiobutton .screen.blank \
+	    -variable screenblank -text "Blank" -relief flat \
+	    -value "blank" -variable screenbla -anchor w
+    radiobutton .screen.pat \
+	    -variable screenblank -text "Pattern" -relief flat \
+	    -value "noblank" -variable screenbla -anchor w
+    labelentry .screen.tim "Timeout (s)" 5 {1 100000}
+    labelentry .screen.cyc "Cycle (s)" 5 {1 100000}
+
+    grid .screen.blank .screen.tim -sticky e
+    grid .screen.pat   .screen.cyc -sticky e
+    grid configure .screen.blank .screen.pat -sticky ew
+
+    #
+    # Main window
+    #
+
+    pack .buttons -side top -fill both
+    pack .bell .kbd .mouse .screen -side top -fill both -expand yes \
+	    -padx 1m -pady 1m
+
+    #
+    # Let the user resize our window
+    #
+    wm minsize . 10 10
+}
+
+##############################################################################
+# Main program
+
+#
+# Listen what "xset" tells us...
+#
+
+readsettings
+
+#
+# Create all windows
+#
+
+createwindows
+
+#
+# Write xset parameters
+#
+
+dispsettings
+
+#
+# Now, wait for user actions...
+#
+
+# Local Variables:
+# mode: tcl
+# End:

janus/lib/tk8.6/demos/knightstour.tcl

@@ -0,0 +1,268 @@
+# Copyright (C) 2008 Pat Thoyts <patthoyts@users.sourceforge.net>
+#
+#	Calculate a Knight's tour of a chessboard.
+#
+#	This uses Warnsdorff's rule to calculate the next square each
+#	time. This specifies that the next square should be the one that
+#	has the least number of available moves.
+#
+#	Using this rule it is possible to get to a position where
+#	there are no squares available to move into. In this implementation
+#	this occurs when the starting square is d6.
+#
+#	To solve this fault an enhancement to the rule is that if we
+#	have a choice of squares with an equal score, we should choose
+#	the one nearest the edge of the board.
+#
+#	If the call to the Edgemost function is commented out you can see
+#	this occur.
+#
+#	You can drag the knight to a specific square to start if you wish.
+#	If you let it repeat then it will choose random start positions
+#	for each new tour.
+
+package require Tk
+
+# Return a list of accessible squares from a given square
+proc ValidMoves {square} {
+    set moves {}
+    foreach pair {{-1 -2} {-2 -1} {-2 1} {-1 2} {1 2} {2 1} {2 -1} {1 -2}} {
+        set col [expr {($square % 8) + [lindex $pair 0]}]
+        set row [expr {($square / 8) + [lindex $pair 1]}]
+        if {$row >= 0 && $row < 8 && $col >= 0 && $col < 8} {
+            lappend moves [expr {$row * 8 + $col}]
+        }
+    }
+    return $moves
+}
+
+# Return the number of available moves for this square
+proc CheckSquare {square} {
+    variable visited
+    set moves 0
+    foreach test [ValidMoves $square] {
+        if {[lsearch -exact -integer $visited $test] < 0} {
+            incr moves
+        }
+    }
+    return $moves
+}
+
+# Select the next square to move to. Returns -1 if there are no available
+# squares remaining that we can move to.
+proc Next {square} {
+    variable visited
+    set minimum 9
+    set nextSquare -1
+    foreach testSquare [ValidMoves $square] {
+        if {[lsearch -exact -integer $visited $testSquare] < 0} {
+            set count [CheckSquare $testSquare]
+            if {$count < $minimum} {
+                set minimum $count
+                set nextSquare $testSquare
+            } elseif {$count == $minimum} {
+                # to remove the enhancement to Warnsdorff's rule
+                # remove the next line:
+                set nextSquare [Edgemost $nextSquare $testSquare]
+            }
+        }
+    }
+    return $nextSquare
+}
+
+# Select the square nearest the edge of the board
+proc Edgemost {a b} {
+    set colA [expr {3-int(abs(3.5-($a%8)))}]
+    set colB [expr {3-int(abs(3.5-($b%8)))}]
+    set rowA [expr {3-int(abs(3.5-($a/8)))}]
+    set rowB [expr {3-int(abs(3.5-($b/8)))}]
+    return [expr {($colA * $rowA) < ($colB * $rowB) ? $a : $b}]
+}
+
+# Display a square number as a standard chess square notation.
+proc N {square} {
+    return [format %c%d [expr {97 + $square % 8}] \
+                [expr {$square / 8 + 1}]]
+}
+
+# Perform a Knight's move and schedule the next move.
+proc MovePiece {dlg last square} {
+    variable visited
+    variable delay
+    variable continuous
+    $dlg.f.txt insert end "[llength $visited]. [N $last] .. [N $square]\n" {}
+    $dlg.f.txt see end
+    $dlg.f.c itemconfigure [expr {1+$last}] -state normal -outline black
+    $dlg.f.c itemconfigure [expr {1+$square}] -state normal -outline red
+    $dlg.f.c moveto knight {*}[lrange [$dlg.f.c coords [expr {1+$square}]] 0 1]
+    lappend visited $square
+    set next [Next $square]
+    if {$next ne -1} {
+        variable aid [after $delay [list MovePiece $dlg $square $next]]
+    } else {
+        $dlg.tf.b1 configure -state normal
+        if {[llength $visited] == 64} {
+            variable initial
+            if {$initial == $square} {
+                $dlg.f.txt insert end "Closed tour!"
+            } else {
+                $dlg.f.txt insert end "Success\n" {}
+                if {$continuous} {
+                    after [expr {$delay * 2}] [namespace code \
+                        [list Tour $dlg [expr {int(rand() * 64)}]]]
+                }
+            }
+        } else {
+            $dlg.f.txt insert end "FAILED!\n" {}
+        }
+    }
+}
+
+# Begin a new tour of the board given a random start position
+proc Tour {dlg {square {}}} {
+    variable visited {}
+    $dlg.f.txt delete 1.0 end
+    $dlg.tf.b1 configure -state disabled
+    for {set n 0} {$n < 64} {incr n} {
+        $dlg.f.c itemconfigure $n -state disabled -outline black
+    }
+    if {$square eq {}} {
+        set coords [lrange [$dlg.f.c coords knight] 0 1]
+        set square [expr {[$dlg.f.c find closest {*}$coords 0 65]-1}]
+    }
+    variable initial $square
+    after idle [list MovePiece $dlg $initial $initial]
+}
+
+proc Stop {} {
+    variable aid
+    catch {after cancel $aid}
+}
+
+proc Exit {dlg} {
+    Stop
+    destroy $dlg
+}
+
+proc SetDelay {new} {
+    variable delay [expr {int($new)}]
+}
+
+proc DragStart {w x y} {
+    $w dtag selected
+    $w addtag selected withtag current
+    variable dragging [list $x $y]
+}
+proc DragMotion {w x y} {
+    variable dragging
+    if {[info exists dragging]} {
+        $w move selected [expr {$x - [lindex $dragging 0]}] \
+            [expr {$y - [lindex $dragging 1]}]
+        variable dragging [list $x $y]
+    }
+}
+proc DragEnd {w x y} {
+    set square [$w find closest $x $y 0 65]
+    $w moveto selected {*}[lrange [$w coords $square] 0 1]
+    $w dtag selected
+    variable dragging ; unset dragging
+}
+
+proc CreateGUI {} {
+    catch {destroy .knightstour}
+    set dlg [toplevel .knightstour]
+    wm title $dlg "Knights tour"
+    wm withdraw $dlg
+    set f [ttk::frame $dlg.f]
+    set c [canvas $f.c -width 240 -height 240]
+    text $f.txt -width 10 -height 1 \
+        -yscrollcommand [list $f.vs set] -font {Arial 8}
+    ttk::scrollbar $f.vs -command [list $f.txt yview]
+
+    variable delay 600
+    variable continuous 0
+    ttk::frame $dlg.tf
+    ttk::label $dlg.tf.ls -text Speed
+    ttk::scale $dlg.tf.sc  -from 8 -to 2000 -command [list SetDelay] \
+        -variable [namespace which -variable delay]
+    ttk::checkbutton $dlg.tf.cc -text Repeat \
+        -variable [namespace which -variable continuous]
+    ttk::button $dlg.tf.b1 -text Start -command [list Tour $dlg]
+    ttk::button $dlg.tf.b2 -text Exit -command [list Exit $dlg]
+    set square 0
+    for {set row 7} {$row >= 0} {incr row -1} {
+        for {set col 0} {$col < 8} {incr col} {
+            if {(($col & 1) ^ ($row & 1))} {
+                set fill tan3 ; set dfill tan4
+            } else {
+                set fill bisque ; set dfill bisque3
+            }
+            set coords [list [expr {$col * 30 + 4}] [expr {$row * 30 + 4}] \
+                            [expr {$col * 30 + 30}] [expr {$row * 30 + 30}]]
+            $c create rectangle $coords -fill $fill -disabledfill $dfill \
+                -width 2 -state disabled -outline black
+        }
+    }
+    if {[tk windowingsystem] ne "x11"} {
+        catch {eval font create KnightFont -size -24}
+        $c create text 0 0 -font KnightFont -text "\u265e" \
+            -anchor nw -tags knight -fill black -activefill "#600000"
+    } else {
+        # On X11 we cannot reliably tell if the \u265e glyph is available
+        # so just use a polygon
+        set pts {
+            2 25   24 25  21 19   20 8   14 0   10 0   0 13   0 16
+            2 17    4 14   5 15    3 17   5 17   9 14  10 15  5 21
+        }
+        $c create polygon $pts -tag knight -offset 8 \
+            -fill black -activefill "#600000"
+    }
+    $c moveto knight {*}[lrange [$c coords [expr {1 + int(rand() * 64)}]] 0 1]
+    $c bind knight <Button-1> [namespace code [list DragStart %W %x %y]]
+    $c bind knight <Motion> [namespace code [list DragMotion %W %x %y]]
+    $c bind knight <ButtonRelease-1> [namespace code [list DragEnd %W %x %y]]
+
+    grid $c $f.txt $f.vs  -sticky news
+    grid rowconfigure    $f 0 -weight 1
+    grid columnconfigure $f 1 -weight 1
+
+    grid $f - - - - - -sticky news
+    set things [list $dlg.tf.ls $dlg.tf.sc $dlg.tf.cc $dlg.tf.b1]
+    if {![info exists ::widgetDemo]} {
+	lappend things $dlg.tf.b2
+	if {[tk windowingsystem] ne "aqua"} {
+	    set things [linsert $things 0 [ttk::sizegrip $dlg.tf.sg]]
+	}
+    }
+    pack {*}$things -side right
+    if {[tk windowingsystem] eq "aqua"} {
+	pack configure {*}$things -padx {4 4} -pady {12 12}
+	pack configure [lindex $things 0] -padx {4 24}
+	pack configure [lindex $things end] -padx {16 4}
+    }
+    grid $dlg.tf  - - - - - -sticky ew
+    if {[info exists ::widgetDemo]} {
+        grid [addSeeDismiss $dlg.buttons $dlg] - - - - - -sticky ew
+    }
+
+    grid rowconfigure $dlg 0 -weight 1
+    grid columnconfigure $dlg 0 -weight 1
+
+    bind $dlg <Control-F2> {console show}
+    bind $dlg <Return> [list $dlg.tf.b1 invoke]
+    bind $dlg <Escape> [list $dlg.tf.b2 invoke]
+    bind $dlg <Destroy> [namespace code [list Stop]]
+    wm protocol $dlg WM_DELETE_WINDOW [namespace code [list Exit $dlg]]
+
+    wm deiconify $dlg
+    tkwait window $dlg
+}
+
+if {![winfo exists .knightstour]} {
+    if {![info exists widgetDemo]} { wm withdraw . }
+    set r [catch [linsert $argv 0 CreateGUI] err]
+    if {$r} {
+	tk_messageBox -icon error -title "Error" -message $err
+    }
+    if {![info exists widgetDemo]} { exit $r }
+}

janus/lib/tk8.6/demos/labelframe.tcl

@@ -0,0 +1,76 @@
+# labelframe.tcl --
+#
+# This demonstration script creates a toplevel window containing
+# several labelframe widgets.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .labelframe
+catch {destroy $w}
+toplevel $w
+wm title $w "Labelframe Demonstration"
+wm iconname $w "labelframe"
+positionWindow $w
+
+# Some information
+
+label $w.msg -font $font -wraplength 4i -justify left -text "Labelframes are\
+	used to group related widgets together.  The label may be either \
+	plain text or another widget."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+# Demo area
+
+frame $w.f
+pack $w.f -side bottom -fill both -expand 1
+set w $w.f
+
+# A group of radiobuttons in a labelframe
+
+labelframe $w.f -text "Value" -padx 2 -pady 2
+grid $w.f -row 0 -column 0 -pady 2m -padx 2m
+
+foreach value {1 2 3 4} {
+    radiobutton $w.f.b$value -text "This is value $value" \
+            -variable lfdummy -value $value
+    pack $w.f.b$value -side top -fill x -pady 2
+}
+
+
+# Using a label window to control a group of options.
+
+proc lfEnableButtons {w} {
+    foreach child [winfo children $w] {
+        if {$child == "$w.cb"} continue
+        if {$::lfdummy2} {
+            $child configure -state normal
+        } else {
+            $child configure -state disabled
+        }
+    }
+}
+
+labelframe $w.f2 -pady 2 -padx 2
+checkbutton $w.f2.cb -text "Use this option." -variable lfdummy2 \
+        -command "lfEnableButtons $w.f2" -padx 0
+$w.f2 configure -labelwidget $w.f2.cb
+grid $w.f2 -row 0 -column 1 -pady 2m -padx 2m
+
+set t 0
+foreach str {Option1 Option2 Option3} {
+    checkbutton $w.f2.b$t -text $str
+    pack $w.f2.b$t -side top -fill x -pady 2
+    incr t
+}
+lfEnableButtons $w.f2
+
+
+grid columnconfigure $w {0 1} -weight 1

janus/lib/tk8.6/demos/menu.tcl

@@ -0,0 +1,177 @@
+# menu.tcl --
+#
+# This demonstration script creates a window with a bunch of menus
+# and cascaded menus using menubars.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .menu
+catch {destroy $w}
+toplevel $w
+wm title $w "Menu Demonstration"
+wm iconname $w "menu"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left
+if {[tk windowingsystem] eq "aqua"} {
+    $w.msg configure -text "This window has a menubar with cascaded menus.  You can invoke entries with an accelerator by typing Command+x, where \"x\" is the character next to the command key symbol. The rightmost menu can be torn off into a palette by selecting the first item in the menu."
+} else {
+    $w.msg configure -text "This window contains a menubar with cascaded menus.  You can post a menu from the keyboard by typing Alt+x, where \"x\" is the character underlined on the menu.  You can then traverse among the menus using the arrow keys.  When a menu is posted, you can invoke the current entry by typing space, or you can invoke any entry by typing its underlined character.  If a menu entry has an accelerator, you can invoke the entry without posting the menu just by typing the accelerator. The rightmost menu can be torn off into a palette by selecting the first item in the menu."
+}
+pack $w.msg -side top
+
+set menustatus "    "
+frame $w.statusBar
+label $w.statusBar.label -textvariable menustatus -relief sunken -bd 1 -font "Helvetica 10" -anchor w
+pack $w.statusBar.label -side left -padx 2 -expand yes -fill both
+pack $w.statusBar -side bottom -fill x -pady 2
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+menu $w.menu -tearoff 0
+
+set m $w.menu.file
+menu $m -tearoff 0
+$w.menu add cascade -label "File" -menu $m -underline 0
+$m add command -label "Open..." -command {error "this is just a demo: no action has been defined for the \"Open...\" entry"}
+$m add command -label "New" -command {error "this is just a demo: no action has been defined for the \"New\" entry"}
+$m add command -label "Save" -command {error "this is just a demo: no action has been defined for the \"Save\" entry"}
+$m add command -label "Save As..." -command {error "this is just a demo: no action has been defined for the \"Save As...\" entry"}
+$m add separator
+$m add command -label "Print Setup..." -command {error "this is just a demo: no action has been defined for the \"Print Setup...\" entry"}
+$m add command -label "Print..." -command {error "this is just a demo: no action has been defined for the \"Print...\" entry"}
+$m add separator
+$m add command -label "Dismiss Menus Demo" -command "destroy $w"
+
+set m $w.menu.basic
+$w.menu add cascade -label "Basic" -menu $m -underline 0
+menu $m -tearoff 0
+$m add command -label "Long entry that does nothing"
+if {[tk windowingsystem] eq "aqua"} {
+    set modifier Command
+} elseif {[tk windowingsystem] eq "win32"} {
+    set modifier Control
+} else {
+    set modifier Meta
+}
+foreach i {A B C D E F} {
+    $m add command -label "Print letter \"$i\"" -underline 14 \
+	    -accelerator $modifier+$i -command "puts $i"
+    bind $w <$modifier-[string tolower $i]> "puts $i"
+}
+
+set m $w.menu.cascade
+$w.menu add cascade -label "Cascades" -menu $m -underline 0
+menu $m -tearoff 0
+$m add command -label "Print hello" \
+	-command {puts stdout "Hello"} -accelerator $modifier+H -underline 6
+bind $w <$modifier-h> {puts stdout "Hello"}
+$m add command -label "Print goodbye" -command {\
+    puts stdout "Goodbye"} -accelerator $modifier+G -underline 6
+bind $w <$modifier-g> {puts stdout "Goodbye"}
+$m add cascade -label "Check buttons" \
+	-menu $w.menu.cascade.check -underline 0
+$m add cascade -label "Radio buttons" \
+	-menu $w.menu.cascade.radio -underline 0
+
+set m $w.menu.cascade.check
+menu $m -tearoff 0
+$m add check -label "Oil checked" -variable oil
+$m add check -label "Transmission checked" -variable trans
+$m add check -label "Brakes checked" -variable brakes
+$m add check -label "Lights checked" -variable lights
+$m add separator
+$m add command -label "Show current values" \
+    -command "showVars $w.menu.cascade.dialog oil trans brakes lights"
+$m invoke 1
+$m invoke 3
+
+set m $w.menu.cascade.radio
+menu $m -tearoff 0
+$m add radio -label "10 point" -variable pointSize -value 10
+$m add radio -label "14 point" -variable pointSize -value 14
+$m add radio -label "18 point" -variable pointSize -value 18
+$m add radio -label "24 point" -variable pointSize -value 24
+$m add radio -label "32 point" -variable pointSize -value 32
+$m add sep
+$m add radio -label "Roman" -variable style -value roman
+$m add radio -label "Bold" -variable style -value bold
+$m add radio -label "Italic" -variable style -value italic
+$m add sep
+$m add command -label "Show current values" \
+	-command "showVars $w.menu.cascade.dialog pointSize style"
+$m invoke 1
+$m invoke 7
+
+set m $w.menu.icon
+$w.menu add cascade -label "Icons" -menu $m -underline 0
+menu $m -tearoff 0
+# Main widget program sets variable tk_demoDirectory
+image create photo lilearth -file [file join $tk_demoDirectory \
+images earthmenu.png]
+$m add command -image lilearth \
+    -hidemargin 1 -command [list \
+	tk_dialog $w.pattern {Bitmap Menu Entry} \
+		"The menu entry you invoked displays a photoimage rather than\
+		a text string.  Other than this, it is just like any other\
+		menu entry." {} 0 OK ]
+foreach i {info questhead error} {
+    $m add command -bitmap $i -hidemargin 1 -command [list \
+	    puts "You invoked the $i bitmap" ]
+}
+$m entryconfigure 2 -columnbreak 1
+
+set m $w.menu.more
+$w.menu add cascade -label "More" -menu $m -underline 0
+menu $m -tearoff 0
+foreach i {{An entry} {Another entry} {Does nothing} {Does almost nothing} {Make life meaningful}} {
+    $m add command -label $i -command [list puts "You invoked \"$i\""]
+}
+set emojiLabel [encoding convertfrom utf-8 "\xF0\x9F\x98\x8D Make friends"]
+$m add command -label $emojiLabel -command [list puts "Menu labels can include non-BMP characters."]
+$m entryconfigure "Does almost nothing" -bitmap questhead -compound left \
+	-command [list \
+	tk_dialog $w.compound {Compound Menu Entry} \
+		"The menu entry you invoked displays both a bitmap and a\
+		text string.  Other than this, it is just like any other\
+		menu entry." {} 0 OK ]
+
+set m $w.menu.colors
+$w.menu add cascade -label "Colors" -menu $m -underline 1
+menu $m -tearoff 1
+if {[tk windowingsystem] eq "aqua"} {
+    # Aqua ignores the -background and -foreground options, but a compound
+    # button can be used for selecting colors.
+    foreach i {red orange yellow green blue} {
+	image create photo image_$i -height 16 -width 16
+	image_$i put black -to 0 0 16 1
+	image_$i put black -to 0 1 1 16
+	image_$i put black -to 0 15 16 16
+	image_$i put black -to 15 1 16 16
+	image_$i put $i -to 1 1 15 15
+	$m add command -label $i -image image_$i -compound left -command [list \
+	puts "You invoked \"$i\"" ]
+    }
+} else {
+    foreach i {red orange yellow green blue} {
+	$m add command -label $i -background $i -command [list \
+	puts "You invoked \"$i\"" ]
+    }
+}
+
+$w configure -menu $w.menu
+
+bind Menu <<MenuSelect>> {
+    global $menustatus
+    if {[catch {%W entrycget active -label} label]} {
+	set label "    "
+    }
+    set menustatus $label
+    update idletasks
+}

janus/lib/tk8.6/demos/msgbox.tcl

@@ -0,0 +1,62 @@
+# msgbox.tcl --
+#
+# This demonstration script creates message boxes of various type
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .msgbox
+catch {destroy $w}
+toplevel $w
+wm title $w "Message Box Demonstration"
+wm iconname $w "messagebox"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "Choose the icon and type option of the message box. Then press the \"Message Box\" button to see the message box."
+pack $w.msg -side top
+
+pack [addSeeDismiss $w.buttons $w {} {
+    ttk::button $w.buttons.vars -text "Message Box" -command "showMessageBox $w"
+}] -side bottom -fill x
+#pack $w.buttons.dismiss $w.buttons.code $w.buttons.vars -side left -expand 1
+
+frame $w.left
+frame $w.right
+pack $w.left $w.right -side left -expand yes -fill y  -pady .5c -padx .5c
+
+label $w.left.label -text "Icon"
+frame $w.left.sep -relief ridge -bd 1 -height 2
+pack $w.left.label -side top
+pack $w.left.sep -side top -fill x -expand no
+
+set msgboxIcon info
+foreach i {error info question warning} {
+    radiobutton $w.left.b$i -text $i -variable msgboxIcon \
+	-relief flat -value $i -width 16 -anchor w
+    pack $w.left.b$i  -side top -pady 2 -anchor w -fill x
+}
+
+label $w.right.label -text "Type"
+frame $w.right.sep -relief ridge -bd 1 -height 2
+pack $w.right.label -side top
+pack $w.right.sep -side top -fill x -expand no
+
+set msgboxType ok
+foreach t {abortretryignore ok okcancel retrycancel yesno yesnocancel} {
+    radiobutton $w.right.$t -text $t -variable msgboxType \
+	-relief flat -value $t -width 16 -anchor w
+    pack $w.right.$t -side top -pady 2 -anchor w -fill x
+}
+
+proc showMessageBox {w} {
+    global msgboxIcon msgboxType
+    set button [tk_messageBox -icon $msgboxIcon -type $msgboxType \
+	-title Message -parent $w\
+	-message "This is a \"$msgboxType\" type messagebox with the \"$msgboxIcon\" icon"]
+
+    tk_messageBox -icon info -message "You have selected \"$button\"" -type ok\
+	-parent $w
+}

janus/lib/tk8.6/demos/nl.msg

@@ -0,0 +1,125 @@
+::msgcat::mcset nl "Widget Demonstration" "Demonstratie van widgets"
+::msgcat::mcset nl "tkWidgetDemo" "tkWidgetDemo"
+::msgcat::mcset nl "&File"     "&Bestand"
+::msgcat::mcset nl "About..."  "Info..."
+::msgcat::mcset nl "&About..." "&Info..."
+::msgcat::mcset nl "<F1>"      "<F1>"
+::msgcat::mcset nl "&Quit"     "&Einde"
+::msgcat::mcset nl "Meta+Q"    "Meta+E"		;# Displayed hotkey
+::msgcat::mcset nl "Meta-q"    "Meta-e"		;# Actual binding sequence
+::msgcat::mcset nl "Ctrl+Q"    "Ctrl+E"		;# Displayed hotkey
+::msgcat::mcset nl "Control-q" "Control-e"	;# Actual binding sequence
+::msgcat::mcset nl "Dismiss"   "Sluiten"
+::msgcat::mcset nl "See Variables"    "Bekijk Variabelen"
+::msgcat::mcset nl "Variable Values"  "Waarden Variabelen"
+::msgcat::mcset nl "OK"        "OK"
+::msgcat::mcset nl "Run the \"%s\" sample program" "Start voorbeeld \"%s\""
+::msgcat::mcset nl "Print Code" "Code Afdrukken"
+::msgcat::mcset nl "Demo code: %s" "Code van Demo %s"
+::msgcat::mcset nl "About Widget Demo" "Over deze demonstratie"
+::msgcat::mcset nl "Tk widget demonstration" "Demonstratie van Tk widgets"
+::msgcat::mcset nl "Copyright © %s"
+
+::msgcat::mcset nl "Tk Widget Demonstrations" "Demonstratie van Tk widgets"
+::msgcat::mcset nl "This application provides a front end for several short scripts" \
+    "Dit programma is een schil rond enkele korte scripts waarmee"
+::msgcat::mcset nl "that demonstrate what you can do with Tk widgets.  Each of the" \
+    "gedemonstreerd wordt wat je kunt doen met Tk widgets.  Elk van de"
+::msgcat::mcset nl "numbered lines below describes a demonstration;  you can click on" \
+    "genummerde regels hieronder omschrijft een demonstratie;  je kunt de"
+::msgcat::mcset nl "it to invoke the demonstration.  Once the demonstration window" \
+    "demonstratie starten door op de regel te klikken."
+::msgcat::mcset nl "appears, you can click the" \
+    "Zodra het nieuwe venster verschijnt, kun je op de knop"
+::msgcat::mcset nl "See Code"  "Bekijk Code"	;# This is also button text!
+::msgcat::mcset nl "button to see the Tcl/Tk code that created the demonstration.  If" \
+    "drukken om de achterliggende Tcl/Tk code te zien.  Als je dat wilt,"
+::msgcat::mcset nl "you wish, you can edit the code and click the" \
+    "kun je de code wijzigen en op de knop"
+::msgcat::mcset nl "Rerun Demo" "Herstart Demo"	;# This is also button text!
+::msgcat::mcset nl "button in the code window to reinvoke the demonstration with the" \
+    "drukken in het codevenster om de demonstratie uit te voeren met de"
+::msgcat::mcset nl "modified code." \
+    "nieuwe code."
+
+::msgcat::mcset nl "Labels, buttons, checkbuttons, and radiobuttons" \
+    "Labels, knoppen, vinkjes/aankruishokjes en radioknoppen"
+
+::msgcat::mcset nl "Labels (text and bitmaps)" "Labels (tekst en plaatjes)"
+::msgcat::mcset nl "Labels and UNICODE text"   "Labels en tekst in UNICODE"
+::msgcat::mcset nl "Buttons" "Buttons (drukknoppen)"
+::msgcat::mcset nl "Check-buttons (select any of a group)" \
+    "Check-buttons (een of meer uit een groep)"
+::msgcat::mcset nl "Radio-buttons (select one of a group)" \
+    "Radio-buttons (een van een groep)"
+::msgcat::mcset nl "A 15-puzzle game made out of buttons" \
+    "Een schuifpuzzel van buttons"
+::msgcat::mcset nl "Iconic buttons that use bitmaps" \
+    "Buttons met pictogrammen"
+::msgcat::mcset nl "Two labels displaying images" \
+    "Twee labels met plaatjes in plaats van tekst"
+::msgcat::mcset nl "A simple user interface for viewing images" \
+    "Een eenvoudige user-interface voor het bekijken van plaatjes"
+::msgcat::mcset nl "Labelled frames" \
+    "Kaders met bijschrift"
+
+::msgcat::mcset nl "Listboxes" "Keuzelijsten"
+::msgcat::mcset nl "The 50 states" "De 50 staten van de VS"
+::msgcat::mcset nl "Colors: change the color scheme for the application" \
+         "Kleuren: verander het kleurenschema voor het programma"
+::msgcat::mcset nl "A collection of famous and infamous sayings" \
+         "Beroemde en beruchte citaten en gezegden"
+
+::msgcat::mcset nl "Entries and Spin-boxes"     "Invulvelden en Spinboxen"
+::msgcat::mcset nl "Entries without scrollbars" "Invulvelden zonder schuifbalk"
+::msgcat::mcset nl "Entries with scrollbars"    "Invulvelden met schuifbalk"
+::msgcat::mcset nl "Validated entries and password fields" \
+         "Invulvelden met controle of wachtwoorden"
+::msgcat::mcset nl "Spin-boxes" "Spinboxen"
+::msgcat::mcset nl "Simple Rolodex-like form" "Simpel kaartsysteem"
+
+::msgcat::mcset nl "Text" "Tekst"
+::msgcat::mcset nl "Basic editable text" "Voorbeeld met te wijzigen tekst"
+::msgcat::mcset nl "Text display styles" "Tekst met verschillende stijlen"
+::msgcat::mcset nl "Hypertext (tag bindings)" \
+    "Hypertext (verwijzingen via \"tags\")"
+::msgcat::mcset nl "A text widget with embedded windows" \
+    "Tekstwidget met windows erin"
+::msgcat::mcset nl "A search tool built with a text widget" \
+    "Zoeken in tekst met behulp van een tekstwidget"
+
+::msgcat::mcset nl "Canvases" "Canvaswidgets"
+::msgcat::mcset nl "The canvas item types"     "Objecten in een canvas"
+::msgcat::mcset nl "A simple 2-D plot"         "Eenvoudige 2D-grafiek"
+::msgcat::mcset nl "Text items in canvases"    "Tekstobjecten in een canvas"
+::msgcat::mcset nl "An editor for arrowheads on canvas lines" \
+    "Editor voor de vorm van de pijl (begin/eind van een lijn)"
+::msgcat::mcset nl "A ruler with adjustable tab stops" \
+    "Een meetlat met aanpasbare ruiters"
+::msgcat::mcset nl "A building floor plan"     "Plattegrond van een gebouw"
+::msgcat::mcset nl "A simple scrollable canvas" "Een schuifbaar canvas"
+
+::msgcat::mcset nl "Scales" "Schaalverdelingen"
+::msgcat::mcset nl "Horizontal scale"          "Horizontale schaal"
+::msgcat::mcset nl "Vertical scale"          "Verticale schaal"
+
+::msgcat::mcset nl "Paned Windows" "Vensters opgedeeld in stukken"
+::msgcat::mcset nl "Horizontal paned window"   "Horizontaal gedeeld venster"
+::msgcat::mcset nl "Vertical paned window"     "Verticaal gedeeld venster"
+
+::msgcat::mcset nl "Menus" "Menu's"
+::msgcat::mcset nl "Menus and cascades (sub-menus)" \
+    "Menu's en cascades (submenu's)"
+::msgcat::mcset nl "Menu-buttons" "Menu-buttons"
+
+::msgcat::mcset nl "Common Dialogs" "Veel voorkomende dialoogvensters"
+::msgcat::mcset nl "Message boxes"  "Mededeling (message box)"
+::msgcat::mcset nl "File selection dialog"     "Selectie van bestanden"
+::msgcat::mcset nl "Color picker"              "Kleurenpalet"
+
+::msgcat::mcset nl "Miscellaneous"             "Diversen"
+::msgcat::mcset nl "The built-in bitmaps"      "Ingebouwde plaatjes"
+::msgcat::mcset nl "A dialog box with a local grab" \
+    "Een dialoogvenster met een locale \"grab\""
+::msgcat::mcset nl "A dialog box with a global grab" \
+    "Een dialoogvenster met een globale \"grab\""

janus/lib/tk8.6/demos/paned1.tcl

@@ -0,0 +1,32 @@
+# paned1.tcl --
+#
+# This demonstration script creates a toplevel window containing
+# a paned window that separates two windows horizontally.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .paned1
+catch {destroy $w}
+toplevel $w
+wm title $w "Horizontal Paned Window Demonstration"
+wm iconname $w "paned1"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "The sash between the two coloured windows below can be used to divide the area between them.  Use the left mouse button to resize without redrawing by just moving the sash, and use the middle mouse button to resize opaquely (always redrawing the windows in each position.)"
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+panedwindow $w.pane
+pack $w.pane -side top -expand yes -fill both -pady 2 -padx 2m
+
+label $w.pane.left  -text "This is the\nleft side"  -fg black -bg yellow
+label $w.pane.right -text "This is the\nright side" -fg black -bg cyan
+
+$w.pane add $w.pane.left $w.pane.right

janus/lib/tk8.6/demos/paned2.tcl

@@ -0,0 +1,74 @@
+# paned2.tcl --
+#
+# This demonstration script creates a toplevel window containing
+# a paned window that separates two windows vertically.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .paned2
+catch {destroy $w}
+toplevel $w
+wm title $w "Vertical Paned Window Demonstration"
+wm iconname $w "paned2"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "The sash between the two scrolled windows below can be used to divide the area between them.  Use the left mouse button to resize without redrawing by just moving the sash, and use the middle mouse button to resize opaquely (always redrawing the windows in each position.)"
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+# Create the pane itself
+panedwindow $w.pane -orient vertical
+pack $w.pane -side top -expand yes -fill both -pady 2 -padx 2m
+
+# The top window is a listbox with scrollbar
+set paneList {
+    {List of Tk Widgets}
+    button
+    canvas
+    checkbutton
+    entry
+    frame
+    label
+    labelframe
+    listbox
+    menu
+    menubutton
+    message
+    panedwindow
+    radiobutton
+    scale
+    scrollbar
+    spinbox
+    text
+    toplevel
+}
+set f [frame $w.pane.top]
+listbox $f.list -listvariable paneList -yscrollcommand "$f.scr set"
+# Invert the first item to highlight it
+$f.list itemconfigure 0 \
+	-background [$f.list cget -fg] -foreground [$f.list cget -bg]
+ttk::scrollbar $f.scr -orient vertical -command "$f.list yview"
+pack $f.scr -side right -fill y
+pack $f.list -fill both -expand 1
+
+# The bottom window is a text widget with scrollbar
+set f [frame $w.pane.bottom]
+text $f.text -xscrollcommand "$f.xscr set" -yscrollcommand "$f.yscr set" \
+	-width 30 -height 8 -wrap none
+ttk::scrollbar $f.xscr -orient horizontal -command "$f.text xview"
+ttk::scrollbar $f.yscr -orient vertical -command "$f.text yview"
+grid $f.text $f.yscr -sticky nsew
+grid $f.xscr         -sticky nsew
+grid columnconfigure $f 0 -weight 1
+grid rowconfigure    $f 0 -weight 1
+$f.text insert 1.0 "This is just a normal text widget"
+
+# Now add our contents to the paned window
+$w.pane add $w.pane.top $w.pane.bottom

janus/lib/tk8.6/demos/pendulum.tcl

@@ -0,0 +1,197 @@
+# pendulum.tcl --
+#
+# This demonstration illustrates how Tcl/Tk can be used to construct
+# simulations of physical systems.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .pendulum
+catch {destroy $w}
+toplevel $w
+wm title $w "Pendulum Animation Demonstration"
+wm iconname $w "pendulum"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "This demonstration shows how Tcl/Tk can be used to carry out animations that are linked to simulations of physical systems. In the left canvas is a graphical representation of the physical system itself, a simple pendulum, and in the right canvas is a graph of the phase space of the system, which is a plot of the angle (relative to the vertical) against the angular velocity. The pendulum bob may be repositioned by clicking and dragging anywhere on the left canvas."
+pack $w.msg
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+# Create some structural widgets
+pack [panedwindow $w.p] -fill both -expand 1
+$w.p add [labelframe $w.p.l1 -text "Pendulum Simulation"]
+$w.p add [labelframe $w.p.l2 -text "Phase Space"]
+
+# Create the canvas containing the graphical representation of the
+# simulated system.
+canvas $w.c -width 320 -height 200 -background white -bd 2 -relief sunken
+$w.c create text 5 5 -anchor nw -text "Click to Adjust Bob Start Position"
+# Coordinates of these items don't matter; they will be set properly below
+$w.c create line 0 25 320 25   -tags plate -fill grey50 -width 2
+$w.c create oval 155 20 165 30 -tags pivot -fill grey50 -outline {}
+$w.c create line 1 1 1 1       -tags rod   -fill black  -width 3
+$w.c create oval 1 1 2 2       -tags bob   -fill yellow -outline black
+pack $w.c -in $w.p.l1 -fill both -expand true
+
+# Create the canvas containing the phase space graph; this consists of
+# a line that gets gradually paler as it ages, which is an extremely
+# effective visual trick.
+canvas $w.k -width 320 -height 200 -background white -bd 2 -relief sunken
+$w.k create line 160 200 160 0 -fill grey75 -arrow last -tags y_axis
+$w.k create line 0 100 320 100 -fill grey75 -arrow last -tags x_axis
+for {set i 90} {$i>=0} {incr i -10} {
+    # Coordinates of these items don't matter; they will be set properly below
+    $w.k create line 0 0 1 1 -smooth true -tags graph$i -fill grey$i
+}
+
+$w.k create text 0 0 -anchor ne -text "\u03b8" -tags label_theta
+$w.k create text 0 0 -anchor ne -text "\u03b4\u03b8" -tags label_dtheta
+pack $w.k -in $w.p.l2 -fill both -expand true
+
+# Initialize some variables
+set points {}
+set Theta   45.0
+set dTheta   0.0
+set pi       3.1415926535897933
+set length 150
+set home   160
+
+# This procedure makes the pendulum appear at the correct place on the
+# canvas. If the additional arguments "at $x $y" are passed (the 'at'
+# is really just syntactic sugar) instead of computing the position of
+# the pendulum from the length of the pendulum rod and its angle, the
+# length and angle are computed in reverse from the given location
+# (which is taken to be the centre of the pendulum bob.)
+proc showPendulum {canvas {at {}} {x {}} {y {}}} {
+    global Theta dTheta pi length home
+    if {$at eq "at" && ($x!=$home || $y!=25)} {
+	set dTheta 0.0
+	set x2 [expr {$x - $home}]
+	set y2 [expr {$y - 25}]
+	set length [expr {hypot($x2, $y2)}]
+	set Theta  [expr {atan2($x2, $y2) * 180/$pi}]
+    } else {
+	set angle [expr {$Theta * $pi/180}]
+	set x [expr {$home + $length*sin($angle)}]
+	set y [expr {25    + $length*cos($angle)}]
+    }
+    $canvas coords rod $home 25 $x $y
+    $canvas coords bob [expr {$x - 15}] [expr {$y - 15}] \
+	    [expr {$x + 15}] [expr {$y + 15}]
+}
+showPendulum $w.c
+
+# Update the phase-space graph according to the current angle and the
+# rate at which the angle is changing (the first derivative with
+# respect to time.)
+proc showPhase {canvas} {
+    global Theta dTheta points psw psh
+    lappend points [expr {$Theta + $psw}] [expr {-20*$dTheta + $psh}]
+    if {[llength $points] > 100} {
+    	 set points [lrange $points end-99 end]
+    }
+    for {set i 0} {$i<100} {incr i 10} {
+	set list [lrange $points end-[expr {$i-1}] end-[expr {$i-12}]]
+	if {[llength $list] >= 4} {
+	    $canvas coords graph$i $list
+	}
+    }
+}
+
+# Set up some bindings on the canvases.  Note that when the user
+# clicks we stop the animation until they release the mouse
+# button. Also note that both canvases are sensitive to <Configure>
+# events, which allows them to find out when they have been resized by
+# the user.
+bind $w.c <Destroy> {
+    after cancel $animationCallbacks(pendulum)
+    unset animationCallbacks(pendulum)
+}
+bind $w.c <Button-1> {
+    after cancel $animationCallbacks(pendulum)
+    showPendulum %W at %x %y
+}
+bind $w.c <B1-Motion> {
+    showPendulum %W at %x %y
+}
+bind $w.c <ButtonRelease-1> {
+    showPendulum %W at %x %y
+    set animationCallbacks(pendulum) [after 15 repeat [winfo toplevel %W]]
+}
+bind $w.c <Configure> {
+    %W coords plate 0 25 %w 25
+    set home [expr {%w/2}]
+    %W coords pivot [expr {$home - 5}] 20 [expr {$home + 5}] 30
+}
+bind $w.k <Configure> {
+    set psh [expr {%h/2}]
+    set psw [expr {%w/2}]
+    %W coords x_axis 2 $psh [expr {%w - 2}] $psh
+    %W coords y_axis $psw [expr {%h - 2}] $psw 2
+    %W coords label_dtheta [expr {$psw - 4}] 6
+    %W coords label_theta [expr {%w - 6}] [expr {$psh + 4}]
+}
+
+# This procedure is the "business" part of the simulation that does
+# simple numerical integration of the formula for a simple rotational
+# pendulum.
+proc recomputeAngle {} {
+    global Theta dTheta pi length
+    set scaling [expr {3000.0/$length/$length}]
+
+    # To estimate the integration accurately, we really need to
+    # compute the end-point of our time-step.  But to do *that*, we
+    # need to estimate the integration accurately!  So we try this
+    # technique, which is inaccurate, but better than doing it in a
+    # single step.  What we really want is bound up in the
+    # differential equation:
+    #       ..             - sin theta
+    #      theta + theta = -----------
+    #                         length
+    # But my math skills are not good enough to solve this!
+
+    # first estimate
+    set firstDDTheta [expr {-sin($Theta * $pi/180)*$scaling}]
+    set midDTheta [expr {$dTheta + $firstDDTheta}]
+    set midTheta [expr {$Theta + ($dTheta + $midDTheta)/2}]
+    # second estimate
+    set midDDTheta [expr {-sin($midTheta * $pi/180)*$scaling}]
+    set midDTheta [expr {$dTheta + ($firstDDTheta + $midDDTheta)/2}]
+    set midTheta [expr {$Theta + ($dTheta + $midDTheta)/2}]
+    # Now we do a double-estimate approach for getting the final value
+    # first estimate
+    set midDDTheta [expr {-sin($midTheta * $pi/180)*$scaling}]
+    set lastDTheta [expr {$midDTheta + $midDDTheta}]
+    set lastTheta [expr {$midTheta + ($midDTheta + $lastDTheta)/2}]
+    # second estimate
+    set lastDDTheta [expr {-sin($lastTheta * $pi/180)*$scaling}]
+    set lastDTheta [expr {$midDTheta + ($midDDTheta + $lastDDTheta)/2}]
+    set lastTheta [expr {$midTheta + ($midDTheta + $lastDTheta)/2}]
+    # Now put the values back in our globals
+    set dTheta $lastDTheta
+    set Theta $lastTheta
+}
+
+# This method ties together the simulation engine and the graphical
+# display code that visualizes it.
+proc repeat w {
+    global animationCallbacks
+
+    # Simulate
+    recomputeAngle
+
+    # Update the display
+    showPendulum $w.c
+    showPhase $w.k
+
+    # Reschedule ourselves
+    set animationCallbacks(pendulum) [after 15 [list repeat $w]]
+}
+# Start the simulation after a short pause
+set animationCallbacks(pendulum) [after 500 [list repeat $w]]

janus/lib/tk8.6/demos/plot.tcl

@@ -0,0 +1,97 @@
+# plot.tcl --
+#
+# This demonstration script creates a canvas widget showing a 2-D
+# plot with data points that can be dragged with the mouse.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .plot
+catch {destroy $w}
+toplevel $w
+wm title $w "Plot Demonstration"
+wm iconname $w "Plot"
+positionWindow $w
+set c $w.c
+
+label $w.msg -font $font -wraplength 4i -justify left -text "This window displays a canvas widget containing a simple 2-dimensional plot.  You can doctor the data by dragging any of the points with mouse button 1."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+canvas $c -relief raised -width 450 -height 300
+pack $w.c -side top -fill x
+
+set plotFont {Helvetica 18}
+
+$c create line 100 250 400 250 -width 2
+$c create line 100 250 100 50 -width 2
+$c create text 225 20 -text "A Simple Plot" -font $plotFont -fill brown
+
+for {set i 0} {$i <= 10} {incr i} {
+    set x [expr {100 + ($i*30)}]
+    $c create line $x 250 $x 245 -width 2
+    $c create text $x 254 -text [expr {10*$i}] -anchor n -font $plotFont
+}
+for {set i 0} {$i <= 5} {incr i} {
+    set y [expr {250 - ($i*40)}]
+    $c create line 100 $y 105 $y -width 2
+    $c create text 96 $y -text [expr {$i*50}].0 -anchor e -font $plotFont
+}
+
+foreach point {
+    {12 56} {20 94} {33 98} {32 120} {61 180} {75 160} {98 223}
+} {
+    set x [expr {100 + (3*[lindex $point 0])}]
+    set y [expr {250 - (4*[lindex $point 1])/5}]
+    set item [$c create oval [expr {$x-6}] [expr {$y-6}] \
+	    [expr {$x+6}] [expr {$y+6}] -width 1 -outline black \
+	    -fill SkyBlue2]
+    $c addtag point withtag $item
+}
+
+$c bind point <Enter> "$c itemconfig current -fill red"
+$c bind point <Leave> "$c itemconfig current -fill SkyBlue2"
+$c bind point <Button-1> "plotDown $c %x %y"
+$c bind point <ButtonRelease-1> "$c dtag selected"
+bind $c <B1-Motion> "plotMove $c %x %y"
+
+set plot(lastX) 0
+set plot(lastY) 0
+
+# plotDown --
+# This procedure is invoked when the mouse is pressed over one of the
+# data points.  It sets up state to allow the point to be dragged.
+#
+# Arguments:
+# w -		The canvas window.
+# x, y -	The coordinates of the mouse press.
+
+proc plotDown {w x y} {
+    global plot
+    $w dtag selected
+    $w addtag selected withtag current
+    $w raise current
+    set plot(lastX) $x
+    set plot(lastY) $y
+}
+
+# plotMove --
+# This procedure is invoked during mouse motion events.  It drags the
+# current item.
+#
+# Arguments:
+# w -		The canvas window.
+# x, y -	The coordinates of the mouse.
+
+proc plotMove {w x y} {
+    global plot
+    $w move selected [expr {$x-$plot(lastX)}] [expr {$y-$plot(lastY)}]
+    set plot(lastX) $x
+    set plot(lastY) $y
+}

janus/lib/tk8.6/demos/puzzle.tcl

@@ -0,0 +1,82 @@
+# puzzle.tcl --
+#
+# This demonstration script creates a 15-puzzle game using a collection
+# of buttons.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+# puzzleSwitch --
+# This procedure is invoked when the user clicks on a particular button;
+# if the button is next to the empty space, it moves the button into the
+# empty space.
+
+proc puzzleSwitch {w num} {
+    global xpos ypos
+    if {(($ypos($num) >= ($ypos(space) - .01))
+	    && ($ypos($num) <= ($ypos(space) + .01))
+	    && ($xpos($num) >= ($xpos(space) - .26))
+	    && ($xpos($num) <= ($xpos(space) + .26)))
+	    || (($xpos($num) >= ($xpos(space) - .01))
+	    && ($xpos($num) <= ($xpos(space) + .01))
+	    && ($ypos($num) >= ($ypos(space) - .26))
+	    && ($ypos($num) <= ($ypos(space) + .26)))} {
+	set tmp $xpos(space)
+	set xpos(space) $xpos($num)
+	set xpos($num) $tmp
+	set tmp $ypos(space)
+	set ypos(space) $ypos($num)
+	set ypos($num) $tmp
+	place $w.frame.$num -relx $xpos($num) -rely $ypos($num)
+    }
+}
+
+set w .puzzle
+catch {destroy $w}
+toplevel $w
+wm title $w "15-Puzzle Demonstration"
+wm iconname $w "15-Puzzle"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "A 15-puzzle appears below as a collection of buttons.  Click on any of the pieces next to the space, and that piece will slide over the space.  Continue this until the pieces are arranged in numerical order from upper-left to lower-right."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+# Special trick: select a darker color for the space by creating a
+# scrollbar widget and using its trough color.
+
+scrollbar $w.s
+
+# The button metrics are a bit bigger in Aqua, and since we are
+# using place which doesn't autosize, then we need to have a
+# slightly larger frame here...
+
+if {[tk windowingsystem] eq "aqua"} {
+    set frameSize 168
+} else {
+    set frameSize 120
+}
+
+frame $w.frame -width $frameSize -height $frameSize -borderwidth 2\
+	-relief sunken -bg [$w.s cget -troughcolor]
+pack $w.frame -side top -pady 1c -padx 1c
+destroy $w.s
+
+set order {3 1 6 2 5 7 15 13 4 11 8 9 14 10 12}
+for {set i 0} {$i < 15} {set i [expr {$i+1}]} {
+    set num [lindex $order $i]
+    set xpos($num) [expr {($i%4)*.25}]
+    set ypos($num) [expr {($i/4)*.25}]
+    button $w.frame.$num -relief raised -text $num -bd 0 -highlightthickness 0 \
+	    -command "puzzleSwitch $w $num"
+    place $w.frame.$num -relx $xpos($num) -rely $ypos($num) \
+	-relwidth .25 -relheight .25
+}
+set xpos(space) .75
+set ypos(space) .75

janus/lib/tk8.6/demos/radio.tcl

@@ -0,0 +1,66 @@
+# radio.tcl --
+#
+# This demonstration script creates a toplevel window containing
+# several radiobutton widgets.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .radio
+catch {destroy $w}
+toplevel $w
+wm title $w "Radiobutton Demonstration"
+wm iconname $w "radio"
+positionWindow $w
+label $w.msg -font $font -wraplength 5i -justify left -text "Three groups of radiobuttons are displayed below.  If you click on a button then the button will become selected exclusively among all the buttons in its group.  A Tcl variable is associated with each group to indicate which of the group's buttons is selected.  When the 'Tristate' button is pressed, the radio buttons will display the tri-state mode. Selecting any radio button will return the buttons to their respective on/off state. Click the \"See Variables\" button to see the current values of the variables."
+grid $w.msg -row 0 -column 0 -columnspan 3 -sticky nsew
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w [list size color align]]
+grid $btns -row 3 -column 0 -columnspan 3 -sticky ew
+
+labelframe $w.left -pady 2 -text "Point Size" -padx 2
+labelframe $w.mid -pady 2 -text "Color" -padx 2
+labelframe $w.right -pady 2 -text "Alignment" -padx 2
+button $w.tristate -text Tristate -command "set size multi; set color multi" \
+    -pady 2 -padx 2
+if {[tk windowingsystem] eq "aqua"} {
+    $w.tristate configure -padx 10
+}
+grid $w.left     -column 0 -row 1 -pady .5c -padx .5c -rowspan 2
+grid $w.mid      -column 1 -row 1 -pady .5c -padx .5c -rowspan 2
+grid $w.right    -column 2 -row 1 -pady .5c -padx .5c
+grid $w.tristate -column 2 -row 2 -pady .5c -padx .5c
+
+foreach i {10 12 14 18 24} {
+    radiobutton $w.left.b$i -text "Point Size $i" -variable size \
+	    -relief flat -value $i -tristatevalue "multi"
+    pack $w.left.b$i  -side top -pady 2 -anchor w -fill x
+}
+
+foreach c {Red Green Blue Yellow Orange Purple} {
+    set lower [string tolower $c]
+    radiobutton $w.mid.$lower -text $c -variable color \
+	    -relief flat -value $lower -anchor w \
+	    -command "$w.mid configure -fg \$color" \
+	-tristatevalue "multi"
+    pack $w.mid.$lower -side top -pady 2 -fill x
+}
+
+
+label $w.right.l -text "Label" -bitmap questhead -compound left
+$w.right.l configure -width [winfo reqwidth $w.right.l] -compound top
+$w.right.l configure -height [winfo reqheight $w.right.l]
+foreach a {Top Left Right Bottom} {
+    set lower [string tolower $a]
+    radiobutton $w.right.$lower -text $a -variable align \
+	    -relief flat -value $lower -indicatoron 0 -width 7 \
+	    -command "$w.right.l configure -compound \$align"
+}
+
+grid x $w.right.top
+grid $w.right.left $w.right.l $w.right.right
+grid x $w.right.bottom

janus/lib/tk8.6/demos/rmt

@@ -0,0 +1,210 @@
+#!/bin/sh
+# the next line restarts using wish \
+exec wish8.6 "$0" ${1+"$@"}
+
+# rmt --
+# This script implements a simple remote-control mechanism for
+# Tk applications.  It allows you to select an application and
+# then type commands to that application.
+
+package require Tk
+
+wm title . "Tk Remote Controller"
+wm iconname . "Tk Remote"
+wm minsize . 1 1
+
+# The global variable below keeps track of the remote application
+# that we're sending to.  If it's an empty string then we execute
+# the commands locally.
+
+set app "local"
+
+# The global variable below keeps track of whether we're in the
+# middle of executing a command entered via the text.
+
+set executing 0
+
+# The global variable below keeps track of the last command executed,
+# so it can be re-executed in response to !! commands.
+
+set lastCommand ""
+
+# Create menu bar.  Arrange to recreate all the information in the
+# applications sub-menu whenever it is cascaded to.
+
+. configure -menu [menu .menu]
+menu .menu.file
+menu .menu.file.apps  -postcommand fillAppsMenu
+.menu add cascade  -label "File"  -underline 0  -menu .menu.file
+.menu.file add cascade  -label "Select Application"  -underline 0 \
+	-menu .menu.file.apps
+.menu.file add command  -label "Quit"  -command "destroy ."  -underline 0
+
+# Create text window and scrollbar.
+
+text .t -yscrollcommand ".s set" -setgrid true
+scrollbar .s -command ".t yview"
+grid .t .s -sticky nsew
+grid rowconfigure . 0 -weight 1
+grid columnconfigure . 0 -weight 1
+
+# Create a binding to forward commands to the target application,
+# plus modify many of the built-in bindings so that only information
+# in the current command can be deleted (can still set the cursor
+# earlier in the text and select and insert;  just can't delete).
+
+bindtags .t {.t Text . all}
+bind .t <Return> {
+    .t mark set insert {end - 1c}
+    .t insert insert \n
+    invoke
+    break
+}
+bind .t <Delete> {
+    catch {.t tag remove sel sel.first promptEnd}
+    if {[.t tag nextrange sel 1.0 end] eq ""} {
+	if {[.t compare insert < promptEnd]} {
+	    break
+	}
+    }
+}
+bind .t <BackSpace> {
+    catch {.t tag remove sel sel.first promptEnd}
+    if {[.t tag nextrange sel 1.0 end] eq ""} {
+	if {[.t compare insert <= promptEnd]} {
+	    break
+	}
+    }
+}
+bind .t <Control-d> {
+    if {[.t compare insert < promptEnd]} {
+	break
+    }
+}
+bind .t <Control-k> {
+    if {[.t compare insert < promptEnd]} {
+	.t mark set insert promptEnd
+    }
+}
+bind .t <Control-t> {
+    if {[.t compare insert < promptEnd]} {
+	break
+    }
+}
+bind .t <Meta-d> {
+    if {[.t compare insert < promptEnd]} {
+	break
+    }
+}
+bind .t <Meta-BackSpace> {
+    if {[.t compare insert <= promptEnd]} {
+	break
+    }
+}
+bind .t <Control-h> {
+    if {[.t compare insert <= promptEnd]} {
+	break
+    }
+}
+### This next bit *isn't* nice - DKF ###
+auto_load tk::TextInsert
+proc tk::TextInsert {w s} {
+    if {$s eq ""} {
+	return
+    }
+    catch {
+	if {
+	    [$w compare sel.first <= insert] && [$w compare sel.last >= insert]
+	} then {
+	    $w tag remove sel sel.first promptEnd
+	    $w delete sel.first sel.last
+	}
+    }
+    $w insert insert $s
+    $w see insert
+}
+
+.t configure -font {Courier 12}
+.t tag configure bold -font {Courier 12 bold}
+
+# The procedure below is used to print out a prompt at the
+# insertion point (which should be at the beginning of a line
+# right now).
+
+proc prompt {} {
+    global app
+    .t insert insert "$app: "
+    .t mark set promptEnd {insert}
+    .t mark gravity promptEnd left
+    .t tag add bold {promptEnd linestart} promptEnd
+}
+
+# The procedure below executes a command (it takes everything on the
+# current line after the prompt and either sends it to the remote
+# application or executes it locally, depending on "app".
+
+proc invoke {} {
+    global app executing lastCommand
+    set cmd [.t get promptEnd insert]
+    incr executing 1
+    if {[info complete $cmd]} {
+	if {$cmd eq "!!\n"} {
+	    set cmd $lastCommand
+	} else {
+	    set lastCommand $cmd
+	}
+	if {$app eq "local"} {
+	    set result [catch [list uplevel #0 $cmd] msg]
+	} else {
+	    set result [catch [list send $app $cmd] msg]
+	}
+	if {$result != 0} {
+	    .t insert insert "Error: $msg\n"
+	} elseif {$msg ne ""} {
+	    .t insert insert $msg\n
+	}
+	prompt
+	.t mark set promptEnd insert
+    }
+    incr executing -1
+    .t yview -pickplace insert
+}
+
+# The following procedure is invoked to change the application that
+# we're talking to.  It also updates the prompt for the current
+# command, unless we're in the middle of executing a command from
+# the text item (in which case a new prompt is about to be output
+# so there's no need to change the old one).
+
+proc newApp appName {
+    global app executing
+    set app $appName
+    if {!$executing} {
+	.t mark gravity promptEnd right
+	.t delete "promptEnd linestart" promptEnd
+	.t insert promptEnd "$appName: "
+	.t tag add bold "promptEnd linestart" promptEnd
+	.t mark gravity promptEnd left
+    }
+    return
+}
+
+# The procedure below will fill in the applications sub-menu with a list
+# of all the applications that currently exist.
+
+proc fillAppsMenu {} {
+    set m .menu.file.apps
+    catch {$m delete 0 last}
+    foreach i [lsort [winfo interps]] {
+	$m add command -label $i -command [list newApp $i]
+    }
+    $m add command -label local -command {newApp local}
+}
+
+set app [winfo name .]
+prompt
+focus .t
+
+# Local Variables:
+# mode: tcl
+# End:

janus/lib/tk8.6/demos/rolodex

@@ -0,0 +1,204 @@
+#!/bin/sh
+# the next line restarts using wish \
+exec wish8.6 "$0" ${1+"$@"}
+
+# rolodex --
+# This script was written as an entry in Tom LaStrange's rolodex
+# benchmark.  It creates something that has some of the look and
+# feel of a rolodex program, although it's lifeless and doesn't
+# actually do the rolodex application.
+
+package require Tk
+
+foreach i [winfo children .] {
+    catch {destroy $i}
+}
+
+set version 1.2
+
+#------------------------------------------
+# Phase 0: create the front end.
+#------------------------------------------
+
+frame .frame -relief flat
+pack .frame -side top -fill y -anchor center
+
+set names {{} Name: Address: {} {} {Home Phone:} {Work Phone:} Fax:}
+foreach i {1 2 3 4 5 6 7} {
+    label .frame.label$i -text [lindex $names $i] -anchor e
+    entry .frame.entry$i -width 35
+    grid .frame.label$i .frame.entry$i -sticky ew -pady 2 -padx 1
+}
+
+frame .buttons
+pack .buttons -side bottom -pady 2 -anchor center
+button .buttons.clear -text Clear
+button .buttons.add -text Add
+button .buttons.search -text Search
+button .buttons.delete -text "Delete ..."
+pack .buttons.clear .buttons.add .buttons.search .buttons.delete \
+	-side left -padx 2
+
+#------------------------------------------
+# Phase 1: Add menus, dialog boxes
+#------------------------------------------
+
+# DKF - note that this is an old-style menu bar; I just have not yet
+# got around to converting the context help code to work with the new
+# menu system and its <<MenuSelect>> virtual event.
+
+frame .menu -relief raised -borderwidth 1
+pack .menu -before .frame -side top -fill x
+
+menubutton .menu.file -text "File" -menu .menu.file.m -underline 0
+menu .menu.file.m
+.menu.file.m add command -label "Load ..." -command fileAction -underline 0
+.menu.file.m add command -label "Exit" -command {destroy .} -underline 0
+pack .menu.file -side left
+
+menubutton .menu.help -text "Help" -menu .menu.help.m -underline 0
+menu .menu.help.m
+pack .menu.help -side right
+
+proc deleteAction {} {
+    if {[tk_dialog .delete {Confirm Action} {Are you sure?} {} 0  Cancel]
+	    == 0} {
+	clearAction
+    }
+}
+.buttons.delete config -command deleteAction
+
+proc fileAction {} {
+    tk_dialog .fileSelection {File Selection} {This is a dummy file selection dialog box, which is used because there isn't a good file selection dialog built into Tk yet.} {} 0 OK
+    puts stderr {dummy file name}
+}
+
+#------------------------------------------
+# Phase 3: Print contents of card
+#------------------------------------------
+
+proc addAction {} {
+    global names
+    foreach i {1 2 3 4 5 6 7} {
+	puts stderr [format "%-12s %s" [lindex $names $i] [.frame.entry$i get]]
+    }
+}
+.buttons.add config -command addAction
+
+#------------------------------------------
+# Phase 4: Miscellaneous other actions
+#------------------------------------------
+
+proc clearAction {} {
+    foreach i {1 2 3 4 5 6 7} {
+	.frame.entry$i delete 0 end
+    }
+}
+.buttons.clear config -command clearAction
+
+proc fillCard {} {
+    clearAction
+    .frame.entry1 insert 0 "John Ousterhout"
+    .frame.entry2 insert 0 "CS Division, Department of EECS"
+    .frame.entry3 insert 0 "University of California"
+    .frame.entry4 insert 0 "Berkeley, CA 94720"
+    .frame.entry5 insert 0 "private"
+    .frame.entry6 insert 0 "510-642-0865"
+    .frame.entry7 insert 0 "510-642-5775"
+}
+.buttons.search config -command "addAction; fillCard"
+
+#----------------------------------------------------
+# Phase 5: Accelerators, mnemonics, command-line info
+#----------------------------------------------------
+
+.buttons.clear config -text "Clear    Ctrl+C"
+bind . <Control-c> clearAction
+.buttons.add config -text "Add    Ctrl+A"
+bind . <Control-a> addAction
+.buttons.search config -text "Search    Ctrl+S"
+bind . <Control-s> "addAction; fillCard"
+.buttons.delete config -text "Delete...    Ctrl+D"
+bind . <Control-d> deleteAction
+
+.menu.file.m entryconfig 1 -accel Ctrl+F
+bind . <Control-f> fileAction
+.menu.file.m entryconfig 2 -accel Ctrl+Q
+bind . <Control-q> {destroy .}
+
+focus .frame.entry1
+
+#----------------------------------------------------
+# Phase 6: help
+#----------------------------------------------------
+
+proc Help {topic {x 0} {y 0}} {
+    global helpTopics helpCmds
+    if {$topic == ""} return
+    while {[info exists helpCmds($topic)]} {
+	set topic [eval $helpCmds($topic)]
+    }
+    if [info exists helpTopics($topic)] {
+	set msg $helpTopics($topic)
+    } else {
+	set msg "Sorry, but no help is available for this topic"
+    }
+    tk_dialog .help {Rolodex Help} "Information on $topic:\n\n$msg" \
+	    {} 0 OK
+}
+
+proc getMenuTopic {w x y} {
+    return $w.[$w index @[expr {$y-[winfo rooty $w]}]]
+}
+
+event add <<Help>> <F1> <Help>
+bind .    <<Help>> {Help [winfo containing %X %Y] %X %Y}
+bind Menu <<Help>> {Help [winfo containing %X %Y] %X %Y}
+
+# Help text and commands follow:
+
+set helpTopics(.menu.file) {This is the "file" menu.  It can be used to invoke some overall operations on the rolodex applications, such as loading a file or exiting.}
+
+set helpCmds(.menu.file.m) {getMenuTopic $topic $x $y}
+set helpTopics(.menu.file.m.1) {The "Load" entry in the "File" menu posts a dialog box that you can use to select a rolodex file}
+set helpTopics(.menu.file.m.2) {The "Exit" entry in the "File" menu causes the rolodex application to terminate}
+set helpCmds(.menu.file.m.none) {set topic ".menu.file"}
+
+set helpTopics(.frame.entry1) {In this field of the rolodex entry you should type the person's name}
+set helpTopics(.frame.entry2) {In this field of the rolodex entry you should type the first line of the person's address}
+set helpTopics(.frame.entry3) {In this field of the rolodex entry you should type the second line of the person's address}
+set helpTopics(.frame.entry4) {In this field of the rolodex entry you should type the third line of the person's address}
+set helpTopics(.frame.entry5) {In this field of the rolodex entry you should type the person's home phone number, or "private" if the person doesn't want his or her number publicized}
+set helpTopics(.frame.entry6) {In this field of the rolodex entry you should type the person's work phone number}
+set helpTopics(.frame.entry7) {In this field of the rolodex entry you should type the phone number for the person's FAX machine}
+
+set helpCmds(.frame.label1) {set topic .frame.entry1}
+set helpCmds(.frame.label2) {set topic .frame.entry2}
+set helpCmds(.frame.label3) {set topic .frame.entry3}
+set helpCmds(.frame.label4) {set topic .frame.entry4}
+set helpCmds(.frame.label5) {set topic .frame.entry5}
+set helpCmds(.frame.label6) {set topic .frame.entry6}
+set helpCmds(.frame.label7) {set topic .frame.entry7}
+
+set helpTopics(context) {Unfortunately, this application doesn't support context-sensitive help in the usual way, because when this demo was written Tk didn't have a grab mechanism and this is needed for context-sensitive help.  Instead, you can achieve much the same effect by simply moving the mouse over the window you're curious about and pressing the Help or F1 keys.  You can do this anytime.}
+set helpTopics(help) {This application provides only very crude help.  Besides the entries in this menu, you can get help on individual windows by moving the mouse cursor over the window and pressing the Help or F1 keys.}
+set helpTopics(window) {This window is a dummy rolodex application created as part of Tom LaStrange's toolkit benchmark.  It doesn't really do anything useful except to demonstrate a few features of the Tk toolkit.}
+set helpTopics(keys) "The following accelerator keys are defined for this application (in addition to those already available for the entry windows):\n\nCtrl+A:\t\tAdd\nCtrl+C:\t\tClear\nCtrl+D:\t\tDelete\nCtrl+F:\t\tEnter file name\nCtrl+Q:\t\tExit application (quit)\nCtrl+S:\t\tSearch (dummy operation)"
+set helpTopics(version) "This is version $version."
+
+# Entries in "Help" menu
+
+.menu.help.m add command -label "On Context..." -command {Help context} \
+	-underline 3
+.menu.help.m add command -label "On Help..." -command {Help help} \
+	-underline 3
+.menu.help.m add command -label "On Window..." -command {Help window} \
+	-underline 3
+.menu.help.m add command -label "On Keys..." -command {Help keys} \
+	-underline 3
+.menu.help.m add command -label "On Version..." -command {Help version}  \
+	-underline 3
+
+# Local Variables:
+# mode: tcl
+# End:

janus/lib/tk8.6/demos/ruler.tcl

@@ -0,0 +1,175 @@
+# ruler.tcl --
+#
+# This demonstration script creates a canvas widget that displays a ruler
+# with tab stops that can be set, moved, and deleted.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+# rulerMkTab --
+# This procedure creates a new triangular polygon in a canvas to
+# represent a tab stop.
+#
+# Arguments:
+# c -		The canvas window.
+# x, y -	Coordinates at which to create the tab stop.
+
+proc rulerMkTab {c x y} {
+    upvar #0 demo_rulerInfo v
+    set newTab [$c create polygon $x $y \
+	    [expr {$x+$v(size)}] [expr {$y+$v(size)}] \
+	    [expr {$x-$v(size)}] [expr {$y+$v(size)}]]
+    set fill [$c itemcget $newTab -outline]
+    $c itemconfigure $newTab -fill $fill -outline {}
+    set v(normalStyle) "-fill $fill"
+    return $newTab
+}
+
+set w .ruler
+catch {destroy $w}
+toplevel $w
+wm title $w "Ruler Demonstration"
+wm iconname $w "ruler"
+positionWindow $w
+set c $w.c
+
+label $w.msg -font $font -wraplength 5i -justify left -text "This canvas widget shows a mock-up of a ruler.  You can create tab stops by dragging them out of the well to the right of the ruler.  You can also drag existing tab stops.  If you drag a tab stop far enough up or down so that it turns dim, it will be deleted when you release the mouse button."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+canvas $c -width 14.8c -height 2.5c
+pack $w.c -side top -fill x
+
+set demo_rulerInfo(grid) .25c
+set demo_rulerInfo(left) [winfo fpixels $c 1c]
+set demo_rulerInfo(right) [winfo fpixels $c 13c]
+set demo_rulerInfo(top) [winfo fpixels $c 1c]
+set demo_rulerInfo(bottom) [winfo fpixels $c 1.5c]
+set demo_rulerInfo(size) [winfo fpixels $c .2c]
+# Main widget program sets variable tk_demoDirectory
+if {[winfo depth $c] > 1} {
+    set demo_rulerInfo(activeStyle) "-fill red -stipple {}"
+    set demo_rulerInfo(deleteStyle) [list -fill red \
+	    -stipple @[file join $tk_demoDirectory images gray25.xbm]]
+} else {
+    set demo_rulerInfo(activeStyle) "-fill black -stipple {}"
+    set demo_rulerInfo(deleteStyle) [list -fill black \
+	    -stipple @[file join $tk_demoDirectory images gray25.xbm]]
+}
+
+$c create line 1c 0.5c 1c 1c 13c 1c 13c 0.5c -width 1
+for {set i 0} {$i < 12} {incr i} {
+    set x [expr {$i+1}]
+    $c create line ${x}c 1c ${x}c 0.6c -width 1
+    $c create line $x.25c 1c $x.25c 0.8c -width 1
+    $c create line $x.5c 1c $x.5c 0.7c -width 1
+    $c create line $x.75c 1c $x.75c 0.8c -width 1
+    $c create text $x.15c .75c -text $i -anchor sw
+}
+$c addtag well withtag [$c create rect 13.2c 1c 13.8c 0.5c \
+	-fill [lindex [$c config -bg] 4]]
+$c addtag well withtag [rulerMkTab $c [winfo pixels $c 13.5c] \
+	[winfo pixels $c .65c]]
+
+$c bind well <Button-1> "rulerNewTab $c %x %y"
+$c bind tab <Button-1> "rulerSelectTab $c %x %y"
+bind $c <B1-Motion> "rulerMoveTab $c %x %y"
+bind $c <ButtonRelease-1> "rulerReleaseTab $c"
+
+# rulerNewTab --
+# Does all the work of creating a tab stop, including creating the
+# triangle object and adding tags to it to give it tab behavior.
+#
+# Arguments:
+# c -		The canvas window.
+# x, y -	The coordinates of the tab stop.
+
+proc rulerNewTab {c x y} {
+    upvar #0 demo_rulerInfo v
+    $c addtag active withtag [rulerMkTab $c $x $y]
+    $c addtag tab withtag active
+    set v(x) $x
+    set v(y) $y
+    rulerMoveTab $c $x $y
+}
+
+# rulerSelectTab --
+# This procedure is invoked when mouse button 1 is pressed over
+# a tab.  It remembers information about the tab so that it can
+# be dragged interactively.
+#
+# Arguments:
+# c -		The canvas widget.
+# x, y -	The coordinates of the mouse (identifies the point by
+#		which the tab was picked up for dragging).
+
+proc rulerSelectTab {c x y} {
+    upvar #0 demo_rulerInfo v
+    set v(x) [$c canvasx $x $v(grid)]
+    set v(y) [expr {$v(top)+2}]
+    $c addtag active withtag current
+    eval "$c itemconf active $v(activeStyle)"
+    $c raise active
+}
+
+# rulerMoveTab --
+# This procedure is invoked during mouse motion events to drag a tab.
+# It adjusts the position of the tab, and changes its appearance if
+# it is about to be dragged out of the ruler.
+#
+# Arguments:
+# c -		The canvas widget.
+# x, y -	The coordinates of the mouse.
+
+proc rulerMoveTab {c x y} {
+    upvar #0 demo_rulerInfo v
+    if {[$c find withtag active] == ""} {
+	return
+    }
+    set cx [$c canvasx $x $v(grid)]
+    set cy [$c canvasy $y]
+    if {$cx < $v(left)} {
+	set cx $v(left)
+    }
+    if {$cx > $v(right)} {
+	set cx $v(right)
+    }
+    if {($cy >= $v(top)) && ($cy <= $v(bottom))} {
+	set cy [expr {$v(top)+2}]
+	eval "$c itemconf active $v(activeStyle)"
+    } else {
+	set cy [expr {$cy-$v(size)-2}]
+	eval "$c itemconf active $v(deleteStyle)"
+    }
+    $c move active [expr {$cx-$v(x)}] [expr {$cy-$v(y)}]
+    set v(x) $cx
+    set v(y) $cy
+}
+
+# rulerReleaseTab --
+# This procedure is invoked during button release events that end
+# a tab drag operation.  It deselects the tab and deletes the tab if
+# it was dragged out of the ruler.
+#
+# Arguments:
+# c -		The canvas widget.
+# x, y -	The coordinates of the mouse.
+
+proc rulerReleaseTab c {
+    upvar #0 demo_rulerInfo v
+    if {[$c find withtag active] == {}} {
+	return
+    }
+    if {$v(y) != $v(top)+2} {
+	$c delete active
+    } else {
+	eval "$c itemconf active $v(normalStyle)"
+	$c dtag active
+    }
+}

janus/lib/tk8.6/demos/search.tcl

@@ -0,0 +1,139 @@
+# search.tcl --
+#
+# This demonstration script creates a collection of widgets that
+# allow you to load a file into a text widget, then perform searches
+# on that file.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+# textLoadFile --
+# This procedure below loads a file into a text widget, discarding
+# the previous contents of the widget. Tags for the old widget are
+# not affected, however.
+#
+# Arguments:
+# w -		The window into which to load the file.  Must be a
+#		text widget.
+# file -	The name of the file to load.  Must be readable.
+
+proc textLoadFile {w file} {
+    set f [open $file]
+    $w delete 1.0 end
+    while {![eof $f]} {
+	$w insert end [read $f 10000]
+    }
+    close $f
+}
+
+# textSearch --
+# Search for all instances of a given string in a text widget and
+# apply a given tag to each instance found.
+#
+# Arguments:
+# w -		The window in which to search.  Must be a text widget.
+# string -	The string to search for.  The search is done using
+#		exact matching only;  no special characters.
+# tag -		Tag to apply to each instance of a matching string.
+
+proc textSearch {w string tag} {
+    $w tag remove search 0.0 end
+    if {$string == ""} {
+	return
+    }
+    set cur 1.0
+    while 1 {
+	set cur [$w search -count length $string $cur end]
+	if {$cur == ""} {
+	    break
+	}
+	$w tag add $tag $cur "$cur + $length char"
+	set cur [$w index "$cur + $length char"]
+    }
+}
+
+# textToggle --
+# This procedure is invoked repeatedly to invoke two commands at
+# periodic intervals.  It normally reschedules itself after each
+# execution but if an error occurs (e.g. because the window was
+# deleted) then it doesn't reschedule itself.
+#
+# Arguments:
+# cmd1 -	Command to execute when procedure is called.
+# sleep1 -	Ms to sleep after executing cmd1 before executing cmd2.
+# cmd2 -	Command to execute in the *next* invocation of this
+#		procedure.
+# sleep2 -	Ms to sleep after executing cmd2 before executing cmd1 again.
+
+proc textToggle {cmd1 sleep1 cmd2 sleep2} {
+    catch {
+	eval $cmd1
+	after $sleep1 [list textToggle $cmd2 $sleep2 $cmd1 $sleep1]
+    }
+}
+
+set w .search
+catch {destroy $w}
+toplevel $w
+wm title $w "Text Demonstration - Search and Highlight"
+wm iconname $w "search"
+positionWindow $w
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+frame $w.file
+label $w.file.label -text "File name:" -width 13 -anchor w
+entry $w.file.entry -width 40 -textvariable fileName
+button $w.file.button -text "Load File" \
+	-command "textLoadFile $w.text \$fileName"
+pack $w.file.label $w.file.entry -side left
+pack $w.file.button -side left -pady 5 -padx 10
+bind $w.file.entry <Return> "
+    textLoadFile $w.text \$fileName
+    focus $w.string.entry
+"
+focus $w.file.entry
+
+frame $w.string
+label $w.string.label -text "Search string:" -width 13 -anchor w
+entry $w.string.entry -width 40 -textvariable searchString
+button $w.string.button -text "Highlight" \
+	-command "textSearch $w.text \$searchString search"
+pack $w.string.label $w.string.entry -side left
+pack $w.string.button -side left -pady 5 -padx 10
+bind $w.string.entry <Return> "textSearch $w.text \$searchString search"
+
+text $w.text -yscrollcommand "$w.scroll set" -setgrid true
+ttk::scrollbar $w.scroll -command "$w.text yview"
+pack $w.file $w.string -side top -fill x
+pack $w.scroll -side right -fill y
+pack $w.text -expand yes -fill both
+
+# Set up display styles for text highlighting.
+
+if {[winfo depth $w] > 1} {
+    textToggle "$w.text tag configure search -background \
+	    #ce5555 -foreground white" 800 "$w.text tag configure \
+	    search -background {} -foreground {}" 200
+} else {
+    textToggle "$w.text tag configure search -background \
+	    black -foreground white" 800 "$w.text tag configure \
+	    search -background {} -foreground {}" 200
+}
+$w.text insert 1.0 \
+{This window demonstrates how to use the tagging facilities in text
+widgets to implement a searching mechanism.  First, type a file name
+in the top entry, then type <Return> or click on "Load File".  Then
+type a string in the lower entry and type <Return> or click on
+"Load File".  This will cause all of the instances of the string to
+be tagged with the tag "search", and it will arrange for the tag's
+display attributes to change to make all of the strings blink.}
+$w.text mark set insert 0.0
+
+set fileName ""
+set searchString ""

janus/lib/tk8.6/demos/spin.tcl

@@ -0,0 +1,53 @@
+# spin.tcl --
+#
+# This demonstration script creates several spinbox widgets.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .spin
+catch {destroy $w}
+toplevel $w
+wm title $w "Spinbox Demonstration"
+wm iconname $w "spin"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 5i -justify left -text "Three different\
+	spin-boxes are displayed below.  You can add characters by pointing,\
+	clicking and typing.  The normal Motif editing characters are\
+	supported, along with many Emacs bindings.  For example, Backspace\
+	and Control-h delete the character to the left of the insertion\
+	cursor and Delete and Control-d delete the chararacter to the right\
+	of the insertion cursor.  For values that are too large to fit in the\
+	window all at once, you can scan through the value by dragging with\
+	mouse button2 pressed.  Note that the first spin-box will only permit\
+	you to type in integers, and the third selects from a list of\
+	Australian cities."
+pack $w.msg -side top
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+set australianCities {
+    Canberra Sydney Melbourne Perth Adelaide Brisbane
+    Hobart Darwin "Alice Springs"
+}
+
+spinbox $w.s1 -from 1 -to 10 -width 10 -validate key \
+	-vcmd {string is integer %P}
+spinbox $w.s2 -from 0 -to 3 -increment .5 -format %05.2f -width 10
+spinbox $w.s3 -values $australianCities -width 10
+
+#entry $w.e1
+#entry $w.e2
+#entry $w.e3
+pack $w.s1 $w.s2 $w.s3 -side top -pady 5 -padx 10 ;#-fill x
+
+#$w.e1 insert 0 "Initial value"
+#$w.e2 insert end "This entry contains a long value, much too long "
+#$w.e2 insert end "to fit in the window at one time, so long in fact "
+#$w.e2 insert end "that you'll have to scan or scroll to see the end."

janus/lib/tk8.6/demos/states.tcl

@@ -0,0 +1,54 @@
+# states.tcl --
+#
+# This demonstration script creates a listbox widget that displays
+# the names of the 50 states in the United States of America.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .states
+catch {destroy $w}
+toplevel $w
+wm title $w "Listbox Demonstration (50 states)"
+wm iconname $w "states"
+positionWindow $w
+
+label $w.msg -font $font -wraplength 4i -justify left -text "A listbox containing the 50 states is displayed below, along with a scrollbar.  You can scan the list either using the scrollbar or by scanning.  To scan, press button 2 in the widget and drag up or down."
+pack $w.msg -side top
+
+labelframe $w.justif -text Justification
+foreach c {Left Center Right} {
+    set lower [string tolower $c]
+    radiobutton $w.justif.$lower -text $c -variable just \
+        -relief flat -value $lower -anchor w \
+        -command "$w.frame.list configure -justify \$just" \
+        -tristatevalue "multi"
+    pack $w.justif.$lower -side left -pady 2 -fill x
+}
+pack $w.justif
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+frame $w.frame -borderwidth .5c
+pack $w.frame -side top -expand yes -fill y
+
+ttk::scrollbar $w.frame.scroll -command "$w.frame.list yview"
+listbox $w.frame.list -yscroll "$w.frame.scroll set" -setgrid 1 -height 12
+pack $w.frame.scroll -side right -fill y
+pack $w.frame.list -side left -expand 1 -fill both
+
+$w.frame.list insert 0 Alabama Alaska Arizona Arkansas California \
+    Colorado Connecticut Delaware Florida Georgia Hawaii Idaho Illinois \
+    Indiana Iowa Kansas Kentucky Louisiana Maine Maryland \
+    Massachusetts Michigan Minnesota Mississippi Missouri \
+    Montana Nebraska Nevada "New Hampshire" "New Jersey" "New Mexico" \
+    "New York" "North Carolina" "North Dakota" \
+    Ohio Oklahoma Oregon Pennsylvania "Rhode Island" \
+    "South Carolina" "South Dakota" \
+    Tennessee Texas Utah Vermont Virginia Washington \
+    "West Virginia" Wisconsin Wyoming

janus/lib/tk8.6/demos/style.tcl

@@ -0,0 +1,155 @@
+# style.tcl --
+#
+# This demonstration script creates a text widget that illustrates the
+# various display styles that may be set for tags.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .style
+catch {destroy $w}
+toplevel $w
+wm title $w "Text Demonstration - Display Styles"
+wm iconname $w "style"
+positionWindow $w
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w]
+pack $btns -side bottom -fill x
+
+# Only set the font family in one place for simplicity and consistency
+
+set family Courier
+
+text $w.text -yscrollcommand "$w.scroll set" -setgrid true \
+	-width 70 -height 32 -wrap word -font "$family 12"
+ttk::scrollbar $w.scroll -command "$w.text yview"
+pack $w.scroll -side right -fill y
+pack $w.text -expand yes -fill both
+
+# Set up display styles
+
+$w.text tag configure bold -font "$family 12 bold italic"
+$w.text tag configure big -font "$family 14 bold"
+$w.text tag configure verybig -font "Helvetica 24 bold"
+$w.text tag configure tiny -font "Times 8 bold"
+if {[winfo depth $w] > 1} {
+    $w.text tag configure color1 -background #a0b7ce
+    $w.text tag configure color2 -foreground red
+    $w.text tag configure raised -relief raised -borderwidth 1
+    $w.text tag configure sunken -relief sunken -borderwidth 1
+} else {
+    $w.text tag configure color1 -background black -foreground white
+    $w.text tag configure color2 -background black -foreground white
+    $w.text tag configure raised -background white -relief raised \
+	    -borderwidth 1
+    $w.text tag configure sunken -background white -relief sunken \
+	    -borderwidth 1
+}
+$w.text tag configure bgstipple -background black -borderwidth 0 \
+	-bgstipple gray12
+$w.text tag configure fgstipple -fgstipple gray50
+$w.text tag configure underline -underline on
+$w.text tag configure overstrike -overstrike on
+$w.text tag configure right -justify right
+$w.text tag configure center -justify center
+$w.text tag configure super -offset 4p -font "$family 10"
+$w.text tag configure sub -offset -2p -font "$family 10"
+$w.text tag configure margins -lmargin1 12m -lmargin2 6m -rmargin 10m
+$w.text tag configure spacing -spacing1 10p -spacing2 2p \
+	-lmargin1 12m -lmargin2 6m -rmargin 10m
+
+$w.text insert end {Text widgets like this one allow you to display information in a
+variety of styles.  Display styles are controlled using a mechanism
+called }
+$w.text insert end tags bold
+$w.text insert end {.  Tags are just textual names that you can apply to one
+or more ranges of characters within a text widget.  You can configure
+tags with various display styles.  If you do this, then the tagged
+characters will be displayed with the styles you chose.  The
+available display styles are:
+}
+$w.text insert end "\n1. Font." big
+$w.text insert end "  You can choose any system font, "
+$w.text insert end large verybig
+$w.text insert end " or "
+$w.text insert end "small" tiny ".\n"
+$w.text insert end "\n2. Color." big
+$w.text insert end "  You can change either the "
+$w.text insert end background color1
+$w.text insert end " or "
+$w.text insert end foreground color2
+$w.text insert end "\ncolor, or "
+$w.text insert end both {color1 color2}
+$w.text insert end ".\n"
+$w.text insert end "\n3. Stippling." big
+$w.text insert end "  You can cause either the "
+$w.text insert end background bgstipple
+$w.text insert end " or "
+$w.text insert end foreground fgstipple
+$w.text insert end {
+information to be drawn with a stipple fill instead of a solid fill.
+}
+$w.text insert end "\n4. Underlining." big
+$w.text insert end "  You can "
+$w.text insert end underline underline
+$w.text insert end " ranges of text.\n"
+$w.text insert end "\n5. Overstrikes." big
+$w.text insert end "  You can "
+$w.text insert end "draw lines through" overstrike
+$w.text insert end " ranges of text.\n"
+$w.text insert end "\n6. 3-D effects." big
+$w.text insert end {  You can arrange for the background to be drawn
+with a border that makes characters appear either }
+$w.text insert end raised raised
+$w.text insert end " or "
+$w.text insert end sunken sunken
+$w.text insert end ".\n"
+$w.text insert end "\n7. Justification." big
+$w.text insert end " You can arrange for lines to be displayed\n"
+$w.text insert end "left-justified,\n"
+$w.text insert end "right-justified, or\n" right
+$w.text insert end "centered.\n" center
+$w.text insert end "\n8. Superscripts and subscripts."  big
+$w.text insert end " You can control the vertical\n"
+$w.text insert end "position of text to generate superscript effects like 10"
+$w.text insert end "n" super
+$w.text insert end " or\nsubscript effects like X"
+$w.text insert end "i" sub
+$w.text insert end ".\n"
+$w.text insert end "\n9. Margins." big
+$w.text insert end " You can control the amount of extra space left"
+$w.text insert end " on\neach side of the text:\n"
+$w.text insert end "This paragraph is an example of the use of " margins
+$w.text insert end "margins.  It consists of a single line of text " margins
+$w.text insert end "that wraps around on the screen.  There are two " margins
+$w.text insert end "separate left margin values, one for the first " margins
+$w.text insert end "display line associated with the text line, " margins
+$w.text insert end "and one for the subsequent display lines, which " margins
+$w.text insert end "occur because of wrapping.  There is also a " margins
+$w.text insert end "separate specification for the right margin, " margins
+$w.text insert end "which is used to choose wrap points for lines.\n" margins
+$w.text insert end "\n10. Spacing." big
+$w.text insert end " You can control the spacing of lines with three\n"
+$w.text insert end "separate parameters.  \"Spacing1\" tells how much "
+$w.text insert end "extra space to leave\nabove a line, \"spacing3\" "
+$w.text insert end "tells how much space to leave below a line,\nand "
+$w.text insert end "if a text line wraps, \"spacing2\" tells how much "
+$w.text insert end "space to leave\nbetween the display lines that "
+$w.text insert end "make up the text line.\n"
+$w.text insert end "These indented paragraphs illustrate how spacing " spacing
+$w.text insert end "can be used.  Each paragraph is actually a " spacing
+$w.text insert end "single line in the text widget, which is " spacing
+$w.text insert end "word-wrapped by the widget.\n" spacing
+$w.text insert end "Spacing1 is set to 10 points for this text, " spacing
+$w.text insert end "which results in relatively large gaps between " spacing
+$w.text insert end "the paragraphs.  Spacing2 is set to 2 points, " spacing
+$w.text insert end "which results in just a bit of extra space " spacing
+$w.text insert end "within a pararaph.  Spacing3 isn't used " spacing
+$w.text insert end "in this example.\n" spacing
+$w.text insert end "To see where the space is, select ranges of " spacing
+$w.text insert end "text within these paragraphs.  The selection " spacing
+$w.text insert end "highlight will cover the extra space." spacing

janus/lib/tk8.6/demos/tclIndex

@@ -0,0 +1,67 @@
+# Tcl autoload index file, version 2.0
+# This file is generated by the "auto_mkindex" command
+# and sourced to set up indexing information for one or
+# more commands.  Typically each line is a command that
+# sets an element in the auto_index array, where the
+# element name is the name of a command and the value is
+# a script that loads the command.
+
+set auto_index(arrowSetup) [list source -encoding utf-8 [file join $dir arrow.tcl]]
+set auto_index(arrowMove1) [list source -encoding utf-8 [file join $dir arrow.tcl]]
+set auto_index(arrowMove2) [list source -encoding utf-8 [file join $dir arrow.tcl]]
+set auto_index(arrowMove3) [list source -encoding utf-8 [file join $dir arrow.tcl]]
+set auto_index(textLoadFile) [list source -encoding utf-8 [file join $dir search.tcl]]
+set auto_index(textSearch) [list source -encoding utf-8 [file join $dir search.tcl]]
+set auto_index(textToggle) [list source -encoding utf-8 [file join $dir search.tcl]]
+set auto_index(itemEnter) [list source -encoding utf-8 [file join $dir items.tcl]]
+set auto_index(itemLeave) [list source -encoding utf-8 [file join $dir items.tcl]]
+set auto_index(itemMark) [list source -encoding utf-8 [file join $dir items.tcl]]
+set auto_index(itemStroke) [list source -encoding utf-8 [file join $dir items.tcl]]
+set auto_index(itemsUnderArea) [list source -encoding utf-8 [file join $dir items.tcl]]
+set auto_index(itemStartDrag) [list source -encoding utf-8 [file join $dir items.tcl]]
+set auto_index(itemDrag) [list source -encoding utf-8 [file join $dir items.tcl]]
+set auto_index(butPress) [list source -encoding utf-8 [file join $dir items.tcl]]
+set auto_index(loadDir) [list source -encoding utf-8 [file join $dir image2.tcl]]
+set auto_index(loadImage) [list source -encoding utf-8 [file join $dir image2.tcl]]
+set auto_index(rulerMkTab) [list source -encoding utf-8 [file join $dir ruler.tcl]]
+set auto_index(rulerNewTab) [list source -encoding utf-8 [file join $dir ruler.tcl]]
+set auto_index(rulerSelectTab) [list source -encoding utf-8 [file join $dir ruler.tcl]]
+set auto_index(rulerMoveTab) [list source -encoding utf-8 [file join $dir ruler.tcl]]
+set auto_index(rulerReleaseTab) [list source -encoding utf-8 [file join $dir ruler.tcl]]
+set auto_index(mkTextConfig) [list source -encoding utf-8 [file join $dir ctext.tcl]]
+set auto_index(textEnter) [list source -encoding utf-8 [file join $dir ctext.tcl]]
+set auto_index(textInsert) [list source -encoding utf-8 [file join $dir ctext.tcl]]
+set auto_index(textPaste) [list source -encoding utf-8 [file join $dir ctext.tcl]]
+set auto_index(textB1Press) [list source -encoding utf-8 [file join $dir ctext.tcl]]
+set auto_index(textB1Move) [list source -encoding utf-8 [file join $dir ctext.tcl]]
+set auto_index(textBs) [list source -encoding utf-8 [file join $dir ctext.tcl]]
+set auto_index(textDel) [list source -encoding utf-8 [file join $dir ctext.tcl]]
+set auto_index(bitmapRow) [list source -encoding utf-8 [file join $dir bitmap.tcl]]
+set auto_index(scrollEnter) [list source -encoding utf-8 [file join $dir cscroll.tcl]]
+set auto_index(scrollLeave) [list source -encoding utf-8 [file join $dir cscroll.tcl]]
+set auto_index(scrollButton) [list source -encoding utf-8 [file join $dir cscroll.tcl]]
+set auto_index(textWindOn) [list source -encoding utf-8 [file join $dir twind.tcl]]
+set auto_index(textWindOff) [list source -encoding utf-8 [file join $dir twind.tcl]]
+set auto_index(textWindPlot) [list source -encoding utf-8 [file join $dir twind.tcl]]
+set auto_index(embPlotDown) [list source -encoding utf-8 [file join $dir twind.tcl]]
+set auto_index(embPlotMove) [list source -encoding utf-8 [file join $dir twind.tcl]]
+set auto_index(textWindDel) [list source -encoding utf-8 [file join $dir twind.tcl]]
+set auto_index(embDefBg) [list source -encoding utf-8 [file join $dir twind.tcl]]
+set auto_index(floorDisplay) [list source -encoding utf-8 [file join $dir floor.tcl]]
+set auto_index(newRoom) [list source -encoding utf-8 [file join $dir floor.tcl]]
+set auto_index(roomChanged) [list source -encoding utf-8 [file join $dir floor.tcl]]
+set auto_index(bg1) [list source -encoding utf-8 [file join $dir floor.tcl]]
+set auto_index(bg2) [list source -encoding utf-8 [file join $dir floor.tcl]]
+set auto_index(bg3) [list source -encoding utf-8 [file join $dir floor.tcl]]
+set auto_index(fg1) [list source -encoding utf-8 [file join $dir floor.tcl]]
+set auto_index(fg2) [list source -encoding utf-8 [file join $dir floor.tcl]]
+set auto_index(fg3) [list source -encoding utf-8 [file join $dir floor.tcl]]
+set auto_index(setWidth) [list source -encoding utf-8 [file join $dir hscale.tcl]]
+set auto_index(plotDown) [list source -encoding utf-8 [file join $dir plot.tcl]]
+set auto_index(plotMove) [list source -encoding utf-8 [file join $dir plot.tcl]]
+set auto_index(puzzleSwitch) [list source -encoding utf-8 [file join $dir puzzle.tcl]]
+set auto_index(setHeight) [list source -encoding utf-8 [file join $dir vscale.tcl]]
+set auto_index(showMessageBox) [list source -encoding utf-8 [file join $dir msgbox.tcl]]
+set auto_index(setColor) [list source -encoding utf-8 [file join $dir clrpick.tcl]]
+set auto_index(setColor_helper) [list source -encoding utf-8 [file join $dir clrpick.tcl]]
+set auto_index(fileDialog) [list source -encoding utf-8 [file join $dir filebox.tcl]]

janus/lib/tk8.6/demos/tcolor

@@ -0,0 +1,358 @@
+#!/bin/sh
+# the next line restarts using wish \
+exec wish8.6 "$0" ${1+"$@"}
+
+# tcolor --
+# This script implements a simple color editor, where you can
+# create colors using either the RGB, HSB, or CYM color spaces
+# and apply the color to existing applications.
+
+package require Tk
+wm title . "Color Editor"
+
+# Global variables that control the program:
+#
+# colorSpace -			Color space currently being used for
+#				editing.  Must be "rgb", "cmy", or "hsb".
+# label1, label2, label3 -	Labels for the scales.
+# red, green, blue -		Current color intensities in decimal
+#				on a scale of 0-65535.
+# color -			A string giving the current color value
+#				in the proper form for x:
+#				#RRRRGGGGBBBB
+# updating -			Non-zero means that we're in the middle of
+#				updating the scales to load a new color,so
+#				information shouldn't be propagating back
+#				from the scales to other elements of the
+#				program:  this would make an infinite loop.
+# command -			Holds the command that has been typed
+#				into the "Command" entry.
+# autoUpdate -			1 means execute the update command
+#				automatically whenever the color changes.
+# name -			Name for new color, typed into entry.
+
+set colorSpace hsb
+set red 65535
+set green 0
+set blue 0
+set color #ffff00000000
+set updating 0
+set autoUpdate 1
+set name ""
+
+# Create the menu bar at the top of the window.
+
+. configure -menu [menu .menu]
+menu .menu.file
+.menu add cascade  -menu .menu.file  -label File  -underline 0
+.menu.file add radio -label "RGB color space" -variable colorSpace \
+	-value rgb -underline 0 -command {changeColorSpace rgb}
+.menu.file add radio -label "CMY color space" -variable colorSpace \
+	-value cmy -underline 0 -command {changeColorSpace cmy}
+.menu.file add radio -label "HSB color space" -variable colorSpace \
+	-value hsb -underline 0 -command {changeColorSpace hsb}
+.menu.file add separator
+.menu.file add radio -label "Automatic updates" -variable autoUpdate \
+	-value 1 -underline 0
+.menu.file add radio -label "Manual updates" -variable autoUpdate \
+	-value 0 -underline 0
+.menu.file add separator
+.menu.file add command -label "Exit program" -underline 0 -command {exit}
+
+# Create the command entry window at the bottom of the window, along
+# with the update button.
+
+labelframe .command -text "Command:" -padx {1m 0}
+entry .command.e -textvariable command
+button .command.update -text Update -command doUpdate
+pack .command.update -side right -pady .1c -padx {.25c 0}
+pack .command.e -expand yes -fill x -ipadx 0.25c
+
+
+# Create the listbox that holds all of the color names in rgb.txt,
+# if an rgb.txt file can be found.
+
+grid .command -sticky nsew -row 2 -columnspan 3 -padx 1m -pady {0 1m}
+
+grid columnconfigure . {1 2} -weight 1
+grid rowconfigure . 0 -weight 1
+foreach i {
+    /usr/local/lib/X11/rgb.txt /usr/lib/X11/rgb.txt
+    /X11/R5/lib/X11/rgb.txt /X11/R4/lib/rgb/rgb.txt
+    /usr/openwin/lib/X11/rgb.txt
+} {
+    if {![file readable $i]} {
+	continue;
+    }
+    set f [open $i]
+    labelframe .names -text "Select:" -padx .1c -pady .1c
+    grid .names -row 0 -column 0 -sticky nsew -padx .15c -pady .15c -rowspan 2
+    grid columnconfigure . 0 -weight 1
+    listbox .names.lb -width 20 -height 12 -yscrollcommand ".names.s set" \
+	-exportselection false
+    bind .names.lb <Double-Button-1> {
+	    tc_loadNamedColor [.names.lb get [.names.lb curselection]]
+    }
+    scrollbar .names.s -orient vertical -command ".names.lb yview"
+    pack .names.lb .names.s -side left -fill y -expand 1
+    while {[gets $f line] >= 0} {
+	if {[regexp {^\s*\d+\s+\d+\s+\d+\s+(\S+)$} $line -> col]} {
+	    .names.lb insert end $col
+	}
+    }
+    close $f
+    break
+}
+
+# Create the three scales for editing the color, and the entry for
+# typing in a color value.
+
+frame .adjust
+foreach i {1 2 3} {
+    label .adjust.l$i -textvariable label$i -pady 0
+    labelframe .adjust.$i -labelwidget .adjust.l$i -padx 1m -pady 1m
+    scale .scale$i -from 0 -to 1000 -length 6c -orient horizontal \
+	    -command tc_scaleChanged
+    pack .scale$i -in .adjust.$i
+    pack .adjust.$i
+}
+grid .adjust -row 0 -column 1 -sticky nsew -padx .15c -pady .15c
+
+labelframe .name -text "Name:" -padx 1m -pady 1m
+entry .name.e -textvariable name -width 10
+pack .name.e -side right -expand 1 -fill x
+bind .name.e <Return> {tc_loadNamedColor $name}
+grid .name   -column 1 -row 1 -sticky nsew -padx .15c -pady .15c
+
+# Create the color display swatch on the right side of the window.
+
+labelframe .sample -text "Color:" -padx 1m -pady 1m
+frame .sample.swatch -width 2c -height 5c -background $color
+label .sample.value -textvariable color -width 13 -font {Courier 12}
+pack .sample.swatch -side top -expand yes -fill both
+pack .sample.value -side bottom -pady .25c
+grid .sample -row 0 -column 2 -sticky nsew -padx .15c -pady .15c -rowspan 2
+
+
+# The procedure below is invoked when one of the scales is adjusted.
+# It propagates color information from the current scale readings
+# to everywhere else that it is used.
+
+proc tc_scaleChanged args {
+    global red green blue colorSpace color updating autoUpdate
+    if {$updating} {
+	return
+    }
+    switch $colorSpace {
+	rgb {
+	    set red   [format %.0f [expr {[.scale1 get]*65.535}]]
+	    set green [format %.0f [expr {[.scale2 get]*65.535}]]
+	    set blue  [format %.0f [expr {[.scale3 get]*65.535}]]
+	}
+	cmy {
+	    set red   [format %.0f [expr {65535 - [.scale1 get]*65.535}]]
+	    set green [format %.0f [expr {65535 - [.scale2 get]*65.535}]]
+	    set blue  [format %.0f [expr {65535 - [.scale3 get]*65.535}]]
+	}
+	hsb {
+	    set list [hsbToRgb [expr {[.scale1 get]/1000.0}] \
+		    [expr {[.scale2 get]/1000.0}] \
+		    [expr {[.scale3 get]/1000.0}]]
+	    set red [lindex $list 0]
+	    set green [lindex $list 1]
+	    set blue [lindex $list 2]
+	}
+    }
+    set color [format "#%04x%04x%04x" $red $green $blue]
+    .sample.swatch config -bg $color
+    if {$autoUpdate} doUpdate
+    update idletasks
+}
+
+# The procedure below is invoked to update the scales from the
+# current red, green, and blue intensities.  It's invoked after
+# a change in the color space and after a named color value has
+# been loaded.
+
+proc tc_setScales {} {
+    global red green blue colorSpace updating
+    set updating 1
+    switch $colorSpace {
+	rgb {
+	    .scale1 set [format %.0f [expr {$red/65.535}]]
+	    .scale2 set [format %.0f [expr {$green/65.535}]]
+	    .scale3 set [format %.0f [expr {$blue/65.535}]]
+	}
+	cmy {
+	    .scale1 set [format %.0f [expr {(65535-$red)/65.535}]]
+	    .scale2 set [format %.0f [expr {(65535-$green)/65.535}]]
+	    .scale3 set [format %.0f [expr {(65535-$blue)/65.535}]]
+	}
+	hsb {
+	    set list [rgbToHsv $red $green $blue]
+	    .scale1 set [format %.0f [expr {[lindex $list 0] * 1000.0}]]
+	    .scale2 set [format %.0f [expr {[lindex $list 1] * 1000.0}]]
+	    .scale3 set [format %.0f [expr {[lindex $list 2] * 1000.0}]]
+	}
+    }
+    set updating 0
+}
+
+# The procedure below is invoked when a named color has been
+# selected from the listbox or typed into the entry.  It loads
+# the color into the editor.
+
+proc tc_loadNamedColor name {
+    global red green blue color autoUpdate
+
+    if {[string index $name 0] != "#"} {
+	set list [winfo rgb .sample.swatch $name]
+	set red [lindex $list 0]
+	set green [lindex $list 1]
+	set blue [lindex $list 2]
+    } else {
+	switch [string length $name] {
+	    4  {set format "#%1x%1x%1x"; set shift 12}
+	    7  {set format "#%2x%2x%2x"; set shift 8}
+	    10 {set format "#%3x%3x%3x"; set shift 4}
+	    13 {set format "#%4x%4x%4x"; set shift 0}
+	    default {error "syntax error in color name \"$name\""}
+	}
+	if {[scan $name $format red green blue] != 3} {
+	    error "syntax error in color name \"$name\""
+	}
+	set red   [expr {$red<<$shift}]
+	set green [expr {$green<<$shift}]
+	set blue  [expr {$blue<<$shift}]
+    }
+    tc_setScales
+    set color [format "#%04x%04x%04x" $red $green $blue]
+    .sample.swatch config -bg $color
+    if {$autoUpdate} doUpdate
+}
+
+# The procedure below is invoked when a new color space is selected.
+# It changes the labels on the scales and re-loads the scales with
+# the appropriate values for the current color in the new color space
+
+proc changeColorSpace space {
+    global label1 label2 label3
+    switch $space {
+	rgb {
+	    set label1 "Adjust Red:"
+	    set label2 "Adjust Green:"
+	    set label3 "Adjust Blue:"
+	    tc_setScales
+	    return
+	}
+	cmy {
+	    set label1 "Adjust Cyan:"
+	    set label2 "Adjust Magenta:"
+	    set label3 "Adjust Yellow:"
+	    tc_setScales
+	    return
+	}
+	hsb {
+	    set label1 "Adjust Hue:"
+	    set label2 "Adjust Saturation:"
+	    set label3 "Adjust Brightness:"
+	    tc_setScales
+	    return
+	}
+    }
+}
+
+# The procedure below converts an RGB value to HSB.  It takes red, green,
+# and blue components (0-65535) as arguments, and returns a list containing
+# HSB components (floating-point, 0-1) as result.  The code here is a copy
+# of the code on page 615 of "Fundamentals of Interactive Computer Graphics"
+# by Foley and Van Dam.
+
+proc rgbToHsv {red green blue} {
+    if {$red > $green} {
+	set max [expr {double($red)}]
+	set min [expr {double($green)}]
+    } else {
+	set max [expr {double($green)}]
+	set min [expr {double($red)}]
+    }
+    if {$blue > $max} {
+	set max [expr {double($blue)}]
+    } elseif {$blue < $min} {
+	set min [expr {double($blue)}]
+    }
+    set range [expr {$max-$min}]
+    if {$max == 0} {
+	set sat 0
+    } else {
+	set sat [expr {($max-$min)/$max}]
+    }
+    if {$sat == 0} {
+	set hue 0
+    } else {
+	set rc [expr {($max - $red)/$range}]
+	set gc [expr {($max - $green)/$range}]
+	set bc [expr {($max - $blue)/$range}]
+	if {$red == $max} {
+	    set hue [expr {($bc - $gc)/6.0}]
+	} elseif {$green == $max} {
+	    set hue [expr {(2 + $rc - $bc)/6.0}]
+	} else {
+	    set hue [expr {(4 + $gc - $rc)/6.0}]
+	}
+	if {$hue < 0.0} {
+	    set hue [expr {$hue + 1.0}]
+	}
+    }
+    return [list $hue $sat [expr {$max/65535}]]
+}
+
+# The procedure below converts an HSB value to RGB.  It takes hue, saturation,
+# and value components (floating-point, 0-1.0) as arguments, and returns a
+# list containing RGB components (integers, 0-65535) as result.  The code
+# here is a copy of the code on page 616 of "Fundamentals of Interactive
+# Computer Graphics" by Foley and Van Dam.
+
+proc hsbToRgb {hue sat value} {
+    set v [format %.0f [expr {65535.0*$value}]]
+    if {$sat == 0} {
+	return "$v $v $v"
+    } else {
+	set hue [expr {$hue*6.0}]
+	if {$hue >= 6.0} {
+	    set hue 0.0
+	}
+	scan $hue. %d i
+	set f [expr {$hue-$i}]
+	set p [format %.0f [expr {65535.0*$value*(1 - $sat)}]]
+	set q [format %.0f [expr {65535.0*$value*(1 - ($sat*$f))}]]
+	set t [format %.0f [expr {65535.0*$value*(1 - ($sat*(1 - $f)))}]]
+	switch $i {
+	    0 {return "$v $t $p"}
+	    1 {return "$q $v $p"}
+	    2 {return "$p $v $t"}
+	    3 {return "$p $q $v"}
+	    4 {return "$t $p $v"}
+	    5 {return "$v $p $q"}
+	    default {error "i value $i is out of range"}
+	}
+    }
+}
+
+# The procedure below is invoked when the "Update" button is pressed,
+# and whenever the color changes if update mode is enabled.  It
+# propagates color information as determined by the command in the
+# Command entry.
+
+proc doUpdate {} {
+    global color command
+    set newCmd $command
+    regsub -all %% $command $color newCmd
+    eval $newCmd
+}
+
+changeColorSpace hsb
+
+# Local Variables:
+# mode: tcl
+# End:

janus/lib/tk8.6/demos/text.tcl

@@ -0,0 +1,113 @@
+# text.tcl --
+#
+# This demonstration script creates a text widget that describes
+# the basic editing functions.
+
+if {![info exists widgetDemo]} {
+    error "This script should be run from the \"widget\" demo."
+}
+
+package require Tk
+
+set w .text
+catch {destroy $w}
+toplevel $w
+wm title $w "Text Demonstration - Basic Facilities"
+wm iconname $w "text"
+positionWindow $w
+
+## See Code / Dismiss buttons
+set btns [addSeeDismiss $w.buttons $w {} \
+	{ttk::button $w.buttons.fontchooser -command fontchooserToggle}]
+pack $btns -side bottom -fill x
+
+text $w.text -yscrollcommand [list $w.scroll set] -setgrid 1 \
+	-height 30 -undo 1 -autosep 1
+ttk::scrollbar $w.scroll -command [list $w.text yview]
+pack $w.scroll -side right -fill y
+pack $w.text -expand yes -fill both
+
+# TIP 324 Demo: [tk fontchooser]
+proc fontchooserToggle {} {
+    tk fontchooser [expr {[tk fontchooser configure -visible] ?
+            "hide" : "show"}]
+}
+proc fontchooserVisibility {w} {
+    $w configure -text [expr {[tk fontchooser configure -visible] ?
+            "Hide Font Dialog" : "Show Font Dialog"}]
+}
+proc fontchooserFocus {w} {
+    tk fontchooser configure -font [$w cget -font] \
+	    -command [list fontchooserFontSel $w]
+}
+proc fontchooserFontSel {w font args} {
+    $w configure -font [font actual $font]
+}
+tk fontchooser configure -parent $w
+bind $w.text <FocusIn> [list fontchooserFocus $w.text]
+fontchooserVisibility $w.buttons.fontchooser
+bind $w <<TkFontchooserVisibility>> [list \
+	fontchooserVisibility $w.buttons.fontchooser]
+focus $w.text
+
+$w.text insert 0.0 \
+{This window is a text widget.  It displays one or more lines of text
+and allows you to edit the text.  Here is a summary of the things you
+can do to a text widget:
+
+1. Scrolling. Use the scrollbar to adjust the view in the text window.
+
+2. Scanning. Press the middle mouse button in the text window and drag up
+or down. This will drag the text at high speed to allow you to scan its
+contents.
+
+3. Insert text. Press mouse button 1 to set the insertion cursor, then
+type text.  What you type will be added to the widget.
+
+4. Select. Press mouse button 1 and drag to select a range of characters.
+Once you've released the button, you can adjust the selection by pressing
+button 1 with the shift key down.  This will reset the end of the
+selection nearest the mouse cursor and you can drag that end of the
+selection by dragging the mouse before releasing the mouse button.
+You can double-click to select whole words or triple-click to select
+whole lines.
+
+5. Delete and replace. To delete text, select the characters you'd like
+to delete and type Backspace or Delete.  Alternatively, you can type new
+text, in which case it will replace the selected text.
+
+6. Copy the selection. To copy the selection into this window, select
+what you want to copy (either here or in another application), then
+click the middle mouse button to copy the selection to the point of the
+mouse cursor.
+
+7. Edit.  Text widgets support the standard Motif editing characters
+plus many Emacs editing characters.  Backspace and Control-h erase the
+character to the left of the insertion cursor.  Delete and Control-d
+erase the character to the right of the insertion cursor.  Meta-backspace
+deletes the word to the left of the insertion cursor, and Meta-d deletes
+the word to the right of the insertion cursor.  Control-k deletes from
+the insertion cursor to the end of the line, or it deletes the newline
+character if that is the only thing left on the line.  Control-o opens
+a new line by inserting a newline character to the right of the insertion
+cursor.  Control-t transposes the two characters on either side of the
+insertion cursor.  Control-z undoes the last editing action performed,
+and }
+
+switch [tk windowingsystem] {
+    "aqua" - "x11" {
+	$w.text insert end "Control-Shift-z"
+    }
+    "win32" {
+	$w.text insert end "Control-y"
+    }
+}
+
+$w.text insert end { redoes undone edits.
+
+7. Resize the window.  This widget has been configured with the "setGrid"
+option on, so that if you resize the window it will always resize to an
+even number of characters high and wide.  Also, if you make the window
+narrow you can see that long lines automatically wrap around onto
+additional lines so that all the information is always visible.}
+$w.text mark set insert 0.0

janus/lib/tk8.6/demos/timer

@@ -0,0 +1,47 @@
+#!/bin/sh
+# the next line restarts using wish \
+exec wish8.6 "$0" ${1+"$@"}
+
+# timer --
+# This script generates a counter with start and stop buttons.
+
+package require Tk
+
+label .counter -text 0.00 -relief raised -width 10 -padx 2m -pady 1m
+button .start -text Start -command {
+    if {$stopped} {
+	set stopped 0
+	set startMoment [clock clicks -milliseconds]
+	tick
+	.stop configure -state normal
+	.start configure -state disabled
+    }
+}
+button .stop -text Stop -state disabled -command {
+    set stopped 1
+    .stop configure -state disabled
+    .start configure -state normal
+}
+pack .counter -side bottom -fill both
+pack .start -side left -fill both -expand yes
+pack .stop -side right -fill both -expand yes
+
+set startMoment {}
+
+set stopped 1
+
+proc tick {} {
+    global startMoment stopped
+    if {$stopped} {return}
+    after 50 tick
+    set elapsedMS [expr {[clock clicks -milliseconds] - $startMoment}]
+    .counter config -text [format "%.2f" [expr {double($elapsedMS)/1000}]]
+}
+
+bind . <Control-c> {destroy .}
+bind . <Control-q> {destroy .}
+focus .
+
+# Local Variables:
+# mode: tcl
+# End: