File size: 4,501 Bytes
ede104b |
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 |
***********Does Public Opinion affect the Preferences of Foreign Policy Leaders? Experimental Evidence from the UK Parliament
***********Journal of Politics
***********Jonathan A. Chu and Stefano Recchia
***********Author contact information at: jonathanchu.org
cd "[insert file location of JOP_ChuRecchia_ReplicationData.dta]"
use JOP_ChuRecchia_ReplicationData.dta
svyset [pw=weight_pr]
**************Main Manuscript: Figure 1
**************Main Manuscript: Figure 1
histogram dv_full [fw=weight_freq] if t_poll==0 , discrete percent fcolor(ebblue*0.6) lcolor(white) ///
subtitle( , lcolor(white) fcolor(white) size(large) ) ///
title("Not given polling information (control group)", margin(medium) color(black) pos(6)) ///
ylab(0(10)70, angle(horizontal) nogmin gmax grid nogextend glcolor(gray*0.3) glwidth(vthin) notick) ///
ytitle("", size (medlarge) margin(medsmall)) ///
yscale(lcolor(white) ) xscale(line lcolor(black) ) ///
xlab(1(1)3 1 "Cease" 2 "Continue" 3 "DK/Other", labsize(medium) notick) ///
xtitle("", size (medlarge) margin(medsmall)) ///
graphregion(fcolor(white) lcolor(white)) bgcolor(white) xsize(10) ysize(8) ///
legend(off) name (control_weights, replace)
histogram dv_full [fw=weight_freq] if t_poll==1 , discrete percent fcolor(ebblue*0.6) lcolor(white) ///
subtitle( , lcolor(white) fcolor(white) size(large) ) ///
title("Given polling information (treatment group)", margin(medium) color(black) pos(6)) ///
ylab(0(10)70, angle(horizontal) nogmin gmax grid nogextend glcolor(gray*0.3) glwidth(vthin) notick) ///
ytitle("", size (medlarge) margin(medsmall)) ///
yscale(lcolor(white) ) xscale(line lcolor(black) ) ///
xlab(1(1)3 1 "Cease" 2 "Continue" 3 "DK/Other", labsize(medium) notick) ///
xtitle("", size (medlarge) margin(medsmall)) ///
graphregion(fcolor(white) lcolor(white)) bgcolor(white) xsize(10) ysize(8) ///
legend(off) name (treatment_weights, replace)
graph combine control_weights treatment_weights, ///
title("Views on Military Presence in the South China Sea", size(vlarge) margin(small) color(black) pos(11) ) ///
subtitle("% of MPs who believe that the UK should ____ activity in the South China Sea", size(medium) margin(small) color(black) pos(11) ) ///
xcommon ycommon ///
graphregion(fcolor(white) ilcolor(white) lcolor(white)) plotregion(color(white) margin(b = 0)) ///
xsize(16) ysize(9) name(histograms_compare, replace)
**************Appendix: Table A1
**************Appendix: Table A1
tab female t_poll, col
tab conservative t_poll, col
tab labour t_poll, col
tab other_party t_poll, col
*************Appendix: Note at bottom of Table A1: no difference is significant at 0.10 level
svy: reg female t_poll
svy: reg conservative t_poll
svy: reg labour t_poll
svy: reg other_party t_poll
**************Appendix: Table A2
**************Appendix: Table A2
***Column 1
svy: mean (dv_cease100) if t_poll==1 // dependent variable scaled to be out of 100
svy: mean (dv_continue100) if t_poll==1
svy: mean (dv_otherDK100) if t_poll==1
***Column 2
svy: mean (dv_cease100) if t_poll==0
svy: mean (dv_continue100) if t_poll==0
svy: mean (dv_otherDK100) if t_poll==0
***Column 3
svy: reg dv_cease100 t_poll
svy: reg dv_continue100 t_poll
svy: reg dv_otherDK100 t_poll
**************Appendix: Figure A1
**************Appendix: Figure A1
svy: reg dv_continue100 t_poll if female==0
estimates store poll_male
svy: reg dv_continue100 t_poll if female ==1
estimates store poll_female
svy: reg dv_continue100 t_poll female
estimates store poll_control
coefplot ///
(poll_male, offset(0.3) label ("Effect among Men") msymbol(square) msize(huge) mfcolor(white) color(black) ciopts(recast(rcap) color(black)) level(90)) ///
(poll_female, offset(0) label ("Effect among Women") msymbol(square) msize(huge) mfcolor(black*0.5) color(black) ciopts(recast(rcap) color(black)) level(90)) ///
(poll_control, offset(-0.3) label ("Effect controlling for Gender") msymbol(square) msize(huge) color(black) ciopts(recast(rcap) color(black)) level(90)) ///
, drop(_cons female) xline(0, lcolor(black*0.7) lp(dash) ) ///
xtitle( "Percentage Point Effect of Public Opinion", size (large) margin(medlarge)) ///
graphregion(fcolor(white) lcolor(white)) bgcolor(white) ///
yscale(off) xscale (line noextend) xlab(-20(10)60) ///
legend (region(lcolor(white)) pos (11) col(1) ) xsize(10) ysize(12) name(Poll_Gender, replace)
|