24/replication_package/Code/analysis.do

************************************************************************************************************************************
*** CLIENTS -MAIN TEXT ****
************************************************************************************************************************************

clear
u "${data}Clients_Main.dta"
*** We recruited clients ($N=924$) later (page 21)
**** Overall, 84\% of clients followed the advisor's recommendation (p.21)
tab follow

*** Footnote 18 (p.22) 
clear
u "${data}Clients_MPL.dta"
*** we recruited a total of 866 clients (p. 22)
**** Of these, 80% of clients followed the advisor's recommendation (p. 22)
tab follow

*** Footnote 19 (p.22) 
clear
u "${data}Clients_Blinding.dta"
*** we recruited 188 advisees (p. 22)
**** Of these, 84% followed the advisors' recommendation. (p. 22)
tab follow

****** TABLE 1 *** SAMPLE SIZES in the table
*NoChoice, SeeIncentiveFirst N=152; Assess Quality First N=147
	u "${data}nochoice.dta", clear
	drop if alphavaluefinal==.
	tab seeincentivefirst
	
*Choice, ChoiceFreeProfessionals=712;ChoiceFree=2574;  
        *See IncentiveFirst Costly=1562; AssessQualityFirst Costly=1067
		u "${data}choice_experiments.dta", clear
		drop if study!=1 & alphavaluefinal==.
		tab condition if Highx10==0 & Highx100==0
		* ChoiceFree -HighStakes (10-fold)=275
		tab condition if Highx10==1
		* ChoiceFree -HighStakes (100-fold)=110
		tab condition if Highx100==1

*ChoiceDeterministic, Replication=385; Deterministic=369
		u "${data}Choice_Deterministic.dta", clear
		drop if alphavaluefinal==.
		tab Deterministic

***ChoiceStakes, Low Incentive=483; IntermediateIncentive=511; HighIncentive=478
		u "${data}stakes.dta", clear
		drop if alphavaluefinal==.
		tab condition

***Information Architect: IA-Advisor=245; IA-Client=253
		u "${data}InformationArchitect.dta", clear
		drop if alphavaluefinal==.
		tab IAAdvisor

*** Total sample size in Table 1: N=9323
di 152+147+712+2574+1562+1067+275+110+385+369+483+511+478+245+253

************************************************************************************************************************************
************************************************************************************************************************************

*    NO CHOICE - MAIN TEXT  

************************************************************************************************************************************
************************************************************************************************************************************
************************************************************************************************************************************
clear
u "${data}nochoice.dta"


drop if alphavaluefinal==.

*PROPORTION TESTS	
prtest recommendincentive if conflict==1, by(seeincentivefirst)
prtest recommendincentive if conflict==0, by(seeincentivefirst)

*** NOCHOICE VS CHOICE COMPARISON for Table C.17 in the Appendix
mean  recommendincentive if seeincentivefirst==1 & conflict==1
mean  recommendincentive if seeincentivefirst==0 & conflict==1

reg recommendincentive seeincentivefirst##noconflict female age, vce(hc3)

*ADDITIONAL DESCRIPTIVES - BY COMMISSION	
estpost summarize recommendincentive ///
	recommendincentive_before recommendincentive_after if conflict==1,detail 
eststo d_nochoice


forvalues i=0(1)1{
estpost summarize recommendincentive ///
	recommendincentive_before recommendincentive_after if incentiveA==`i' & conflict==1,detail 
eststo d_nochoice`i'
}

** "Throughout, advisors exhibit a preference for product A"
tabstat recommendincentive if incentiveB==1 & noconflict==1, stats(mean n)
** "recommending it 16% of the times even when the quality signal is a $2 ball and the advisor is incentivized to recommend B
gen notrecommendincentive=1-recommendincentive
tabstat notrecommendincentive if incentiveB==1 & noconflict==1, stats(mean n)
/*reg recommendincentive noconflict incentiveB female age stdalpha 

	if missingalpha==0, vce(hc3) */


*FIGURE NO CHOICE - RECOMMENDATIONS		
bys before conflict: egen meanrec=mean(recommendincentive)
bys before conflict: egen sdrec=sd(recommendincentive) 
bys before conflict: egen nrec=count(recommendincentive)

*Binomial SE (formula: sqrt(p(1-p)/n))
g lorec=meanrec-1.96*(sqrt((meanrec*(1-meanrec))/nrec))
g hirec=meanrec+1.96*(sqrt((meanrec*(1-meanrec))/nrec))

gen xaxis=0 if before==1 & conflict==1
replace xaxis=1 if before==0 & conflict==1
replace xaxis=2.5 if before==1 & conflict==0
replace xaxis=3.5 if before==0 & conflict==0


twoway 	(bar meanrec xaxis if before==1 & conflict==1, color(black) barw(0.7)) ///
(bar meanrec xaxis if before==0 & conflict==1, fcolor(white) lcolor(black) barw(0.7) ) ///
(bar meanrec xaxis if before==1 & conflict==0, color(black) barw(0.7)) ///
(bar meanrec xaxis if before==0 & conflict==0, color(white) lcolor(black) barw(0.7)) ///
(rcap lorec hirec xaxis , lcolor(black*0.3) lwidth(medthick)) ///
, xtitle(" ") ///
ytitle("{bf: Incentivized Product Recommendation}") ///
graphr(c(white)) plotr(c(white)) ///
ylabel(0(0.1)1, gmax) ///
xlabel(0.5 "{bf: Conflict}"  3 "{bf: No Conflict}" ) ///
xscale(r(-0.5 3.5)) legend(order(1 "See Incentive First" 2 "See Quality First"))
graph export "${main}/nochoice_recommendations.png", replace


*REGRESSIONS (Reported in Appendix C.1)
clear 
u "${data}nochoice.dta"

*******APPENDIX*********
** MAIN REGRESSION (APPENDIX, TABLE C.1)
est clear
eststo:reg recommendincentive seeincentivefirst noconflict   incentiveB female age stdalpha  if missingalpha==0 & conflict==1, vce(hc3)
eststo:reg recommendincentive seeincentivefirst noconflict   incentiveB female age  stdalpha if missingalpha==0 & conflict==0, vce(hc3)
eststo:reg recommendincentive seeincentivefirst noconflict seeincentivefirst_noconflict   incentiveB female age stdalpha  if missingalpha==0, vce(hc3)

local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{11}\selectfont" "\caption{Recommendations}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "$\ \ \ \ \ \ \ \ \ \ \ \ \ \ $    &\multicolumn{1}{c}{\textbf{Conflict }} &\multicolumn{1}{c}{\textbf{No Conflict}} & \multicolumn{1}{c}{\textbf{Both}} \\\hline & & & \\"

esttab using "${appendix}NoChoice_Recommendations.tex",  se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (seeincentivefirst "See Incentive First" noconflict "No Conflict" seeincentivefirst_noconflict "See Incentive First * No Conflict"  ///
 incentiveB "Incentive for B" ///
female "Female" age "Age" stdalpha "Selfishness"  ) ///
order ( seeincentivefirst noconflict seeincentivefirst_noconflict  incentiveB female age stdalpha) collabels(none) ///
drop ( female age) ///
star( * 0.10 ** 0.05 *** 0.01) ///
nomtitle label substitute(" 0.000 " " " " (.) " " ") ///
prehead("`panel'") posthead("`dv'") postfoot("\hline" "\end{tabular}%" "\captionsetup{width=0.7\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the advisors' recommendations. See Incentive first is a binary indicator coded as 1 for participants who were randomly assigned to see the incentive first. Selfishness is a standardized measure of the number of times the advisor chose to recommend the incentivized product in the MPL task aimed at measuring moral costs. The sample includes attentive participants who did not switch multiple times in this elicitation. The regression includes individual controls for the advisor's gender and age. Robust standard errors (HC3) in parentheses}" "\label{tab:nochoicerec}" "\end{table}")


** REGRESSION THAT INCLUDES INATTENTIVE (APPENDIX, TABLE C.2)
clear
u "${data}nochoice.dta"



est clear 
eststo:reg recommendincentive seeincentivefirst noconflict   incentiveB female age   if conflict==1, vce(hc3)
eststo:reg recommendincentive seeincentivefirst noconflict   incentiveB female age   if conflict==0, vce(hc3)
eststo:reg recommendincentive seeincentivefirst noconflict seeincentivefirst_noconflict   incentiveB female age, vce(hc3)

local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{11}\selectfont" "\caption{Recommendations including Inattentive}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "$\ \ \ \ \ \ \ \ \ \ \ \ \ \ $    &\multicolumn{1}{c}{\textbf{Conflict }} &\multicolumn{1}{c}{\textbf{No Conflict}} & \multicolumn{1}{c}{\textbf{Both}} \\\hline & & & \\"

esttab using  "${appendix}NoChoice_Recommendations_Inattentive.tex",  se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) collabels(none) ///
coeflabel (seeincentivefirst "See Incentive First" noconflict "No Conflict" seeincentivefirst_noconflict "See Incentive First * No Conflict"  ///
 incentiveB "Incentive for B" ///
female "Female" age "Age"  ) ///
order ( seeincentivefirst noconflict seeincentivefirst_noconflict  incentiveB female age) ///
drop ( female age) ///
star( * 0.10 ** 0.05 *** 0.01) ///
nomtitle label substitute(" 0.000 " " " " (.) " " ") ///
prehead("`panel'") posthead("`dv'") postfoot("\hline" "\end{tabular}%" "\captionsetup{width=0.7\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the advisors' recommendations. See Incentive first is a binary indicator coded as 1 for participants who were randomly assigned to see the incentive first. The sample includes all participants, including those who switched multiple times in the MPL task to measure moral costs.  The regression includes individual controls for the advisor's gender and age. Robust standard errors (HC3) in parentheses}" "\label{tab:nochoicerec_inattentive}" "\end{table}")


/************************************************************************************************************************************

************************************************************************************************************************************



    CHOICE -  MAIN TEXT 



************************************************************************************************************************************

************************************************************************************************************************************

************************************************************************************************************************************/


clear
u "${data}choice_experiments.dta"

*As pre-registered, drop Mturk participant with inconsistent alpha value
drop if study!=1 & alphavaluefinal==. /*(study1 are profs and there's no MPL')*/

************************************
/*FOOTNOTE 13

PROFESSIONALS: Comparison Prolific / CloudResearch

************************************



We pool these two samples since choices regarding the preferred sequence of information 

did not vary significantly across them ($p$=0.308) */
prtest choicebefore if study==1, by(sample)
*and recommendations did not differ either ($p$=0.820). 
reg recommendincentive cloudresearch conflict female age locatedus  if study==1

************************************
/*FOOTNOTE 15

************************************

*"We found no effect of incentive size, order or their interaction on the preference to see the incentive first ")*/
 reg choicebefore incentiveshigh##incentiveleft if study==4, ro

*"We also found no effect of incentive size, order or their interaction on recommendations)
reg recommendincentive incentiveshigh##incentiveleft if study==4 & conflict==1, ro
************************************


******************************************************************************************************************************************
******************************************************************************************************************************************
** PREFERENCES / DEMAND - MAIN TEXT 
******************************************************************************************************************************************
******************************************************************************************************************************************

global covariates "wave2 wave3 professionalscloudresearch incentiveshigh##incentiveleft age female"	
global covariates2 "professionalsfree seeincentivecostly seequalitycostly wave2 wave3 professionalscloudresearch incentiveshigh incentiveleft incentiveshigh_incentiveleft age female"

*FIGURE 4: ADVISOR PREFERENCES

eststo:reg choicebefore i.treatment $covariates if Highx10==0 & Highx100==0, vce(hc3)
margins i.treatment, atmeans saving("${main}Choice_adjusted_demand", replace)

*return list
matrix coeffs=r(table)
matrix list coeffs

g preddemand=coeffs[1,1] if treatment==0
g sepreddemand=coeffs[2,1] if treatment==0
forval i=2(1)4{
	local j=`i'-1
replace preddemand=coeffs[1,`i'] if treatment==`j'
replace sepreddemand=coeffs[2,`i'] if treatment==`j'
}
g ubpreddemand=preddemand+1.96*sepreddemand
g lbpreddemand=preddemand-1.96*sepreddemand

g xaxis=1 if treatment==1
replace xaxis=3.10 if treatment==2
replace xaxis=2.10 if treatment==0
replace xaxis=4.10 if treatment==3

g meancommit=1
			
		twoway (bar meancommit xaxis, ///
		lcolor(gs10) fcolor(white) barw(0.5) ) ///
		(bar preddemand xaxis, color(gs10) barw(0.5) ) ///
		(rcap  ubpreddemand lbpreddemand xaxis if xaxis!=., color(gs9) lwidth(*0.5)) ///
		, xtitle(Study) ///
			ytitle("Advisor preference") ///
			graphr(c(white)) plotr(c(white)) ///
			ylabel(0(0.2)1, gmax) ///
			xlabel(			2.10 `" "Choice" "Free" "' ///
			1 `" "Choice Free" "- Professionals" "' ///
			4.10 `" "Quality First" "Costly" "' ///
			3.10 `" "Incentive First" "Costly" "') ///
			xscale(r(0.5 3.5)) legend(lab(1 "Prefer to assess quality first") ///
			lab(2 "Prefer to see incentive first") order(2 1)) /// 
			xtitle("") ///
			text(0.8 1 "0.55", color(black)) text(0.30 1 "0.45", color(black))  ///
			text(0.8 2.10 "0.45") text(0.30 2.10 "0.55") ///
			text(0.8 3.10 "0.59")text(0.30 3.10 "0.41") ///
			text(0.8 4.10 "0.30")  text(0.30 4.10 "0.70") 
			*graph export "${main}Demand_predicted_errorbars.png", replace
			graph export "${main}Choice_Demand_predicted_errorbars.pdf", replace

			
*TABLE 2: PREFERENCES FOR INFORMATION ORDER
est clear
eststo:reg choicebefore $covariates2 if Highx10==0 & Highx100==0, vce(hc3)
eststo:reg choicebefore $covariates2 stdalpha if Highx10==0 & Highx100==0 & professionals==0, vce(hc3)
eststo:reg choicebefore $covariates2 stdalpha selfishseeincentivecostly selfishseequalitycostly if Highx10==0 & Highx100==0, vce(hc3)

local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{11}\selectfont" "\caption{Preference for Information Order}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "$\ \ \ \ \ \ \ \ \ \ \ \ \ \ $    &\multicolumn{3}{c}{\textbf{Prefer to See Incentive First}} \\\hline & & & \\"

esttab using  "${main}Choice_Demand.tex", ///
 se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (professionalsfree "Choice Free -- Professionals    $  \ \ \ \ \ \ \  $" seeincentivecostly "See Incentive First Costly          " seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" ///
female "Female" age "Age" stdalpha "Selfishness" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "See Incentive First Costly X Selfishness       " selfishseequalitycostly "See Quality First Costly X Selfishness            " ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order") ///
order (seeincentivecostly seequalitycostly  professionalsfree stdalpha selfishseeincentivecostly selfishseequalitycostly female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  collabels(none)  ///
drop(wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch) ///
nomtitle label substitute(" 0.000 " " " " (.) " " ") ///
prehead("`panel'") posthead("`dv'") postfoot("\hline" "\end{tabular}%" "\captionsetup{width=0.8\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the preference to see the incentive first. See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. Selfishness was elicited at the end of the experiment, using a multiple price list (MPL) with 5 decisions. The variable is a standardized measure of the number of times the advisor chose to recommend the incentivized product in the MPL task. The regression models in columns (2) and (3) include individual controls for the advisor's gender and age, each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:demand}" "\end{table}")

***************
* BLINDING **
***************


tabstat avoid_incentiveinfo if wave3==1 & Highx10==0 & Highx100==0 & age!=. & female!=., by(choiceafter)
**Overall percentages


*PROPORTION TESTS	
prtest avoid_incentiveinfo if wave3==1 & Highx10==0 & Highx100==0 & age!=. & female!=., by(choiceafter)

	
*STACKED FIGURE
bys choicebefore: egen blind=mean(avoid_incentiveinfo) if Highx10==0 & Highx100==0 & age!=. & female!=. & wave3==1
bys choicebefore: egen blindsd=sd(avoid_incentiveinfo) if Highx10==0 & Highx100==0 & age!=. & female!=. & wave3==1
bys choicebefore: egen blindn=count(avoid_incentiveinfo) if Highx10==0 & Highx100==0 & age!=. & female!=. & wave3==1

summ avoid_incentiveinfo if Highx10==0 & Highx100==0, d
return list

g loblind=blind-1.96*(blindsd/sqrt(blindn))
g hiblind=blind+1.96*(blindsd/sqrt(blindn))


tab blind

twoway (bar meancommit choiceafter, lcolor(black) fcolor(white) barwidth(0.3)) ///
		(bar blind choiceafter, color(gs8) barwidth(0.3)) ///
		(rcap loblind hiblind choiceafter, color(gs12)) ///
		, graphr(c(white)) xlabel(0 "Prefer to See Incentive First" 1 "Prefer to Assess Quality First") ///
		xscale(r(-0.4 1.4)) legend(order(1 "Prefer Not to Blind Incentive Information" ///
		2 "Prefer Blinding Incentive Information") rows(2)) ylabel(0(0.2)1) ///
		ytitle("Advisor Preference to Blind" " ") ///
		xtitle(" " "Advisor Preference in Choice Experiment") ///
		text(0.2 0 "0.32") text(0.2 1 "0.55")  ///
		text(0.8 0 "0.68") text(0.8 1 "0.45")
graph export "${main}Choice_Blinding.png", replace


/*The difference in preference to blind between advisors who prefer to see incentive first 

and those who prefer to see quality first  remains large (22 percentage points) and significant 

in regression analyses that control for treatment, gender, age, advisors facing a conflict of interest in the main experiment, and for being assigned 

to their preferred order in the main experiment ($t$-stat$=-7.18$, $p<0.001$, see Online Appendix C.2) */
reg avoid_incentive choicebefore notgetyourchoice choicebeforenotgetyourchoice $covariates2 noconflict if Highx10==0 & Highx100==0, vce(hc3)

********************************************************************************	
********************************************************************************	
*CHOICE - CODED EXPLANATIONS OF CHOICE 
********************************************************************************	
********************************************************************************
 u "${data}Choice_coding_explanations.dta", clear


*Main Text - page 23 - Section 4.
*Appendix C.2.4.
	*N=1749 advisors
	tab study

	*"classified their responses into four categories, which apply to 91\% of 
	*the responses. The remaining 9\% consists of empty or unrelated comments according to both raters."
	tabstat nocategory if choicebefore!=., s(mean n)

	*"Agreed in over 82% of their classifications..." and Kappa=0.76.
	kap mergedcategory1 mergedcategory2

*Main Text - Section 6.2
	*rarely report that they are indifferent between seeing the incentive 
	*first or assessing quality first (on average, 10\% of the comments)
	tab nomatter if choicebefore!=.

	*an average of 41\% of AMT participants and 53\% of professionals
	* versus 5\% of AMT participants and 7\% of professionals, 
	*respectively, $\chi^2\textrm{-stat}=405$, $p<$0.001
	tabstat limitbias if nocategory==0 & condition!="ChoiceFree_Professionals", by(choicebefore)
	tabstat limitbias if nocategory==0 & condition=="ChoiceFree_Professionals", by(choicebefore)
	tab limitbias choicebefore, chi2

	*an average of 36% of the cases for both AMT and for professionals
	tabstat commission_expl if nocategory==0 & condition=="ChoiceFree_Professionals", by(choicebefore)
	 tabstat commission_expl if nocategory==0 & condition!="ChoiceFree_Professionals", by(choicebefore)

	 
*******************************************
* APPENDIX C.2.4 - TABLE C.15
*******************************************	 
preserve
collapse limitbias nomatter commission_expl otherreason ///
 (count) nlimitbias=limitbias if nocategory==0, by(choicebefore)
 egen sumn=total(nlimitbias)
 drop nlimitbias
save "${appendix}taba.dta", replace
restore 
preserve
collapse limitbias nomatter commission_expl otherreason ///
 (count) nlimitbias=limitbias if nocategory==0 & condition!="ChoiceFree_Professionals", by(choicebefore)
 egen sumn=total(nlimitbias)
 drop nlimitbias
save "${appendix}tabb.dta", replace
restore 
preserve
collapse limitbias nomatter commission_expl otherreason ///
 (count) nlimitbias=limitbias if nocategory==0 & condition=="ChoiceFree_Professionals", by(choicebefore)
 egen sumn=total(nlimitbias)
 drop nlimitbias 
save "${appendix}tabc.dta", replace
restore 

preserve
clear
u "${appendix}taba.dta"
append using "${appendix}tabb.dta"
append using "${appendix}tabc.dta"
export excel "${appendix}tablec15.xlsx", replace first(var) keepcellfmt
rm "${appendix}taba.dta"
rm "${appendix}tabb.dta"
rm "${appendix}tabc.dta"
restore 
	 
	 
******************************************************************************************************************************************
******************************************************************************************************************************************
** RECOMMENDATIONS - MAIN TEXT 
******************************************************************************************************************************************
******************************************************************************************************************************************

u "${data}choice_experiments.dta", clear
*As pre-registered, drop Mturk participant with inconsistent alpha value
drop if study!=1 & alphavaluefinal==. /*(study1 are profs and there's no MPL')*/
gen incentiveBgetbefore=incentiveB*getbefore

**** FIGURE ***** MAIN TEXT

cap drop predrecommend_* ubpredrecommend_* lbpredrecommend_* sepredrecommend_*
g predrecommend_dqf_gqf=.
g sepredrecommend_dqf_gqf=.
g predrecommend_dqf_gif=.
g sepredrecommend_dqf_gif=.
g predrecommend_dif_gqf=.
g sepredrecommend_dif_gqf=.
g predrecommend_dif_gif=.
g sepredrecommend_dif_gif=.

*demand incentive first 
est clear
eststo:reg recommendincentive i.treatment##i.getbefore incentiveB  $covariates2 ///
if choicebefore==1  ///
& conflict==1 & Highx10==0 & Highx100==0, vce(hc3) 
forval i=0(1)3{
margins i.getbefore if treatment==`i', atmeans saving("${main}adjusted_recommendations", replace)
matrix coeffs=r(table)
replace predrecommend_dif_gqf=coeffs[1,1] if treatment==`i' & choicebefore==1 & getbefore==0
replace sepredrecommend_dif_gqf=coeffs[2,1] if treatment==`i' & choicebefore==1 & getbefore==0
replace predrecommend_dif_gif=coeffs[1,2] if treatment==`i' & choicebefore==1 & getbefore==1
replace sepredrecommend_dif_gif=coeffs[2,2] if treatment==`i' & choicebefore==1 & getbefore==1
}	
g ubpredrecommend_dif_gif=predrecommend_dif_gif+1.96*sepredrecommend_dif_gif
g lbpredrecommend_dif_gif=predrecommend_dif_gif-1.96*sepredrecommend_dif_gif
g ubpredrecommend_dif_gqf=predrecommend_dif_gqf+1.96*sepredrecommend_dif_gqf
g lbpredrecommend_dif_gqf=predrecommend_dif_gqf-1.96*sepredrecommend_dif_gqf


*demand quality first 
est clear
eststo:reg recommendincentive i.treatment##i.getbefore incentiveB  $covariates2 ///
if choicebefore==0  ///
& conflict==1 & Highx10==0 & Highx100==0, vce(hc3)  
forval i=0(1)3{
margins i.getbefore if treatment==`i', atmeans saving("${main}adjusted_recommendations", replace)
matrix coeffs=r(table)
replace predrecommend_dqf_gqf=coeffs[1,1] if treatment==`i' & choicebefore==0 & getbefore==0
replace sepredrecommend_dqf_gqf=coeffs[2,1] if treatment==`i' & choicebefore==0 & getbefore==0
replace predrecommend_dqf_gif=coeffs[1,2] if treatment==`i' & choicebefore==0 & getbefore==1
replace sepredrecommend_dqf_gif=coeffs[2,2] if treatment==`i' & choicebefore==0 & getbefore==1
}	
g ubpredrecommend_dqf_gif=predrecommend_dqf_gif+1.96*sepredrecommend_dqf_gif 
g lbpredrecommend_dqf_gif=predrecommend_dqf_gif-1.96*sepredrecommend_dqf_gif
g ubpredrecommend_dqf_gqf=predrecommend_dqf_gqf+1.96*sepredrecommend_dqf_gqf
g lbpredrecommend_dqf_gqf=predrecommend_dqf_gqf-1.96*sepredrecommend_dqf_gqf


cap drop treatnumgraph2
g treatnumgraph2=2 if  choicebefore==1 & getbefore==1 & condition=="ChoiceFree" & professionals==0
replace treatnumgraph2=2.1 if choicebefore==1 & getbefore==0 & condition=="ChoiceFree" & professionals==0
replace treatnumgraph2=2.2 if  choicebefore==0 & getbefore==1 & condition=="ChoiceFree" & professionals==0
replace treatnumgraph2=2.3 if  choicebefore==0 & getbefore==0 & condition=="ChoiceFree" & professionals==0


replace treatnumgraph2=1 if  choicebefore==1 & getbefore==1 & condition=="ChoiceFree_Professionals" 
replace treatnumgraph2=1.1 if choicebefore==1 & getbefore==0 & condition=="ChoiceFree_Professionals" 
replace treatnumgraph2=1.2 if  choicebefore==0 & getbefore==1 & condition=="ChoiceFree_Professionals" 
replace treatnumgraph2=1.3 if  choicebefore==0 & getbefore==0 & condition=="ChoiceFree_Professionals" 

replace treatnumgraph2=4 if  choicebefore==1 & getbefore==1 & condition=="PayAfter"
replace treatnumgraph2=4.1 if  choicebefore==1 & getbefore==0 & condition=="PayAfter"
replace treatnumgraph2=4.2 if  choicebefore==0 & getbefore==1 & condition=="PayAfter"
replace treatnumgraph2=4.3 if  choicebefore==0 & getbefore==0 & condition=="PayAfter"

replace treatnumgraph2=3 if  choicebefore==1 & getbefore==1 & condition=="PayBefore"
replace treatnumgraph2=3.1 if  choicebefore==1 & getbefore==0 & condition=="PayBefore"
replace treatnumgraph2=3.2 if  choicebefore==0 & getbefore==1 & condition=="PayBefore"
replace treatnumgraph2=3.3 if  choicebefore==0 & getbefore==0 & condition=="PayBefore"

		
*Conflict panel for long version of figure 		
twoway 	(scatteri 1 0.7 1 1.7, bcolor(gs15) recast(area)) ///
		(scatteri 1 2.7 1 3.7, bcolor(gs15) recast(area)) ///
		(rcap lbpredrecommend_dif_gif ubpredrecommend_dif_gif treatnumgraph2, lcolor(red) lwidth(thin)) ///
		(rcap lbpredrecommend_dqf_gqf ubpredrecommend_dqf_gqf treatnumgraph2, lcolor(black) lwidth(thin)) ///
		(rcap lbpredrecommend_dif_gqf ubpredrecommend_dif_gqf treatnumgraph2, lcolor(red*0.3) lwidth(thin)) ///
		(rcap lbpredrecommend_dqf_gif ubpredrecommend_dqf_gif treatnumgraph2, lcolor(black*0.3) lwidth(thin)) ///
		(scatter predrecommend_dif_gif treatnumgraph2 if ///
		condition=="ChoiceFree_Professionals" & professionals==1 , mcolor(red) msize(*0.75) ms(T)) ///
		(scatter predrecommend_dif_gqf treatnumgraph2 if ///
		condition=="ChoiceFree_Professionals" & professionals==1 & choicebefore==1 & getbefore==0, mfcolor(white) msize(*0.8) mlcolor(red%50) ms(S)) ///
		(scatter predrecommend_dqf_gif treatnumgraph2 if ///
		condition=="ChoiceFree_Professionals" & professionals==1 & choicebefore==0 & getbefore==1,  mfcolor(white) mlcolor(black%50) msize(*0.8) ms(T)) ///
		(scatter predrecommend_dqf_gqf treatnumgraph2 if ///
		condition=="ChoiceFree_Professionals" & professionals==1 & choicebefore==0 & getbefore==0, mcolor(black) msize(*0.8) ms(S)) ///
		(scatter predrecommend_dif_gif treatnumgraph2 if ///
		condition=="ChoiceFree" , mcolor(red) msize(*0.75) ms(T)) ///
		(scatter predrecommend_dif_gqf treatnumgraph2 if ///
		condition=="ChoiceFree" , mfcolor(white) msize(*0.8) mlcolor(red%50) ms(T)) ///
		(scatter predrecommend_dqf_gif treatnumgraph2 if ///
		condition=="ChoiceFree", mfcolor(white)  mlcolor(black*0.3) msize(*0.8) ms(S)) ///
		(scatter predrecommend_dqf_gqf treatnumgraph2 if ///
		condition=="ChoiceFree", msize(*0.8) mcolor(black) ms(S)) ///
		(scatter predrecommend_dif_gif treatnumgraph2 if condition=="PayAfter", mcolor(red) msize(*0.75) ms(T)) ///
		(scatter predrecommend_dif_gqf treatnumgraph2 if condition=="PayAfter", mfcolor(white) msize(*0.8) mlcolor(red%50)  ms(T)) ///
		(scatter predrecommend_dqf_gif treatnumgraph2 if condition=="PayAfter", mfcolor(white) mlcolor(black%50) msize(*0.8) ms(S)) ///
		(scatter predrecommend_dqf_gqf treatnumgraph2 if condition=="PayAfter", mcolor(black)  msize(*0.8)  ms(S)) ///
		(scatter predrecommend_dif_gif treatnumgraph2 if condition=="PayBefore", mcolor(red) msize(*0.75) ms(T)) ///
		(scatter predrecommend_dif_gqf treatnumgraph2 if condition=="PayBefore", mfcolor(white) msize(*0.8) mlcolor(red%50)  ms(T)) ///
		(scatter predrecommend_dqf_gif treatnumgraph2 if condition=="PayBefore", mfcolor(white) mlcolor(black%50) msize(*0.8) ms(S)) ///
		(scatter predrecommend_dqf_gqf treatnumgraph2 if condition=="PayBefore", msize(*0.8) mcolor(black) ms(S)) ///
		, graphr(c(white)) plotr(c(white)) ///
		ylabel(0.3(0.1)1) yscale(r(0.3 1)) 	///
		xtitle(" ") ///
		xlabel(none) ///                  
		xscale(r(0.7 4.6)) ///
		legend(order( - "{bf:Advisor Prefers to}" "{bf:See Incentive First}" ///
				7 8 - "{bf:Advisor Prefers to}" "{bf:Assess Quality First}" 9 10) ///
		lab(7 " Assigned to See Incentive First") ///
		lab(8 " Assigned to Assess Quality First") ///
		lab(10 " Assigned to Assess Quality First") ///
		lab(9 " Assigned to See Incentive First") ///
		rows(3) colfirst size(*0.7)) ///
		text(0.38 1.15 "{bf: Choice Free}", color(black) size(*0.8)) ///
		text(0.35 1.15 "{bf: - Professionals}", color(black) size(*0.8)) ///		
		text(0.38 2.15 "{bf: Choice}", color(black) size(*0.8)) ///
		 text(0.35 2.15 "{bf: Free }", color(black) size(*0.8)) ///
		text(0.38 4.15 "{bf: Quality First}", color(black) size(*0.8)) ///
		text(0.35 4.15 "{bf: Costly}", color(black) size(*0.8)) ///
		text(0.38 3.15 "{bf: Incentive First}", color(black) size(*0.8)) ///
		text(0.35 3.15 "{bf: Costly}", color(black) size(*0.8)) ///
		ytitle("{bf:Incentivized product recommendation}" " " ) 
		
		graph export "${main}Choice_recommendations_conflict_pred.pdf", replace

/* By contrast, those who prefer and are assigned to see quality first, recommend the incentivized product significantly less often in all cases (t-test, all p<.001) */
ttest recommendincentive if getyourchoice==1 & Highx10==0 & Highx100==0 & age!=. & treatment==0, by(choicebefore)
ttest recommendincentive if getyourchoice==1 & Highx10==0 & Highx100==0 & age!=. & treatment==1, by(choicebefore)
ttest recommendincentive if getyourchoice==1 & Highx10==0 & Highx100==0 & age!=. & treatment==2, by(choicebefore)
ttest recommendincentive if getyourchoice==1 & Highx10==0 & Highx100==0 & age!=. & treatment==3, by(choicebefore)


***Check effect of seeing incentive first vs. quality first among those who prefer to see incentive first in the COSTLY version of Choice, AMT-1 wave (to be used in Prediction study, in Appendix F)
tabstat recommendincentive if  choicebefore==1 & conflict==1 & wave=="AMT-1" & condition=="PayBefore" & alphavaluefinal!=., by(getbefore) 	stats(mean sd)	

*******************************************
* TABLE 3: RECOMMENDATIONS BY ASSIGNMENT & PREFERENCE 
*******************************************


*get pref
est clear 
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1, vce(hc3)
test choicebefore+choicebeforenoconflict==0
		
*not get
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==0, vce(hc3)

*combined
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict notgetyourchoice choicebeforenotgetyourchoice notgetyourchoicenoconflict incentiveB $covariates2 ///
		if Highx10==0 & Highx100==0, vce(hc3)
test choicebefore+choicebeforenoconflict==0
test choicebefore+notgetyourchoice+choicebeforenotgetyourchoice==0
test notgetyourchoice+choicebeforenotgetyourchoice==0		

lincom notgetyourchoice+choicebeforenotgetyourchoice


local panel "\begin{table}[h!]" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{10}\selectfont" "\caption{Advisor Recommendations}" "\hspace{-1cm}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "&\multicolumn{3}{c}{\textbf{Recommend incentivized product}} \\"
local groups "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Both} \\\hline &  &     &     \\   "
local conflict "&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict} \\ \hline    & &    &            &     &            &  \\"
	
esttab using  "${main}recommendations_pref_assign.tex",  se r2 replace cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (noconflict "No Conflict" getbefore "Assigned to See Incentive First"  getbeforenoconflict "Assigned to See Incentive First X No Conflict" professionalsfree "Choice Free--Professionals" seeincentivecostly "See Incentive First Costly" seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" notgetyourchoice "Not Assigned Preference" ///
female "Female" age "Age" selfish "Selfish" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "Selfish X See Incentive First Costly" selfishseequalitycostly "Selfish X See Quality First Costly" ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order" ///
incentiveB "Incentive for B" choicebefore "Prefer to See Incentive First" ///
choicebeforenoconflict "No Conflict X Prefer to See Incentive First" ///
choicebeforenotgetyourchoice "Prefer to See Incentive First X Not Assigned Preference" ///
notgetyourchoicenoconflict "No Conflict X Not Assigned Preference") ///
order (choicebefore notgetyourchoice choicebeforenotgetyourchoice noconflict choicebeforenoconflict notgetyourchoicenoconflict  professionalsfree seeincentivecostly seequalitycostly  incentiveB  selfish female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Advisor Recommendations") ///
drop(selfish wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch) ///
mlabels(none) label collabels(none) substitute(" 0.00 " " " " (.) " " ") ///
posthead("`dv'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=1.15\textwidth}" "\caption*{\footnotesize Note: This table displays the estimated coefficients from linear probability models on the advisor's decision to recommend the incentivized option. Column (1) focuses on individuals who are assigned their preference, while column (2) focuses on individuals who are not assigned their preference. Both groups are merged in column (3). Prefer to See Incentive First is an indicator of the advisor's preference, and Not Assigned Preference is an indicator for not receiving the preferred order. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. All regression models include individual controls for the advisor's gender and age, each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. The same analysis including a measure of advisor's selfishness are shown in Online Appendix C. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:recommendations}" "\end{table}")
		
		
/* page 30 On average, advisors who choose to see the incentive first are 9.8 percentage points more likely to recommend the incentivized product if they 

are assigned their preferred order ($t-\textrm{stat}=3.66$, $p<0.001$).	*/

reg recommendincentive i.getbefore incentiveB incentiveBgetbefore   ///
$covariates2 if choicebefore==1 & conflict==1  & Highx10==0 & Highx100==0, vce(hc3)	

/* page 33: In the Choice experiment, we estimate a 23.5 percentage point gap */

reg recommendincentive choicebefore choicebeforenoconflict ///
noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1 & treatment==0, vce(hc3)
*** 23.5pp [18.67-28.4]: Estimated Gap in recommendations Between Prefer&Get Incentive and Prefer&GetQuality, ChoiceFree

/* page 33: "which is not significantly different from the gap estimated in the NoChoice experiment  ($t-\textrm{stat}=1.26$, $p=0.207$)

 but directionally larger by about 7 percentage points.

 

 

COMPARISON OF GAP IN CHOICE TO GAP IN NOCHOICE (APPENDIX TABLE C.16) */ 


*clear
*u "${data}choice_experiments.dta"
preserve
keep if treatment==0
gen seeincentivefirst=getbefore
append using "${data}nochoice.dta"
gen nochoice=0
replace nochoice=1 if choice=="No Choice"
replace nochoice=1 if seeincentivefirst==.
replace seeincentivefirst=0 if condition=="AfterA" | condition=="AfterB"
replace seeincentivefirst=1 if condition=="BeforeA" | condition=="BeforeB"
replace getbefore=1 if nochoice==1 & seeincentivefirst==1
replace incentiveshigh=0 if nochoice==1
replace incentiveleft=0 if nochoice==1
drop if Highx10==1 
drop if Highx100==1
replace noconflict=1-conflict if nochoice==1
replace wave1=0 if nochoice==1
replace wave2=0 if nochoice==1
replace wave3=0  if nochoice==1
gen choice1=1-nochoice
replace seeincentivefirst_noconflict=seeincentivefirst*noconflict
gen seeincentivefirst_nochoice=seeincentivefirst*nochoice
gen seeincentivefirst_nochoiceNocon=seeincentivefirst*nochoice*noconflict
gen nochoice_noconflict=nochoice*noconflict
replace incentiveshigh_incentive=0 if nochoice==1
drop if alphavaluefinal==.


est clear 
eststo: reg recommendincentive seeincentivefirst noconflict seeincentivefirst_noconflict incentiveB wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentive age female if  choice=="No Choice"
eststo: reg recommendincentive seeincentivefirst noconflict seeincentivefirst_noconflict incentiveB wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentive age female if (getyourchoice==1 ) & choice=="Choice"
eststo: reg recommendincentive seeincentivefirst nochoice seeincentivefirst_nochoice noconflict  seeincentivefirst_noconflict nochoice_noconflict seeincentivefirst_nochoiceNocon incentiveB wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentive age female if ((choice=="Choice" & getyourchoice==1) | choice=="No Choice") 



local panel "\begin{table}[h!]" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{10}\selectfont" "\caption{Advisor Recommendations}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "&\multicolumn{3}{c}{\textbf{Recommend incentivized product}} \\"
local groups "\multicolumn{1}{r}{\textit{Sample:}}&\multicolumn{1}{c}{NoChoice.}&\multicolumn{1}{c}{Choice}&\multicolumn{1}{c}{Both} \\\hline &  &     &     \\   "
local conflict "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Randomly Assigned}&\multicolumn{1}{c}{Prefer and Assigned}&\multicolumn{1}{c}{Both} \\\hline &  &     &     \\   "


esttab using  "${appendix}choice_nochoice.tex",  se r2 replace cells(b(star fmt(4)) se(par fmt(4))) ///
coeflabel (seeincentivefirst "See Incentive First" noconflict "No Conflict" seeincentivefirst_noconflict "See Incentive First X No Conflict"  ///
nochoice "No Choice" seeincentivefirst_nochoice  "See IncentiveFirst X NoChoice"  nochoice_noconflict "No Choice X No Conflict" seeincentivefirst_nochoiceNocon "See Incentive First X No Choice X No Conflict"  ///
wave2 "Wave 2" wave3 "Wave 3" ///
incentiveB "Incentive for B" choicebefore "Prefer to See Incentive First" ) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Advisor Recommendations") ///
order(seeincentivefirst nochoice seeincentivefirst_nochoice noconflict nochoice_noconflict seeincentivefirst_noconflict seeincentivefirst_nochoiceNocon incentiveB) ///
drop( wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft female age) ///
mlabels(none) label collabels(none) substitute(" 0.000 " " " " (.) " " ") ///
posthead("`dv'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=\textwidth}" "\caption*{\footnotesize Note: This table displays the estimated coefficients from linear probability models on the advisor's decision to recommend the incentivized option. Column (1) focuses on the NoChoice Experiment, while column (2) focuses on  the Choice Experiment (ChoiceFree Treatment only) and on individuals who are assigned their preference. Both groups are merged in column (3). See Incentive First is an indicator for whether advisors are randomly assigned to see the incentive first in NoChoice, and whether, conditional on preferring to see the incentive first, they are assigned to see the incentive first in Choice. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission.  All regression models include individual controls for the advisor's gender and age, each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:recommendations}" "\end{table}")

restore 


/* PAGE 32: "Relative to advisors who are assigned to receive cognitive flexibility, those who are assigned moral commitment are 9 percentage points less likely 

to recommend the incentivized product ($t-\textrm{stat}=3.05$, $p=0.002$) */
reg recommendincentive i.getbefore incentiveB incentiveBgetbefore   ///
$covariates2 if choicebefore==0 & conflict==1  & Highx10==0 & Highx100==0, vce(hc3)

*******************************************
**** BELIEFS ******
*******************************************

*** LOGIT BELIEFS

*** GENERATE TABLE 4: BELIEF UPDATING	


cap program drop appendmodels 
program appendmodels, eclass
     syntax namelist
     tempname b V tmp
    foreach name of local namelist {
         qui est restore `name'
         mat `tmp' = e(b)
         local eq1: coleq `tmp'
         gettoken eq1 : eq1
         mat `tmp' = `tmp'[1,"`eq1':"]
        local cons = colnumb(`tmp',"_cons")
         if `cons'<. & `cons'>1 {
             mat `tmp' = `tmp'[1,1..`cons'-1]
         }
         mat `b' = nullmat(`b') , `tmp'
        mat `tmp' = e(V)
         mat `tmp' = `tmp'["`eq1':","`eq1':"]
         if `cons'<. & `cons'>1 {
             mat `tmp' = `tmp'[1..`cons'-1,1..`cons'-1]
        }
        capt confirm matrix `V'
         if _rc {
             mat `V' = `tmp'
        }
         else {
            mat `V' = ///
             ( `V' , J(rowsof(`V'),colsof(`tmp'),0) ) \ ///
             ( J(rowsof(`tmp'),colsof(`V'),0) , `tmp' )
         }
     }
     local names: colfullnames `b'
     mat coln `V' = `names'
     mat rown `V' = `names'
     eret post `b' `V'
     eret local cmd "whatever"
end


est clear
*Column 1-Panel A: Assigned Preferences (All)
eststo belief_all0: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1, vce(hc3) nocons
*mentioned in text: page 34, 5.57, p=0.018
test good=bad
*Column 1-Panel B: Assigned Preferences (By Choice)
*Quality first: f=q
eststo belief_0: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & choicebefore==0, vce(hc3) nocons

test good=bad

*Incentive first: f=i
eststo belief_1: reg logitbelief bad good ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & choicebefore==1, vce(hc3) nocons

test good=bad

eststo bivar: appendmodels belief_all0 belief_1 belief_0 

*mentioned in text, t-stats from table (2.45 and 2.19, p=0.014 and p=0.029, respectively)
reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==1, vce(hc3) nocons
test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==1
estadd scalar obs=r(N): bivar 

*Column 2-Panel A: Not Assigned Preferences (All)
eststo belief_all1: reg logitbelief bad good ///
		if Highx10==0 & Highx100==0 & getyourchoice==0, vce(hc3) nocons

*Column 2-Panel B: Not Assigned Preferences (By Choice)
*Quality first: f=q
eststo belief_2: reg logitbelief bad good ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & choicebefore==0, vce(hc3) nocons

*Incentive first: f=i
eststo belief_3: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & choicebefore==1, vce(hc3) nocons


eststo bivar2: appendmodels belief_all1 belief_3 belief_2 

reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==0, vce(hc3) nocons

test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar2
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar2
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==0
estadd scalar obs=r(N): bivar2 

*Excluding subjects who update in the wrong direction
*Column 3-Panel A: Assigned Preferences (All)
eststo belief_all2: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0, vce(hc3) nocons
*mentioned in text: page 34, 12.06, p<0.001
test good=bad

*Column 3-Panel B: Assigned Preferences (By Choice)
*Quality first: f=q
eststo belief_4: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & choicebefore==0, vce(hc3) nocons
test good=bad

*Incentive first: f=i
eststo belief_5: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & choicebefore==1, vce(hc3) nocons
test good=bad	
	

eststo bivar3: appendmodels belief_all2 belief_5 belief_4 
*Mentioned in text: page 35, t-stats from table 1.76 and 0.81
reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0, vce(hc3) nocons

test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar3
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar3
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0
estadd scalar obs=r(N): bivar3


*Column 4-Panel A: Not Assigned Preferences (All)
eststo belief_all3: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0, vce(hc3) nocons
test good=bad

*Column 4-Panel B: Not Assigned Preferences (BY Choice)
*Quality first: f=q
eststo belief_6: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & choicebefore==0, vce(hc3) nocons
test good=bad

*Incentive first: f=i	
eststo belief_7: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & choicebefore==1, vce(hc3) nocons
test good=bad	

eststo bivar4: appendmodels belief_all3 belief_7 belief_6 

reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0, robust nocons

test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar4
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar4
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0
estadd scalar obs=r(N): bivar4


*estadd scalar test_bad_good_news=r(p): belief_0

local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{9}{10}\selectfont" "\begin{tabular}{l*{4}{c}}\hline" 
local dv "&\multicolumn{4}{c}{\textbf{Log-odds Belief}} \\"
local pref "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}\\    "
local groups "\multicolumn{1}{r}{\textit{Data:}} &\multicolumn{2}{c}{All}&\multicolumn{2}{c}{Excl. update in wrong direction}  \\\hline        &            &     &            &  \\"

esttab bivar bivar2 bivar3 bivar4 using  "${main}beliefs_pref_assign.tex",  se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (bad "$\beta_C$" good "$\beta_{NC}$") ///
order (bad good) ///
star(* 0.10 ** 0.05 *** 0.01) ///
mlabels(none) label collabels(none) ///
stats(obs test_bad_ifirst test_good_ifirst, fmt(%9.0g %9.3f %9.3f %9.3f %9.3f) labels("Observations" "$\beta^{f=q}_C=\beta^{f=i}_{C}$" "$\beta^{f=q}_{NC}=\beta^{f=i}_{NC}$" )) ///
addnotes("Note:  * p$<$.10; ** p$<$.05; *** p$<$.01") posthead("`dv'" "`pref'" "`groups'") prehead("`panel'") ///
 postfoot("\hline" "\end{tabular}%" "\captionsetup{width=\textwidth}" ///
"\caption*{\footnotesize \textit{Notes:} The outcome in all regressions is the log belief ratio. $\beta^f_C$ and $\beta^f_{NC}$ are the estimated effects of the log likelihood ratio for conflict and no conflict signals, respectively, for advisors who prefer order $f$ ($f=i$ indicates a preference to see the incentive first, and $f=q$ indicates a preference to see quality first). Columns(1) and (2) include all advisors. Columns (3) and (4) exclude advisors who updated in the wrong direction. Columns (1) and (3) include only advisors who were assigned their preference, while columns (2) and (4) include only advisors who were not assigned their preference. Robust standard errors (HC3) in parentheses.\sym{*} \(p<0.10\), \sym{**} \(p<0.05\), \sym{***} \(p<0.01\).}" "\label{tab:beliefs}" "\end{table}")

******************************************
***** CHOICE EXPERIMENT: APPENDIX ******
*******************************************
preserve
***** APPENDIX B - TABLE B.1 ****** SAMPLE SIZES in the table
*NoChoice, SeeIncentiveFirst N=152; Assess Quality First N=147
	u "${data}nochoice.dta", clear
	drop if alphavaluefinal==.
	tab seeincentivefirst
	
*Choice, * AMT-1
		 *ChoiceFree= 1308; Incentive First Costly= 
		 u "${data}choice_experiments.dta", clear
		 drop if study!=1 & alphavaluefinal==.
		 tab condition if Highx10==0 & Highx100==0 & wave1==1
		 * AMT-2 
		 *Choice Free, $0.15 = 511; Choice Free, $15 to 1/100 = 542
		 tab condition incentiveshigh if wave2==1
		 * AMT-3 
		 *Choice Free =213 ; QualityFirst Costly=1067, IncentiveFirstCostly=215
		 tab condition if Highx10==0 & Highx100==0 & wave3==1
		 * ChoiceFree -HighStakes (10-fold)=110
		 tab condition if Highx10==1
		 * ChoiceFree -HighStakes (100-fold)=110
		 tab condition if Highx100==1

***ChoiceStakes, Low Incentive=483; IntermediateIncentive=511; HighIncentive=478
		u "${data}stakes.dta", clear
		drop if alphavaluefinal==.
		tab condition
		
***Information Architect: IA-Advisor=245; IA-Client=253
		u "${data}InformationArchitect.dta", clear
		drop if alphavaluefinal==.
		tab IAAdvisor
		
*ChoiceDeterministic, Replication=385; Deterministic=369
		u "${data}Choice_Deterministic.dta", clear
		drop if alphavaluefinal==.
		tab Deterministic

***NoChoiceSimultaneous, SeeIncentiveFirst=70; AssessQualityFirst=78; Simultaneous=128		u "${data}NoChoiceSimoultaneous.dta", clear
		u "${data}NoChoiceSimoultaneous.dta", clear
		drop if alphavaluefinal==.
		tab treatment

***Predictions, N=288
		u "${data}predictionsstudy.dta", clear
		tab gap


*** Total sample size in Table B.1: N=9599 
di 152+147+1308+1347+511+542+712+213+1067+215+275+110+483+511+478+245+253+385+369+70+78+128
restore
***** *APPENDIX B.2 - ADDITIONAL ANALYSES ******
preserve 
u "${data}professionals_jobtitles.dta", clear
*Essential: 
*Out of 712 professionals, 677 (95\%) provided job descriptions 
*that could be used by our independent raters to judge 
*whether their position was fiduciary or not.
tab fiduciary_2 fiduciary_1

di 677/712

*The raters agreed on their classification of fiduciary duty 
*in 87\% of the cases (interrater agreement $\kappa$=0.85).
alpha fiduciary_2 fiduciary_1
tab fiduciary_2 fiduciary_1
di (247+341)/677

*At least one rater classified job titles 
*as fiduciary in 62.9% of the cases (50% both, 12.7% one), while they agreed 
*that 37% of the job titles conveyed a position without fiduciary duty. 
egen meanfiduciary=rowmean(fiduciary_2 fiduciary_1)
tab meanfiduciary
di 100-37.09
*Focusing on the cases with agreement, 58\% of 
*the job titles were considered as fiduciary.  
tab fiduciary_2 fiduciary_1
di 341/(247+341)


*JOB TITLE
*Job titles frequently found in the data included the word analyst 
*(financial, actuarial, etc., in 9.4\% of the cases), accountant or 
*account manager (11.6\% of the cases), and lawyer or paralegal 
*(in 7.2\% of the cases). In their job titles, 14\% of participants 
*included the word ``manager.''

cap drop account
gen account = regexm(jobtitle, "account") | regexm(jobtitle, "Account")
tab account 

gen analyst = regexm(jobtitle, "analyst") | regexm(jobtitle, "Analyst")
tab analyst

gen lawyer = regexm(jobtitle, "lawyer") | regexm(jobtitle, "Lawyer") | regexm(jobtitle, "Legal") | regexm(jobtitle, "legal")
tab lawyer

gen manager = regexm(jobtitle, "manager") | regexm(jobtitle, "Manager") 
tab manager


*Prolific provides this information for some of our participants, but it
* was missing in 156 of 493 cases. 
tab industry if cloudresearch==0, m


*The agreement between raters regarding
* industry classification was high for CloudResearch ($\kappa=0.80$) and 
*somewhat lower for the missing cases on Prolific ($\kappa=0.65$). 
alpha industrycode_2 industrycode_1 if cloudresearch==1
alpha industrycode_2 industrycode_1 if cloudresearch==0 & industry==""


*Overall, for cases in which there is an agreement (636 out of 712), 
*we find that 72.5\% of professionals work in the finance and insurance 
*industry, 18.9\% in legal service, and for the remaining 8.7\% the industry is unknown. 

g agreedcode=industrycode_2==industrycode_1
tab industrytype_2 industrytype_1 if agreedcode==1, m cell
restore



******************************************
***** *APPENDIX C.2 - ADDITIONAL ANALYSES ******
*******************************************
***APPENDIX TABLE C.3 ****
*******************************************
preserve 
collapse year choicebefore (count) countobs=choicebefore, by(wave condition incentivedesign)

order year wave condition incentivedesign countobs choicebefore 
replace condition="Choice Free" if condition=="ChoiceFree"
replace condition="Incentive First Costly" if condition=="PayBefore"
replace condition="Quality First Costly" if condition=="PayAfter"
format choicebefore %9.3fc
format countobs %9.0fc
rename wave Wave
rename condition Treatment
rename incentivedesign Incentives
rename year Year 
rename countobs N
rename choicebefore DemandIncentiveFirst
drop Incentives Year
dataout, save("${appendix}AppendixTable_Conditions_Choice.tex") tex head replace
restore

*******************************************
**** APPENDIX TABLE C.4: BLINDING 
*******************************************
*******************************************

est clear 
eststo: reg avoid_incentive choicebefore $covariates2 noconflict if Highx10==0 & Highx100==0 & getyourchoice==1, vce(hc3)
eststo: reg avoid_incentive choicebefore $covariates2 noconflict if Highx10==0 & Highx100==0 & getyourchoice==0, vce(hc3)
eststo: reg avoid_incentive choicebefore notgetyourchoice choicebeforenotgetyourchoice $covariates2 noconflict if Highx10==0 & Highx100==0, vce(hc3)
*reg avoid_incentive choicebefore notgetyourchoice choicebeforenotgetyourchoice noconflict $covariates2 if Highx10==0 & Highx100==0, robust



local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{11}\selectfont" "\caption{Preferences for Blindness and Preferences for Information Order}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "& \multicolumn{3}{c}{\textbf{Advisor Preference to Blind}} \\"   
local pref "&\multicolumn{1}{c}{Assigned Pref.} &\multicolumn{1}{c}{Not Assigned Pref.} &\multicolumn{1}{c}{Both}  \\\hline & & & \\"


esttab using  "${appendix}Choice_Blinding.tex",  se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (noconflict "No Conflict" ///
 choicebefore "Prefer Incentive First" notgetyourchoice "Not Assigned Preference" ///
choicebeforenotgetyourchoice "Prefer Incentive First X Not Assigned Preference" ///
seequalitycostly "Assess Quality First Costly" seeincentivecostly "See Incentive First Costly") ///
order (choicebefore noconflict notgetyourchoice ///
choicebeforenotgetyourchoice seeincentivecostly seequalitycostly) ///
star(* 0.10 ** 0.05 *** 0.01) ///
mlabels(none) label collabels(none) ///
drop(professionalsfree wave2 wave3 professionalscloudresearch incentiveshigh incentiveleft ///
incentiveshigh_incentiveleft age female) ///
addnotes("Note:  * p$<$.10; ** p$<$.05; *** p$<$.01") posthead("`dv'" "`pref'" ) prehead("`panel'") ///
 postfoot("\hline" "\end{tabular}%" "\captionsetup{width=1\textwidth}" ///
"\caption*{\footnotesize \textit{Notes:} This table displays the coefficient estimates of OLS regressions on the advisor's preferences to blind themselves to incentives information in the Blinding task. Robust standard errors in parentheses. \sym{*} \(p<0.10\), \sym{**} \(p<0.05\), \sym{***} \(p<0.01\).}" "\label{tab:blinding1}" "\end{table}")


*******************************************
**** APPENDIX TABLE C.5 - BLINDING ADDING SELFISHNESS 
*******************************************

est clear 
eststo: reg avoid_incentive choicebefore $covariates2 noconflict stdalpha if Highx10==0 & Highx100==0 & getyourchoice==1, vce(hc3)
eststo: reg avoid_incentive choicebefore $covariates2 noconflict stdalpha if Highx10==0 & Highx100==0 & getyourchoice==0, vce(hc3)
eststo: reg avoid_incentive choicebefore notgetyourchoice choicebeforenotgetyourchoice $covariates2 noconflict  stdalpha if Highx10==0 & Highx100==0, vce(hc3)


local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{11}\selectfont" "\caption{Preferences for Blindness, Information Order \& Selfishness}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "& \multicolumn{3}{c}{\textbf{Advisor Preference to Blind}} \\"   
local pref "&\multicolumn{1}{c}{Assigned Pref.} &\multicolumn{1}{c}{Not Assigned Pref.} &\multicolumn{1}{c}{Both}  \\\hline & & & \\"

esttab using  "${appendix}Choice_Blinding_selfish.tex",  se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (noconflict "No Conflict" ///
 choicebefore "Prefer Incentive First" notgetyourchoice "Not Assigned Preference" ///
choicebeforenotgetyourchoice "Prefer Incentive First X Not Assigned Preference" ///
seequalitycostly "Assess Quality First Costly" seeincentivecostly "See Incentive First Costly" ///
stdalpha "Selfishness") ///
order (choicebefore noconflict notgetyourchoice ///
choicebeforenotgetyourchoice seeincentivecostly seequalitycostly stdalpha) ///
star(* 0.10 ** 0.05 *** 0.01) ///
mlabels(none) label collabels(none) ///
drop(professionalsfree wave2 wave3 professionalscloudresearch incentiveshigh incentiveleft ///
incentiveshigh_incentiveleft age female) ///
addnotes("Note:  * p$<$.10; ** p$<$.05; *** p$<$.01") posthead("`dv'" "`pref'" ) prehead("`panel'") ///
 postfoot("\hline" "\end{tabular}" "\captionsetup{width=1\textwidth}" ///
"\caption*{\footnotesize \textit{Notes:} This table displays the coefficient estimates of OLS regressions on the advisor's preferences to blind themselves to incentives information in the Blinding task, controlling for selfishness. Selfishness was elicited at the end of the experiment, using a multiple price list (MPL) with 5 decisions. The variable is a standardized measure of the number of times the advisor chose to recommend the incentivized product in the MPL task. Robust standard errors in parentheses. \sym{*} \(p<0.10\), \sym{**} \(p<0.05\), \sym{***} \(p<0.01\).}" "\label{tab:blinding2}" "\end{table}")
	

*******************************************
*APPENDIX : NO CONFLICT RECOMMENDATIONS - FIGURE C.1
*******************************************


cap drop predrecommend_* ubpredrecommend_* lbpredrecommend_* sepredrecommend_*
g predrecommend_dqf_gqf=.
g sepredrecommend_dqf_gqf=.
g predrecommend_dqf_gif=.
g sepredrecommend_dqf_gif=.
g predrecommend_dif_gqf=.
g sepredrecommend_dif_gqf=.
g predrecommend_dif_gif=.
g sepredrecommend_dif_gif=.

*demand incentive first 
est clear
eststo:reg recommendincentive i.treatment##i.getbefore incentiveB incentiveBgetbefore $covariates2 ///
if choicebefore==1  ///
& conflict==0 & Highx10==0 & Highx100==0, robust 
forval i=0(1)3{
margins i.getbefore if treatment==`i', atmeans saving("${main}adjusted_recommendations", replace)
matrix coeffs=r(table)
replace predrecommend_dif_gqf=coeffs[1,1] if treatment==`i' & choicebefore==1 & getbefore==0
replace sepredrecommend_dif_gqf=coeffs[2,1] if treatment==`i' & choicebefore==1 & getbefore==0
replace predrecommend_dif_gif=coeffs[1,2] if treatment==`i' & choicebefore==1 & getbefore==1
replace sepredrecommend_dif_gif=coeffs[2,2] if treatment==`i' & choicebefore==1 & getbefore==1
}	
g ubpredrecommend_dif_gif=predrecommend_dif_gif+1.96*sepredrecommend_dif_gif
g lbpredrecommend_dif_gif=predrecommend_dif_gif-1.96*sepredrecommend_dif_gif
g ubpredrecommend_dif_gqf=predrecommend_dif_gqf+1.96*sepredrecommend_dif_gqf
g lbpredrecommend_dif_gqf=predrecommend_dif_gqf-1.96*sepredrecommend_dif_gqf


*demand quality first 
est clear
eststo:reg recommendincentive i.treatment##i.getbefore incentiveB incentiveBgetbefore $covariates2 ///
if choicebefore==0  ///
& conflict==0 & Highx10==0 & Highx100==0, robust 
forval i=0(1)3{
margins i.getbefore if treatment==`i', atmeans saving("${main}adjusted_recommendations", replace)
matrix coeffs=r(table)
replace predrecommend_dqf_gqf=coeffs[1,1] if treatment==`i' & choicebefore==0 & getbefore==0
replace sepredrecommend_dqf_gqf=coeffs[2,1] if treatment==`i' & choicebefore==0 & getbefore==0
replace predrecommend_dqf_gif=coeffs[1,2] if treatment==`i' & choicebefore==0 & getbefore==1
replace sepredrecommend_dqf_gif=coeffs[2,2] if treatment==`i' & choicebefore==0 & getbefore==1
}	
g ubpredrecommend_dqf_gif=predrecommend_dqf_gif+1.96*sepredrecommend_dqf_gif 
g lbpredrecommend_dqf_gif=predrecommend_dqf_gif-1.96*sepredrecommend_dqf_gif
g ubpredrecommend_dqf_gqf=predrecommend_dqf_gqf+1.96*sepredrecommend_dqf_gqf
g lbpredrecommend_dqf_gqf=predrecommend_dqf_gqf-1.96*sepredrecommend_dqf_gqf

	
	
twoway 	(scatteri 1 0.7 1 1.7, bcolor(gs15) recast(area)) ///
		(scatteri 1 2.7 1 3.7, bcolor(gs15) recast(area)) ///
		(rcap lbpredrecommend_dif_gif ubpredrecommend_dif_gif treatnumgraph2, lcolor(red) lwidth(thin)) ///
		(rcap lbpredrecommend_dqf_gqf ubpredrecommend_dqf_gqf treatnumgraph2, lcolor(black) lwidth(thin)) ///
		(rcap lbpredrecommend_dif_gqf ubpredrecommend_dif_gqf treatnumgraph2, lcolor(red*0.3) lwidth(thin)) ///
		(rcap lbpredrecommend_dqf_gif ubpredrecommend_dqf_gif treatnumgraph2, lcolor(black*0.3) lwidth(thin)) ///
		(scatter predrecommend_dif_gif treatnumgraph2 if ///
		condition=="ChoiceFree_Professionals" & professionals==1 , mcolor(red) msize(*0.75) ms(T)) ///
		(scatter predrecommend_dif_gqf treatnumgraph2 if ///
		condition=="ChoiceFree_Professionals" & professionals==1 & choicebefore==1 & getbefore==0, mfcolor(white) msize(*0.8) mlcolor(red%50) ms(S)) ///
		(scatter predrecommend_dqf_gif treatnumgraph2 if ///
		condition=="ChoiceFree_Professionals" & professionals==1 & choicebefore==0 & getbefore==1,  mfcolor(white) mlcolor(black%50) msize(*0.8) ms(T)) ///
		(scatter predrecommend_dqf_gqf treatnumgraph2 if ///
		condition=="ChoiceFree_Professionals" & professionals==1 & choicebefore==0 & getbefore==0, mcolor(black) msize(*0.8) ms(S)) ///
		(scatter predrecommend_dif_gif treatnumgraph2 if ///
		condition=="ChoiceFree" , mcolor(red) msize(*0.75) ms(T)) ///
		(scatter predrecommend_dif_gqf treatnumgraph2 if ///
		condition=="ChoiceFree" , mfcolor(white) msize(*0.8) mlcolor(red%50) ms(T)) ///
		(scatter predrecommend_dqf_gif treatnumgraph2 if ///
		condition=="ChoiceFree", mfcolor(white)  mlcolor(black*0.3) msize(*0.8) ms(S)) ///
		(scatter predrecommend_dqf_gqf treatnumgraph2 if ///
		condition=="ChoiceFree", msize(*0.8) mcolor(black) ms(S)) ///
		(scatter predrecommend_dif_gif treatnumgraph2 if condition=="PayAfter", mcolor(red) msize(*0.75) ms(T)) ///
		(scatter predrecommend_dif_gqf treatnumgraph2 if condition=="PayAfter", mfcolor(white) msize(*0.8) mlcolor(red%50)  ms(T)) ///
		(scatter predrecommend_dqf_gif treatnumgraph2 if condition=="PayAfter", mfcolor(white) mlcolor(black%50) msize(*0.8) ms(S)) ///
		(scatter predrecommend_dqf_gqf treatnumgraph2 if condition=="PayAfter", mcolor(black)  msize(*0.8)  ms(S)) ///
		(scatter predrecommend_dif_gif treatnumgraph2 if condition=="PayBefore", mcolor(red) msize(*0.75) ms(T)) ///
		(scatter predrecommend_dif_gqf treatnumgraph2 if condition=="PayBefore", mfcolor(white) msize(*0.8) mlcolor(red%50)  ms(T)) ///
		(scatter predrecommend_dqf_gif treatnumgraph2 if condition=="PayBefore", mfcolor(white) mlcolor(black%50) msize(*0.8) ms(S)) ///
		(scatter predrecommend_dqf_gqf treatnumgraph2 if condition=="PayBefore", msize(*0.8) mcolor(black) ms(S)) ///
		, graphr(c(white)) plotr(c(white)) ///
		ylabel(0.3(0.1)1) yscale(r(0.3 1)) 	///
		xtitle("Treatment") ///
		xlabel(none) ///   fgfd                  
		xscale(r(0.7 4.6)) ///
		legend(order( - "{bf:Advisor Prefers to}" "{bf:See Incentive First}" ///
				7 8 - "{bf:Advisor Prefers to}" "{bf:Assess Quality First}" 9 10) ///
		lab(7 " Assigned to See Incentive First") ///
		lab(8 " Assigned to Assess Quality First") ///
		lab(10 " Assigned to Assess Quality First") ///
		lab(9 " Assigned to See Incentive First") ///
		rows(3) colfirst size(*0.7)) ///
		text(0.38 1.15 "{bf: Choice Free}", color(black) size(*0.8)) ///
		text(0.35 1.15 "{bf: - Professionals}", color(black) size(*0.8)) ///		
		text(0.38 2.15 "{bf: Choice}", color(black) size(*0.8)) ///
		 text(0.35 2.15 "{bf: Free }", color(black) size(*0.8)) ///
		text(0.38 4.15 "{bf: Quality First}", color(black) size(*0.8)) ///
		text(0.35 4.15 "{bf: Costly}", color(black) size(*0.8)) ///
		text(0.38 3.15 "{bf: Incentive First}", color(black) size(*0.8)) ///
		text(0.35 3.15 "{bf: Costly}", color(black) size(*0.8)) ///
		ytitle("{bf:Incentivized product recommendation}" " " )  		
		
		graph export "${appendix}Choice_Recommendations_Noconflict.png", replace
		
		
*******************************************
*APPENDIX TABLE C.6 - RECCOMENDATIONS ADDING SELFISHNESS
*******************************************
 
*get pref
est clear 
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict incentiveB stdalpha $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1, vce(hc3)

*not get
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict incentiveB stdalpha $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==0, vce(hc3) 

*combined
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict notgetyourchoice choicebeforenotgetyourchoice notgetyourchoicenoconflict incentiveB ///
		stdalpha $covariates2 ///
		if Highx10==0 & Highx100==0, vce(hc3)

			

local panel "\begin{table}[h!]" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{10}\selectfont" "\caption{Advisor Recommendations}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "&\multicolumn{3}{c}{\textbf{Recommend incentivized product}} \\"
local groups "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Both}  \\\hline &  &     &   &  \\   "
local conflict "&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict} \\ \hline    & &    &            &     &            &  \\"
	
esttab using  "${appendix}Choice_Recommendations_Selfishness.tex",  se r2 replace cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (noconflict "No Conflict" getbefore "Assigned to See Incentive First"  getbeforenoconflict "Assigned to See Incentive First X No Conflict" professionalsfree "Choice Free--Professionals" seeincentivecostly "See Incentive First Costly" seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" notgetyourchoice "Not Assigned Preference" ///
female "Female" age "Age" stdalpha "Selfishness" professionalscloudresearch "Professionals x Cloudresearch" ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order" ///
incentiveB "Incentive for B" choicebefore "Prefer to See Incentive First" ///
choicebeforenoconflict "No Conflict X Prefer to See Incentive First" ///
choicebeforenotgetyourchoice "Prefer to See Incentive First X Not Assigned Pref." ///
notgetyourchoicenoconflict "No Conflict X Not Assigned Preference") ///
order (choicebefore notgetyourchoice choicebeforenotgetyourchoice noconflict choicebeforenoconflict notgetyourchoicenoconflict seeincentivecostly seequalitycostly  professionalsfree incentiveB stdalpha female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Advisor Recommendations") ///
drop(professionalsfree wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch) ///
mlabels(none) label collabels(none) substitute(" 0.000 " " " " (.) " " ") ///
posthead("`dv'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the advisor's decision to recommend the incentivized option. Column (1) focuses on individuals who are assigned their preference, while column (2) focuses on individuals who are not assigned their preference. Both groups are merged in column (3). Prefer to See Incentive First is an indicator of the advisor's preference, and Not Assigned Preference is an indicator for not receiving the preferred order. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. Choice Free-Professionals, See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise.  Selfishness was elicited at the end of the experiment, using a multiple price list (MPL) with 5 decisions. The variable is a standardized measure of the number of times the advisor chose to recommend the incentivized product in the MPL task. All regression models include controls for each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:recommendations_selfish}" "\end{table}")


*************************************************************
 * APPENDIX TABLE C.7: ADVISOR RECOMMENDATION - INCENTIVE A 
*************************************************************

*get pref
est clear 
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict  $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1 & incentiveB==0, vce(hc3)

*not get
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict  $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==0 & incentiveB==0, vce(hc3) 

*combined
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict notgetyourchoice choicebeforenotgetyourchoice notgetyourchoicenoconflict $covariates2 ///
		if Highx10==0 & Highx100==0 & incentiveB==0, vce(hc3)

		

	
local panel "\begin{table}[h!]" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{10}\selectfont" "\caption{Advisor Recommendations: Incentive for A}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "&\multicolumn{3}{c}{\textbf{Recommend incentivized product}} \\"
local groups "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Both}  \\\hline &  &     &   &  \\   "
local conflict "&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict} \\ \hline    & &    &            &     &            &  \\"
	
esttab using  "${appendix}Choice_Recommendations_IncentiveA.tex",  se r2 replace cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (noconflict "No Conflict" getbefore "Assigned to See Incentive First"  getbeforenoconflict "Assigned to See Incentive First X No Conflict" professionalsfree "Choice Free--Professionals" seeincentivecostly "See Incentive First Costly" seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" notgetyourchoice "Not Assigned Preference" ///
female "Female" age "Age" selfish "Selfish" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "Selfish X See Incentive First Costly" selfishseequalitycostly "Selfish X See Quality First Costly" ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order" ///
choicebefore "Prefer to See Incentive First" ///
choicebeforenoconflict "No Conflict X Prefer to See Incentive First" ///
choicebeforenotgetyourchoice "Prefer to See Incentive First X Not Assigned Pref." ///
notgetyourchoicenoconflict "No Conflict X Not Assigned Preference" ///
selfishchoicebefore "Prefer to See Incentive First X Selfish" ///
selfishnotgetyourchoice "Not Assigned Preference X Selfish") ///
order (choicebefore notgetyourchoice choicebeforenotgetyourchoice noconflict choicebeforenoconflict notgetyourchoicenoconflict seeincentivecostly seequalitycostly  professionalsfree female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Advisor Recommendations") ///
drop(professionalsfree wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch) ///
mlabels(none) label collabels(none) substitute(" 0.000 " " " " (.) " " ") ///
posthead("`dv'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the advisor's decision to recommend the incentivized option, focusing on the cases in which advisors were incentivized to recommend product A. Column (1) focuses on individuals who are assigned their preference, while column (2) focuses on individuals who are not assigned their preference. Both groups are merged in column (3). Prefer to See Incentive First is an indicator of the advisor's preference, and Not Assigned Preference is an indicator for not receiving the preferred order. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. Choice Free-Professionals, See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. All regression models include controls for each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:recommendations_A}" "\end{table}")
 
*************************************************************
 * APPENDIX TABLE C.8: ADVISOR RECOMMENDATION - INCENTIVE B 
*************************************************************
 
*get pref
est clear 
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1 & incentiveB==1, vce(hc3)

*not get
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==0 & incentiveB==1, vce(hc3) 

*combined
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict notgetyourchoice choicebeforenotgetyourchoice notgetyourchoicenoconflict $covariates2 ///
		if Highx10==0 & Highx100==0 & incentiveB==1, vce(hc3)

		

	
local panel "\begin{table}[h!]" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{10}\selectfont" "\caption{Advisor Recommendations: Incentive for B}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "&\multicolumn{3}{c}{\textbf{Recommend incentivized product}} \\"
local groups "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Both}  \\\hline &  &     &   &  \\   "
local conflict "&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict} \\ \hline    & &    &            &     &            &  \\"
	
esttab using  "${appendix}Choice_Recommendations_IncentiveB.tex",  se r2 replace cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (noconflict "No Conflict" getbefore "Assigned to See Incentive First"  getbeforenoconflict "Assigned to See Incentive First X No Conflict" professionalsfree "Choice Free--Professionals" seeincentivecostly "See Incentive First Costly" seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" notgetyourchoice "Not Assigned Preference" ///
female "Female" age "Age" selfish "Selfish" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "Selfish X See Incentive First Costly" selfishseequalitycostly "Selfish X See Quality First Costly" ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order" ///
choicebefore "Prefer to See Incentive First" ///
choicebeforenoconflict "No Conflict X Prefer to See Incentive First" ///
choicebeforenotgetyourchoice "Prefer to See Incentive First X Not Assigned Pref." ///
notgetyourchoicenoconflict "No Conflict X Not Assigned Preference" ///
selfishchoicebefore "Prefer to See Incentive First X Selfish" ///
selfishnotgetyourchoice "Not Assigned Preference X Selfish") ///
order (choicebefore notgetyourchoice choicebeforenotgetyourchoice noconflict choicebeforenoconflict notgetyourchoicenoconflict seeincentivecostly seequalitycostly  professionalsfree female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Advisor Recommendations") ///
drop(professionalsfree wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch) ///
mlabels(none) label collabels(none) substitute(" 0.000 " " " " (.) " " ") ///
posthead("`dv'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the advisor's decision to recommend the incentivized option, focusing on the cases in which advisors were incentivized to recommend product B. Column (1) focuses on individuals who are assigned their preference, while column (2) focuses on individuals who are not assigned their preference. Both groups are merged in column (3). Prefer to See Incentive First is an indicator of the advisor's preference, and Not Assigned Preference is an indicator for not receiving the preferred order. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. Choice Free-Professionals, See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. All regression models include controls for each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:recommendations_B}" "\end{table}")



*************************************************************
 * APPENDIX TABLE C.9: SELECTION VS ASSIGNMENT
************************************************************* 
est clear 
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getbefore==1, vce(hc3)
test choicebefore+choicebeforenoconflict==0
		
*effect of preference for those assigned to see quality first
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getbefore==0, vce(hc3)

*effect of assignment for those who prefer to see the incentive first 
eststo: reg recommendincentive getbefore getbeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & choicebefore==1, vce(hc3)

*effect of assignment for those who prefer to see the quality first 
eststo: reg recommendincentive getbefore getbeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & choicebefore==0, vce(hc3)


**combined
	eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict getbefore choicebeforegetbefore getbeforenoconflict incentiveB $covariates2 ///
		if Highx10==0 & Highx100==0, vce(hc3)	

		test choicebefore=getbefore+choicebeforegetbefore


local panel "\begin{table}[h!]" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{10}\selectfont" "\caption{Advisor Recommendations - Role of Selection and Experience}" "\hspace{-1cm}" "\begin{tabular}{l*{5}{c}} \hline" 
local dv "&\multicolumn{5}{c}{\textbf{Recommend incentivized product}} \\"
local assigned "\multicolumn{1}{r}{\textit{Sample:}}&\multicolumn{2}{c}{Assigned to See:}&\multicolumn{2}{c}{Prefer to See:}&\multicolumn{1}{c}{Full Sample} \\   "
local groups "\multicolumn{1}{r}{\textit{}}&\multicolumn{1}{c}{Incentive First}&\multicolumn{1}{c}{Quality First}&\multicolumn{1}{c}{Incentive First}&\multicolumn{1}{c}{Quality First} & \\\hline &  &     &     \\   "
	
esttab using  "${appendix}Choice_recommendations_selection.tex",  se r2 replace cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (choicebefore "Prefer See Inc. First" noconflict "No Conflict" getbefore "Assigned See Inc. First"  getbeforenoconflict "No Conflict X Assigned See Inc. First" professionalsfree "Choice Free--Professionals" seeincentivecostly "See Inc. First Costly" seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" notgetyourchoice "Not Assigned Preference" ///
choicebeforegetbefore "Prefer X Assigned See Inc. First"female "Female" age "Age" selfish "Selfish" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "Selfish X See Inc. First Costly" selfishseequalitycostly "Selfish X See Quality First Costly" ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order" ///
incentiveB "Incentive for B" choicebefore "Prefer to See Incentive First" ///
choicebeforenoconflict "No Conflict X Prefer See Inc. First" ///
choicebeforenotgetyourchoice "Prefer See Inc. First X Not Assigned Preference" ) ///
order (choicebefore getbefore choicebeforegetbefore noconflict choicebeforenoconflict getbeforenoconflict   professionalsfree seeincentivecostly seequalitycostly  incentiveB  selfish female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Advisor Recommendations") ///
drop(selfish wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch) ///
mlabels(none) label collabels(none) substitute(" 0.00 " " " " (.) " " ") ///
posthead("`dv'" "`assigned'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=1.15\textwidth}" "\caption*{\footnotesize Note: This table displays the estimated coefficients from linear probability models on the advisor's decision to recommend the incentivized option. Column (1) and (2) focus on participants assigned to experience a given information order. Column (1) focuses on individuals who are assigned to see the incentive first,  column (2) focuses on individuals who are assigned to see quality first. Columns (3) and (4) focus on individuals' who prefer to be assigned to a given order, with Column (3) focusing on those who prefer to see the incentive first, and Column (4) focusing on those who prefer to see quality first. These groups are merged in column (5). Prefer See Inc. First is an indicator of the advisor's preference to see her incentive first, and Assigned See Inc. First is a indicator for whether advisors are assigned to see their incentive first. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. All regression models include individual controls for the advisor's gender and age, each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. The same analysis including a measure of advisor's selfishness are shown in Online Appendix C. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:recommendations}" "\end{table}")
		 
************************************************************
				* APPENDIX SECTION C.2.3: BELIEFS*

*****************************************************************************
		  *FIGURE C.2: CUMULATIVE BELIEFS DISTANCE - ASSIGNED PREFERRED ORDER
*****************************************************************************


cumul relbeliefdistance if choicebefore==1 & getbefore==1 & badsignal==1, generate(bel_dif_gif_bad) equal
cumul relbeliefdistance if choicebefore==0 & getbefore==0 & badsignal==1, generate(bel_dqf_gqf_bad) equal

cumul relbeliefdistance if choicebefore==1 & getbefore==1 & badsignal==0, generate(bel_dif_gif_good) equal
cumul relbeliefdistance if choicebefore==0 & getbefore==0 & badsignal==0, generate(bel_dqf_gqf_good) equal

cumul relbeliefdistance if choicebefore==1 & getbefore==0 & badsignal==1, generate(bel_dif_gqf_bad) equal
cumul relbeliefdistance if choicebefore==0 & getbefore==1 & badsignal==1, generate(bel_dqf_gif_bad) equal

cumul relbeliefdistance if choicebefore==1 & getbefore==0 & badsignal==0, generate(bel_dif_gqf_good) equal
cumul relbeliefdistance if choicebefore==0 & getbefore==1 & badsignal==0, generate(bel_dqf_gif_good) equal

twoway 	(scatter bel_dif_gif_bad relbeliefdistance, sort c(J) ms(none) color(red) lpattern(longdash)) ///
(scatter bel_dqf_gqf_bad relbeliefdistance, sort c(J)  ms(none) color(black) lpattern(longdash))  ///
, ytitle("CDF") xtitle("Relative Distance from Prior" "((Prior - Belief) / (Prior - Bayesian Posterior))") ///
legend( pos(10) ring(0) col(1) ///
label(2 "Prefer to See Quality First") label(1 "Prefer to See Incentive First") size(*0.8)) ///
xlabel(-2(0.5)2) xscale(r(0 1)) ///
	graphr(c(white)) ///
	xline(1, lcolor(gs12)) xline(0, lcolor(gs12)) ///
	text(0.0 0.3 "Prior", color(gs10) size(*0.8)) ///
	text(0.0 2 "Bayesian Posterior", color(gs10) size(*0.8)) ///
	title("Conflict", color(black) size(*0.8))
graph export "${appendix}Choice_Beliefs_Getchoice_Bad.png", replace
graph save "${appendix}Choice_Beliefs_Getchoice_bad.gph", replace

twoway 	(scatter bel_dif_gif_good relbeliefdistance, sort c(J) ms(none) color(red) lpattern(longdash)) ///
(scatter bel_dqf_gqf_good relbeliefdistance, sort c(J)  ms(none) color(black) lpattern(longdash))  ///
, ytitle("CDF") xtitle("Relative Distance from Prior" "((Prior - Belief) / (Prior - Bayesian Posterior))") ///
legend( pos(10) ring(0) col(1) ///
label(2 "Prefer to See Quality First") label(1 "Prefer to See Incentive First") size(*0.8)) ///
xlabel(-2(0.5)2) xscale(r(0 1)) ///
	graphr(c(white)) ///
		xline(1, lcolor(gs12)) xline(0, lcolor(gs12)) ///
	text(0.0 0.3 "Prior", color(gs10) size(*0.8)) ///
	text(0.0 2 "Bayesian Posterior", color(gs10) size(*0.8)) ///
	title("No Conflict", color(black) size(*0.8))
graph save "${appendix}Choice_Beliefs_Getchoice_Good.gph", replace
	
grc1leg	"${appendix}Choice_Beliefs_Getchoice_bad.gph" ///
 "${appendix}Choice_Beliefs_Getchoice_Good.gph" ///
 , graphr(c(white))
graph export "${appendix}Choice_Beliefs_Getchoice.pdf", replace
	
***********************************************************************************
		  *FIGURE C.3: CUMULATIVE BELIEFS DISTANCE* NOT ASSIGNED PREFERRED ORDER
***********************************************************************************

twoway 	(scatter bel_dif_gqf_bad relbeliefdistance, sort c(J) ms(none) color(red) lpattern(longdash)) ///
(scatter bel_dqf_gif_bad relbeliefdistance, sort c(J)  ms(none) color(black) lpattern(longdash))  ///
, ytitle("CDF") xtitle("Relative Distance from Prior" "((Prior - Belief) / (Prior - Bayesian Posterior))") ///
legend( pos(10) ring(0) col(1) ///
label(2 "Prefer to See Quality First") label(1 "Prefer to See Incentive First") size(*0.8)) ///
xlabel(-2(0.5)2) xscale(r(0 1)) ///
	graphr(c(white)) ///
			xline(1, lcolor(gs12)) xline(0, lcolor(gs12)) ///
	text(0.0 0.3 "Prior", color(gs10) size(*0.8)) ///
	text(0.0 2 "Bayesian Posterior", color(gs10) size(*0.8)) ///
 title("Conflict", color(black) size(*0.8))
graph export "${appendix}Choice_Beliefs_Notgetchoice_Bad.png", replace
graph save "${appendix}Choice_Beliefs_Notgetchoice_Bad.gph", replace


twoway 	(scatter bel_dif_gqf_good relbeliefdistance, sort c(J) ms(none) color(red) lpattern(longdash)) ///
(scatter bel_dqf_gif_good relbeliefdistance, sort c(J)  ms(none) color(black) lpattern(longdash))  ///
, ytitle("CDF") xtitle("Relative Distance from Prior" "((Prior - Belief) / (Prior - Bayesian Posterior))") ///
legend( pos(10) ring(0) col(1) ///
label(2 "Prefer to See Quality First") label(1 "Prefer to See Incentive First") size(*0.8)) ///
xlabel(-2(0.5)2) xscale(r(0 1)) ///
	graphr(c(white)) ///
			xline(1, lcolor(gs12)) xline(0, lcolor(gs12)) ///
	text(0.0 0.3 "Prior", color(gs10) size(*0.8)) ///
	text(0.0 2 "Bayesian Posterior", color(gs10) size(*0.8)) ///
 title("No Conflict", color(black) size(*0.8))
graph save "${appendix}Choice_Beliefs_Notgetchoice_Good.gph", replace
	
grc1leg	"${appendix}Choice_Beliefs_Notgetchoice_Bad.gph" ///
 "${appendix}Choice_Beliefs_Notgetchoice_Good.gph" ///
 , graphr(c(white))
graph export "${appendix}Choice_Beliefs_Notgetchoice.pdf", replace


***********************************************************************************
              *TABLE C.10 0BELIEF UPDATING WHEN SIGNAL IS $0  
***********************************************************************************
est clear
*get pref
eststo belief_all0: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & signalblue==0, vce(hc3) nocons

test good=bad
*get pref
eststo belief_0: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & choicebefore==0 & signalblue==0 , vce(hc3) nocons

test good=bad

eststo belief_1: reg logitbelief bad good ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & choicebefore==1 & signalblue==0, vce(hc3) nocons

test good=bad

eststo bivar: appendmodels belief_all0 belief_1 belief_0 

reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & signalblue==0, vce(hc3) nocons
test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==1 & signalblue==0
estadd scalar obs=r(N): bivar 

*not get
eststo belief_all1: reg logitbelief bad good ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & signalblue==0, vce(hc3) nocons

eststo belief_2: reg logitbelief bad good ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & choicebefore==0 & signalblue==0, vce(hc3) nocons

test good=bad
*estadd scalar test_bad_good_news=r(p): belief_0

eststo belief_3: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & choicebefore==1 & signalblue==0, vce(hc3) nocons

test good=bad

eststo bivar2: appendmodels belief_all1 belief_3 belief_2 

reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & signalblue==0, vce(hc3) nocons

test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar2
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar2
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==0 & signalblue==0
estadd scalar obs=r(N): bivar2 

*Columns 3/4: Focus on participants who update in correct direction only  
*get pref
eststo belief_all2: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & signalblue==0, vce(hc3) nocons
test good=bad

eststo belief_4: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & choicebefore==0 & signalblue==0, vce(hc3) nocons
test good=bad
	
eststo belief_5: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & choicebefore==1 & signalblue==0, vce(hc3) nocons
test good=bad	
	

eststo bivar3: appendmodels belief_all2 belief_5 belief_4 

reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & signalblue==0, vce(hc3) nocons

test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar3
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar3
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & signalblue==0
estadd scalar obs=r(N): bivar3

test goodchoicebefore==badchoicebefore


*not get
eststo belief_all3: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & signalblue==0, vce(hc3) nocons
test good=bad

eststo belief_6: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & choicebefore==0 & signalblue==0, vce(hc3) nocons
test good=bad
	
eststo belief_7: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & choicebefore==1 & signalblue==0, vce(hc3) nocons
test good=bad	

eststo bivar4: appendmodels belief_all3 belief_7 belief_6 

reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & signalblue==0, robust nocons

test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar4
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar4
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & signalblue==0
estadd scalar obs=r(N): bivar4


local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{9}{10}\selectfont" "\begin{tabular}{l*{4}{c}}\hline" 
local dv "&\multicolumn{4}{c}{\textbf{Log-odds Belief}} \\"
local pref "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}\\    "
local groups "\multicolumn{1}{r}{\textit{Data:}} &\multicolumn{2}{c}{All}&\multicolumn{2}{c}{Excl. update in wrong direction}  \\\hline        &            &     &            &  \\"

esttab bivar bivar2 bivar3 bivar4 using  "${appendix}beliefs_pref_assign_ball0.tex",  se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (bad "$\beta_C$" good "$\beta_{NC}$") ///
order (bad good) ///
star(* 0.10 ** 0.05 *** 0.01) ///
mlabels(none) label collabels(none) ///
stats(obs test_bad_ifirst test_good_ifirst, fmt(%9.0g %9.3f %9.3f %9.3f %9.3f) labels("Observations" "$\beta^{f=q}_C=\beta^{f=i}_{C}$" "$\beta^{f=q}_{NC}=\beta^{f=i}_{NC}$" )) ///
addnotes("Note:  * p$<$.10; ** p$<$.05; *** p$<$.01") posthead("`dv'" "`pref'" "`groups'") prehead("`panel'") ///
 postfoot("\hline" "\end{tabular}%" "\captionsetup{width=0.8\textwidth}" ///
"\caption*{\footnotesize \textit{Notes:} The outcome in all regressions is the log belief ratio, when the advisors sees a \$0 ball for product $B$. $\beta^f_C$ and $\beta^f_{NC}$ are the estimated effects of the log likelihood ratio for conflict and no conflict signals, respectively, for advisors who prefer order $f$ ($f=i$ indicates a preference to see the incentive first, and $f=q$ indicates a preference to see quality first). Columns(1) and (2) include all advisors. Columns (3) and (4) exclude advisors who updated in the wrong direction. Columns (1) and (3) include only advisors who were assigned their preference, while columns (2) and (4) include only advisors who were not assigned their preference. Robust standard errors (HC3) in parentheses.\sym{*} \(p<0.10\), \sym{**} \(p<0.05\), \sym{***} \(p<0.01\).}" "\label{tab:beliefs1}" "\end{table}")

***********************************************************************************
              *TABLE C.11 0BELIEF UPDATING WHEN SIGNAL IS $2  
***********************************************************************************
*Columns 1/2: Full Sample
est clear
*get pref
eststo belief_all0: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & signalblue==1, vce(hc3) nocons

test good=bad
*get pref
eststo belief_0: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & choicebefore==0 & signalblue==1 , vce(hc3) nocons

test good=bad

eststo belief_1: reg logitbelief bad good ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & choicebefore==1 & signalblue==1, vce(hc3) nocons

test good=bad

eststo bivar: appendmodels belief_all0 belief_1 belief_0 

reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & signalblue==1, vce(hc3) nocons
test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==1 & signalblue==1
estadd scalar obs=r(N): bivar 

*not get
eststo belief_all1: reg logitbelief bad good ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & signalblue==1, vce(hc3) nocons

eststo belief_2: reg logitbelief bad good ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & choicebefore==0 & signalblue==1, vce(hc3) nocons

test good=bad

eststo belief_3: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & choicebefore==1 & signalblue==1, vce(hc3) nocons

test good=bad

eststo bivar2: appendmodels belief_all1 belief_3 belief_2 

reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & signalblue==1, vce(hc3) nocons

test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar2
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar2
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==0 & signalblue==1
estadd scalar obs=r(N): bivar2 

*Columns 3/4: Focus on participants who update in correct direction only  
*get pref
eststo belief_all2: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & signalblue==1, vce(hc3) nocons
test good=bad

eststo belief_4: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & choicebefore==0 & signalblue==1, vce(hc3) nocons
test good=bad
	
eststo belief_5: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & choicebefore==1 & signalblue==1, vce(hc3) nocons
test good=bad	
	

eststo bivar3: appendmodels belief_all2 belief_5 belief_4 

reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & signalblue==1, vce(hc3) nocons

test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar3
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar3
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0 & signalblue==1
estadd scalar obs=r(N): bivar3


*not get
eststo belief_all3: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & signalblue==0, vce(hc3) nocons
test good=bad

eststo belief_6: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & choicebefore==0 & signalblue==1, vce(hc3) nocons
test good=bad
	
eststo belief_7: reg logitbelief bad good  ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & choicebefore==1 & signalblue==1, vce(hc3) nocons
test good=bad	

eststo bivar4: appendmodels belief_all3 belief_7 belief_6 

reg logitbelief good bad goodchoicebefore badchoicebefore ///
		if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & signalblue==1, robust nocons

test goodchoicebefore==0
estadd scalar test_good_ifirst=r(p): bivar4
test badchoicebefore==0
estadd scalar test_bad_ifirst=r(p): bivar4
summ logitbelief if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0 & signalblue==1
estadd scalar obs=r(N): bivar4



local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{9}{10}\selectfont" "\caption{Belief Updating when Signal is \$2}" "\begin{tabular}{l*{4}{c}}\hline" 
local dv "&\multicolumn{4}{c}{\textbf{Log-odds Belief}} \\"
local pref "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}\\    "
local groups "\multicolumn{1}{r}{\textit{Data:}} &\multicolumn{2}{c}{All}&\multicolumn{2}{c}{Excl. update in wrong direction}  \\\hline        &            &     &            &  \\"

esttab bivar bivar2 bivar3 bivar4 using  "${appendix}beliefs_pref_assign_ball2.tex",  se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (bad "$\beta_C$" good "$\beta_{NC}$") ///
order (bad good) ///
star(* 0.10 ** 0.05 *** 0.01) ///
mlabels(none) label collabels(none) ///
stats(obs test_bad_ifirst test_good_ifirst, fmt(%9.0g %9.3f %9.3f %9.3f %9.3f) labels("Observations" "$\beta^{f=q}_C=\beta^{f=i}_{C}$" "$\beta^{f=q}_{NC}=\beta^{f=i}_{NC}$" )) ///
addnotes("Note:  * p$<$.10; ** p$<$.05; *** p$<$.01") posthead("`dv'" "`pref'" "`groups'") prehead("`panel'") ///
 postfoot("\hline" "\end{tabular}%" "\captionsetup{width=0.8\textwidth}" ///
"\caption*{\footnotesize \textit{Notes:} The outcome in all regressions is the log belief ratio, when the advisors sees a \$2 ball for product $B$. $\beta^f_C$ and $\beta^f_{NC}$ are the estimated effects of the log likelihood ratio for conflict and no conflict signals, respectively, for advisors who prefer order $f$ ($f=i$ indicates a preference to see the incentive first, and $f=q$ indicates a preference to see quality first). Columns(1) and (2) include all advisors. Columns (3) and (4) exclude advisors who updated in the wrong direction. Columns (1) and (3) include only advisors who were assigned their preference, while columns (2) and (4) include only advisors who were not assigned their preference. Robust standard errors (HC3) in parentheses.\sym{*} \(p<0.10\), \sym{**} \(p<0.05\), \sym{***} \(p<0.01\).}" "\label{tab:beliefs2}" "\end{table}")

***********************************************************************************
              *TABLE C.12 BELIEF UPDATING - CORRECT CHOICE
***********************************************************************************

tab beliefinbin

tab correctdirbin 
est clear

eststo: reg beliefcorrect choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1, vce(hc3)

eststo: reg beliefcorrect choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==0, vce(hc3)
		
eststo: reg beliefcorrect choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1 & correctdirbin==1, vce(hc3)
		
eststo: reg beliefcorrect choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==0 & correctdirbin==1, vce(hc3)

local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{9}{10}\selectfont" "\caption{Belief Updating: Correct Choice}" "\begin{tabular}{l*{4}{c}}\hline" 
local dv "&\multicolumn{4}{c}{\textbf{Belief Correct}} \\"
local pref "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}\\    "
local groups "\multicolumn{1}{r}{\textit{Data:}} &\multicolumn{2}{c}{All}&\multicolumn{2}{c}{Excl. update in wrong direction}  \\\hline        &            &     &            &  \\"

	
esttab using  "${appendix}beliefcorrect.tex",  se r2 replace cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (noconflict "No Conflict" professionalsfree "Choice Free--Professionals" seeincentivecostly "See Incentive First Costly" seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" notgetyourchoice "Not Assigned Preference" ///
female "Female" age "Age" selfish "Selfish" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "Selfish X See Incentive First Costly" selfishseequalitycostly "Selfish X See Quality First Costly" ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order" ///
incentiveB "Incentive for B" choicebefore "Prefer to See Incentive First" ///
choicebeforenoconflict "No Conflict X Prefer to See Incentive First" ///
choicebeforenotgetyourchoice "Prefer to See Incentive First X Not Assigned Pref." ///
notgetyourchoicenoconflict "No Conflict X Not Assigned Preference") ///
order (choicebefore noconflict choicebeforenoconflict seeincentivecostly seequalitycostly  professionalsfree incentiveB female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Belief Updating: Choice of Correct Belief Bin") ///
drop(professionalsfree wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch) ///
mlabels(none) label collabels(none) substitute(" 0.000 " " " " (.) " " ") ///
posthead("`dv'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the advisor's beliefs that the quality of product B is low measured via their choice of one out of 10 possible belief bins (ranging from 0 to 100, in steps of 10). Column (1) focuses on individuals who are assigned their preference, while column (2) focuses on individuals who are not assigned their preference. Columns (3) and (4) exclude individuals who chose a bin that is consistent with updating in the incorrect direction. Prefer to See Incentive First is an indicator of the advisor's preference, and Not Assigned Preference is an indicator for not receiving the preferred order. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. Choice Free-Professionals, See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. All regression models include controls for each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:beliefcorrect}" "\end{table}")


***************************************************************************************************************
              *TABLE C.13 BELIEF UPDATING - LIKELIHOOD OF STICKING TO PRIOR BELIEF - INCENTIVIZED ELICITATION
***************************************************************************************************************
est clear

eststo: reg belief_prior choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1, vce(hc3)

eststo: reg belief_prior choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==0, vce(hc3)
		
eststo: reg belief_prior choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1 & correctdirbin==1, vce(hc3)
		
eststo: reg belief_prior choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==0 & correctdirbin==1, vce(hc3)

local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{9}{10}\selectfont" "\caption{Belief Updating: Likelihood of Sticking to the Prior Belief - Incentivized Elicitation}" "\begin{tabular}{l*{4}{c}}\hline" 
local dv "&\multicolumn{4}{c}{\textbf{Belief Bin Containing the Prior of 50\%}} \\"
local pref "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}\\    "
local groups "\multicolumn{1}{r}{\textit{Data:}} &\multicolumn{2}{c}{All}&\multicolumn{2}{c}{Excl. update in wrong direction}  \\\hline        &            &     &            &  \\"

	
esttab using  "${appendix}beliefprior.tex",  se r2 replace cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (noconflict "No Conflict" professionalsfree "Choice Free--Professionals" seeincentivecostly "See Incentive First Costly" seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" notgetyourchoice "Not Assigned Preference" ///
female "Female" age "Age" selfish "Selfish" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "Selfish X See Incentive First Costly" selfishseequalitycostly "Selfish X See Quality First Costly" ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order" ///
incentiveB "Incentive for B" choicebefore "Prefer to See Incentive First" ///
choicebeforenoconflict "No Conflict X Prefer to See Incentive First" ///
choicebeforenotgetyourchoice "Prefer to See Incentive First X Not Assigned Pref." ///
notgetyourchoicenoconflict "No Conflict X Not Assigned Preference") ///
order (choicebefore noconflict choicebeforenoconflict seeincentivecostly seequalitycostly  professionalsfree incentiveB female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Belief Updating: Likelihood to Stick to the Prior Belief") ///
drop(professionalsfree wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch) ///
mlabels(none) label collabels(none) substitute(" 0.000 " " " " (.) " " ") ///
posthead("`dv'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the advisor's likelihood to stick to the bin containing the prior belief (50\%) in the incentivized belief elicitation. Column (1) focuses on individuals who are assigned their preference, while column (2) focuses on individuals who are not assigned their preference. Columns (3) and (4) exclude individuals who chose a bin that is consistent with updating in the incorrect direction. Prefer to See Incentive First is an indicator of the advisor's preference, and Not Assigned Preference is an indicator for not receiving the preferred order. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. Choice Free-Professionals, See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. All regression models include controls for each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:beliefcorrect}" "\end{table}")


*************************************************************************************************************
              *TABLE C.14 BELIEF UPDATING - LIKELIHOOD OF STICKING TO PRIOR BELIEF - CONTINUOUS ELICITATION
*************************************************************************************************************

est clear

eststo: reg belief_prior_continuos choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1, vce(hc3)

eststo: reg belief_prior_continuos choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==0, vce(hc3)

eststo: reg belief_prior_continuos choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1 & updatewrong==0, vce(hc3)
		
eststo: reg belief_prior_continuos choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==0 & updatewrong==0, vce(hc3)

local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{9}{10}\selectfont" "\caption{Belief Updating: Likelihood of Sticking to the Prior Belief - Continuous Elicitation}" "\begin{tabular}{l*{4}{c}}\hline" 
local dv "&\multicolumn{4}{c}{\textbf{Belief at Prior of 50\%}} \\"
local pref "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}\\    "
local groups "\multicolumn{1}{r}{\textit{Data:}} &\multicolumn{2}{c}{All}&\multicolumn{2}{c}{Excl. update in wrong direction}  \\\hline        &            &     &            &  \\"

	
esttab using  "${appendix}beliefprior_continuous.tex",  se r2 replace cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (noconflict "No Conflict" professionalsfree "Choice Free--Professionals" seeincentivecostly "See Incentive First Costly" seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" notgetyourchoice "Not Assigned Preference" ///
female "Female" age "Age" selfish "Selfish" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "Selfish X See Incentive First Costly" selfishseequalitycostly "Selfish X See Quality First Costly" ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order" ///
incentiveB "Incentive for B" choicebefore "Prefer to See Incentive First" ///
choicebeforenoconflict "No Conflict X Prefer to See Incentive First" ///
choicebeforenotgetyourchoice "Prefer to See Incentive First X Not Assigned Pref." ///
notgetyourchoicenoconflict "No Conflict X Not Assigned Preference") ///
order (choicebefore noconflict choicebeforenoconflict seeincentivecostly seequalitycostly  professionalsfree incentiveB female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Belief Updating: Likelihood to Stick to the Prior Belief") ///
drop(professionalsfree wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch) ///
mlabels(none) label collabels(none) substitute(" 0.000 " " " " (.) " " ") ///
posthead("`dv'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the advisor's likelihood to stick to the bin containing the prior belief (50\%) in the incentivized belief elicitation. Column (1) focuses on individuals who are assigned their preference, while column (2) focuses on individuals who are not assigned their preference. Columns (3) and (4) exclude individuals who chose a bin that is consistent with updating in the incorrect direction. Prefer to See Incentive First is an indicator of the advisor's preference, and Not Assigned Preference is an indicator for not receiving the preferred order. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. Choice Free-Professionals, See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. All regression models include controls for each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:beliefcorrect}" "\end{table}")

***************************************************************************
***** Table C.17 CHOICE panel, numbers reported in table below ********
***************************************************************************
*CHOICE PANEL
reg recommendincentive i.treatment##i.getbefore incentiveB  $covariates2 ///
if choicebefore==1  & conflict==1 & Highx10==0 & Highx100==0, vce(hc3) 
margins i.getbefore if treatment==0, atmeans 
***Prefer & assigned to See incentive first: 81% [73%-84%]
***Prefer & not assigned to See incentive first: 71% [66%-77%]

reg recommendincentive i.treatment##i.getbefore incentiveB  $covariates2 ///
if choicebefore==0  & conflict==1 & Highx10==0 & Highx100==0, vce(hc3) 
margins i.getbefore if treatment==0, atmeans 
***Prefer & assigned to Assess quality first: 68% [61%-74%]
***Prefer & not assigned to Assess quality first: 71% [53%-61%]

*CHOICE PREDICTED
/* Since on average 55% of participants prefer to see incentive first and 45% quality first,

then the predicted preference to see the incentive first is: */
di 0.45*.7115466 + 0.55*.8104721
di 0.45*.5659195 + 0.55*.6759732

**********************************************************************************
**** APPENDIX - TABLE C.18:  PREFERENCES - INCLUDING HIGHx10 and HIGhx100 TREATMENTS
**********************************************************************************
est clear
eststo:reg choicebefore $covariates2 Highx10 Highx100, vce(hc3)
eststo:reg choicebefore $covariates2 Highx10 Highx100 stdalpha, vce(hc3)
eststo:reg choicebefore $covariates2 Highx10 Highx100 stdalpha selfishseeincentivecostly selfishseequalitycostly, vce(hc3)


local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{11}\selectfont" "\caption{Preference for Information Order: Including Incentives Treatments}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "$\ \ \ \ \ \ \ \ \ \ \ \ \ \ $    &\multicolumn{3}{c}{\textbf{Prefer to See Incentive First}} \\\hline & & & \\"


esttab using  "${appendix}Choice_Preferences_Including_Stakes.tex", ///
 se r2 replace lines cells(b(star fmt(2)) se(par fmt(2))) ///
coeflabel (professionalsfree "Choice Free -- Professionals    $  \ \ \ \ \ \ \  $" seeincentivecostly "See Incentive First Costly          " seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" ///
female "Female" age "Age" stdalpha "Selfishness" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "See Incentive First Costly X Selfishness       " selfishseequalitycostly "See Quality First Costly X Selfishness            " ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft ///
"Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order" ///
Highx10 "High Stakes (10-fold incentives)" ///
Highx100 "High Stakes (100-fold incentives)") ///
order (seeincentivecostly seequalitycostly  professionalsfree Highx10 Highx100 stdalpha selfishseeincentivecostly selfishseequalitycostly female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  collabels(none)  ///
drop(wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch) ///
nomtitle label substitute(" 0.000 " " " " (.) " " ") ///
prehead("`panel'") posthead("`dv'") postfoot("\hline" "\end{tabular}%" "\captionsetup{width=0.75\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the preference to see the incentive first. See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. Selfishness was elicited at the end of the experiment, using a multiple price list (MPL) with 5 decisions. The variable is a standardized measure of the number of times the advisor chose to recommend the incentivized product in the MPL task. The regression models in columns (2) and (3) include individual controls for the advisor's gender and age, each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:demand_highincentives}" "\end{table}")
	
**********************************************************************************
**** APPENDIX - TABLE C.19:  RECOMMENDATIONS - INCLUDING HIGHx10 and HIGhx100 TREATMENTS
**********************************************************************************

foreach var in choicebefore choicebeforenoconflict noconflict ///
notgetyourchoice choicebeforenotgetyourchoice notgetyourchoicenoconflict{
	g `var'x10=`var'*Highx10
	g `var'x100=`var'*Highx100
}

*get pref
est clear 
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict Highx10 Highx100 ///
	choicebeforex10 choicebeforenoconflictx10 noconflictx10 ///
	choicebeforex100 choicebeforenoconflictx100 noconflictx100 ///
		incentiveB $covariates2 if  getyourchoice==1, vce(hc3)

*not get
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict Highx10 Highx100  ///
	choicebeforex10 choicebeforenoconflictx10 noconflictx10 ///
	choicebeforex100 choicebeforenoconflictx100 noconflictx100 ///
incentiveB $covariates2 if getyourchoice==0, vce(hc3) 

*combined
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict notgetyourchoice choicebeforenotgetyourchoice ///
		notgetyourchoicenoconflict Highx10 Highx100 ///
choicebeforex10 choicebeforenoconflictx10 noconflictx10 ///
choicebeforex100 choicebeforenoconflictx100 noconflictx100 ///
notgetyourchoicex10 choicebeforenotgetyourchoicex10 ///
 notgetyourchoicenoconflictx10 ///
 notgetyourchoicex100 choicebeforenotgetyourchoicex100 ///
 notgetyourchoicenoconflictx100 ///
incentiveB $covariates2 ///
		, vce(hc3)

local panel "\begin{table}[h!]" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{10}\selectfont" "\caption{Advisor Recommendations: Including Incentives Treatments}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "&\multicolumn{3}{c}{\textbf{Recommend incentivized product}} \\"
local groups "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Both}  \\\hline &  &     &   &  \\   "
local conflict "&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict} \\ \hline    & &    &            &     &            &  \\"


esttab using  "${appendix}Choice_Recommendations_IncludingStakes.tex",  se r2 replace cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (noconflict "No Conflict" getbefore "Assigned to See Incentive First"  getbeforenoconflict "Assigned to See Incentive First X No Conflict" professionalsfree "Choice Free--Professionals" seeincentivecostly "See Incentive First Costly" seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" notgetyourchoice "Not Assigned Preference" ///
female "Female" age "Age" selfish "Selfish" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "Selfish X See Incentive First Costly" selfishseequalitycostly "Selfish X See Quality First Costly" ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order" ///
incentiveB "Incentive for B" choicebefore "Prefer to See Incentive First" ///
choicebeforenoconflict "No Conflict X Prefer to See Incentive First" ///
choicebeforenotgetyourchoice "Prefer to See Incentive First X Not Assigned Pref." ///
Highx10 "High Stakes (10-fold incentives)" ///
Highx100 "High Stakes (100-fold incentives)" ///
notgetyourchoicenoconflict "No Conflict X Not Assigned Preference" ///
selfishchoicebefore "Prefer to See Incentive First X Selfish" ///
selfishnotgetyourchoice "Not Assigned Preference X Selfish" ///
choicebeforex10 "Prefer to See Incentive First X High Stakes (10-fold)" ///
choicebeforex100 "Prefer to See Incentive First X High Stakes (100-fold)") ///
order (choicebefore notgetyourchoice choicebeforenotgetyourchoice noconflict choicebeforenoconflict notgetyourchoicenoconflict seeincentivecostly seequalitycostly  professionalsfree incentiveB female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Advisor Recommendations") ///
drop(professionalsfree wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ///
choicebeforenoconflictx10 noconflictx10 ///
choicebeforenoconflictx100 noconflictx100 ///
notgetyourchoicex10 choicebeforenotgetyourchoicex10 ///
 notgetyourchoicenoconflictx10 ///
 notgetyourchoicex100 choicebeforenotgetyourchoicex100 ///
 notgetyourchoicenoconflictx100) ///
mlabels(none) label collabels(none) substitute(" 0.000 " " " " (.) " " ") ///
posthead("`dv'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the advisor's decision to recommend the incentivized option. Column (1) focuses on individuals who are assigned their preference, while column (2) focuses on individuals who are not assigned their preference. Both groups are merged in column (3). Prefer to See Incentive First is an indicator of the advisor's preference, and Not Assigned Preference is an indicator for not receiving the preferred order. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. Choice Free-Professionals, See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. All regression models include controls for each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:recommendations_highincentives}" "\end{table}")

**********************************************************************************
**** 				SECTION C.5: INCLUDING INATTENTIVE PARTICIPANTS
**** APPENDIX - TABLE C.20:  PREFERENCES - INCLUDING INATTENTIVE
**********************************************************************************

clear
u "${data}choice_experiments.dta"
*As pre-registered, drop Mturk participant with inconsistent alpha value
drop if study!=1 & alphavaluefinal==. /*(study1 are profs and there's no MPL')*/
global covariates "wave2 wave3 professionalscloudresearch incentiveshigh##incentiveleft age female"	
global covariates2 "professionalsfree seeincentivecostly seequalitycostly wave2 wave3 professionalscloudresearch incentiveshigh incentiveleft incentiveshigh_incentiveleft age female"


tab alphavaluefinal if  Highx10==0 | Highx100==0, m
			
est clear
eststo:reg choicebefore $covariates2 if Highx10==0 & Highx100==0 & alphavaluefinal!=., vce(hc3)
eststo:reg choicebefore $covariates2 if Highx10==0 & Highx100==0, vce(hc3)

local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{11}\selectfont" "\caption{Preference for Information Order---Including Inattentive}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "$\ \ \ \ \ \ \ \ \ \ \ \ \ \ $    &\multicolumn{3}{c}{\textbf{Prefer to See Incentive First}} \\\hline & & & \\"
local pref "\multicolumn{1}{r}{\textit{Sample:}}&\multicolumn{1}{c}{Main Sample}&\multicolumn{1}{c}{Including Inattentive}\\ \hline        &     &        &  \\"

esttab using  "${appendix}Choice_Demand_withInattentive.tex", ///
 se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (professionalsfree "Choice Free -- Professionals    $  \ \ \ \ \ \ \  $" seeincentivecostly "See Incentive First Costly          " seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" ///
female "Female" age "Age" stdalpha "Selfishness" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "See Incentive First Costly X Selfish       " selfishseequalitycostly "See Quality First Costly X Selfish            " ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order") ///
order (seeincentivecostly seequalitycostly  professionalsfree stdalpha selfishseeincentivecostly selfishseequalitycostly female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  collabels(none)  ///
drop(wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch stdalpha selfishseeincentivecostly selfishseequalitycostly) ///
nomtitle label substitute(" 0.000 " " " " (.) " " ") ///
prehead("`panel'") posthead("`dv'") postfoot("\hline" "\end{tabular}%" "\captionsetup{width=0.75\textwidth}" "\caption*{\footnotesize Note: This table displays the estimated coefficients from linear probability models on the advisor's preference to see the incentive first. Column (1) focuses on individuals who are assigned their preference, while column (2) focuses on individuals who are not assigned their preference. Both groups are merged in column (3). Prefer to See Incentive First is an indicator of the advisor's preference, and Not Assigned Preference is an indicator for not receiving the preferred order. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. All regression models include individual controls for the advisor's gender and age, each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:demand_inattentive}" "\end{table}")
		
		
		
**********************************************************************************
**** APPENDIX - TABLE C.21:  RECOMMENDATIONS - INCLUDING INATTENTIVE
**********************************************************************************

*get pref
est clear 
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==1, vce(hc3)
test choicebefore+choicebeforenoconflict==0
		
*not get
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 if Highx10==0 & Highx100==0 & getyourchoice==0, vce(hc3)

*combined
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict notgetyourchoice choicebeforenotgetyourchoice notgetyourchoicenoconflict incentiveB $covariates2 ///
		if Highx10==0 & Highx100==0, vce(hc3)
test choicebefore+choicebeforenoconflict==0
test choicebefore+notgetyourchoice+choicebeforenotgetyourchoice==0
test notgetyourchoice+choicebeforenotgetyourchoice==0		

lincom notgetyourchoice+choicebeforenotgetyourchoice


local panel "\begin{table}[h!]" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{10}\selectfont" "\caption{Advisor Recommendations---Including Inattentive}" "\hspace{-0.5cm}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "&\multicolumn{3}{c}{\textbf{Recommend incentivized product}} \\"
local groups "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Both} \\\hline &  &     &     \\   "
local conflict "&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict} \\ \hline    & &    &            &     &            &  \\"
	
esttab using  "${appendix}Choice_Recommendations_WithInattentive.tex",  se r2 replace cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (noconflict "No Conflict" getbefore "Assigned to See Incentive First"  getbeforenoconflict "Assigned to See Incentive First X No Conflict" professionalsfree "Choice Free--Professionals" seeincentivecostly "See Incentive First Costly" seequalitycostly "Assess Quality First Costly" wave2 "Wave 2" wave3 "Wave 3" notgetyourchoice "Not Assigned Preference" ///
female "Female" age "Age" stdalpha "Selfishness" professionalscloudresearch "Professionals x Cloudresearch" selfishseeincentivecostly "Selfish X See Incentive First Costly" selfishseequalitycostly "Selfish X See Quality First Costly" ///
incentiveshigh "Probabilistic Incentive Mturk" incentiveleft "Order" incentiveshigh_incentiveleft "Probabilistic Incentive X Order" ///
incentiveB "Incentive for B" choicebefore "Prefer to See Incentive First" ///
choicebeforenoconflict "No Conflict X Prefer to See Incentive First" ///
choicebeforenotgetyourchoice "Prefer to See Incentive First X Not Assigned Preference" ///
notgetyourchoicenoconflict "No Conflict X Not Assigned Preference") ///
order (choicebefore notgetyourchoice choicebeforenotgetyourchoice noconflict choicebeforenoconflict notgetyourchoicenoconflict  professionalsfree seeincentivecostly seequalitycostly  incentiveB  selfish female age wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch ) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Advisor Recommendations") ///
drop(selfish wave2 wave3 incentiveshigh incentiveleft incentiveshigh_incentiveleft professionalscloudresearch) ///
mlabels(none) label collabels(none) substitute(" 0.000 " " " " (.) " " ") ///
posthead("`dv'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=1.1\textwidth}" "\caption*{\footnotesize Note: This table displays the estimated coefficients from linear probability models on the advisor's decision to recommend the incentivized option. Column (1) focuses on individuals who are assigned their preference, while column (2) focuses on individuals who are not assigned their preference. Both groups are merged in column (3). Prefer to See Incentive First is an indicator of the advisor's preference, and Not Assigned Preference is an indicator for not receiving the preferred order. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. Choice Free-Professionals, See Incentive First Costly and Assess Quality First Costly are indicator variables that take value 1 in the respective treatment, 0 otherwise. All regression models include controls for each wave of the experiment, whether incentives were probabilistic, the position of the products on the screen and the interaction between these two variables. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:recommendations_inattentive}" "\end{table}")


********************************************************************************	
********************************************************************************	
*CHOICESTAKES EXPERIMENT	
********************************************************************************	
********************************************************************************	
u "${data}stakes.dta", clear

drop if alphavaluefinal==.


global indiva "female age stdalpha"
	
******************************************
*FIGURE 7: DEMAND SEE INCENTIVES BEFORE
****************************************** 
bys condition: egen meandemand=mean(choicebefore)
bys condition: egen sddemand=sd(choicebefore) 
bys condition: egen ndemand=count(choicebefore) 
g lodemand=meandemand-1.96*(sqrt((meandemand*(1-meandemand))/ndemand))
g hidemand=meandemand+1.96*(sqrt((meandemand*(1-meandemand))/ndemand))


g meancommit =1

twoway (bar meancommit conditionnum, fcolor(white) lcolor(gs10) barw(0.65)) ///
		(bar meandemand conditionnum if conditionnum==1 , fcolor(gs10) lcolor(gs10) barw(0.65)) ///
		(bar meandemand conditionnum if conditionnum==2 , fcolor(gs10) lcolor(gs10) barw(0.65)) ///
		(bar meandemand conditionnum if conditionnum==3 , fcolor(gs10) lcolor(gs10) barw(0.65)) ///
		(rcap lodemand hidemand conditionnum, lcolor(gs10)) ///
		, 	ytitle("Advisor's preference") xtitle(" " "Treatment") ///
		graphr(c(white)) ylabel(0(0.2)1, gmax) ///
			xlabel(1 "Low Incentive" 2 "Intermediate Incentive" 3 "High Incentive") ///
		 xscale(r(0.5 3.5)) ///
		legend(order(2 1) lab(1 "Prefer to Assess Quality First") ///
		lab(2 "Prefer to See Incentive First") size(*0.9)) ///
		text(0.05 1 "0.13") text(0.30 2 "0.41") text(0.3 3 "0.44") ///
		text(0.95 1 "0.87") text(0.95 2 "0.59") text(0.95 3 "0.56")
graph export "${main}bar_stakes.pdf", replace 		

* Section 8 - page 36: 41%of advisors prefer to see the incentive first, replicating our finding in the Incentives First Costly treatment of Choice Experiment
tabstat choicebefore, by(condition)	s(mean n)

* This fraction decreases significantly in the Low Incentive treatment, to 13% (Z − stat = 9.79, p < 0.001)
prtest choicebefore if conditionnum!=3, by(conditionnum)

*In the High Incentive treatment, the advisors’ preference to see the incentive first increases by
* only 3 percentage points, to 44% (Z − stat = 0.96, p = 0.337)	
prtest choicebefore if conditionnum!=1, by(conditionnum)	

global covariates2 "commissionlow commissionhigh age female"

/* 	When advisors are assigned their preferred order, they are

	14 percentage points more likely to recommend the incentivized product 



		See Column 1 of Table C.23 in Appendix C.6 (lines 2115-2157 of the analysis do file)



	When doubling the commission of the advisor, however, the preference to see the incentive first

	increases by only 3 percentage points, less than 10 percent



		See Column 1 of Table C.22 in Appendix C.6 (lines 2103-2119)



*/

**************************************************************************
* APPPENDIX TABLE C.22: CHOICESTAKES - PREFERENCES FOR INFORMATION ORDER
**************************************************************************

est clear
eststo:reg choicebefore $covariates2, vce(hc3)
eststo:reg choicebefore $covariates2 stdalpha, vce(hc3)
*eststo:reg choicebefore $covariates2 selfish selfishseeincentivecostly selfishseequalitycostly if Highx10==0 & Highx100==0, vce(hc3)

local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{11}\selectfont" "\caption{Preference for Information Order}" "\begin{tabular}{l*{2}{c}} \hline" 
local dv "$\ \ \ \ \ \ \ \ \ \ \ \ \ \ $    &\multicolumn{2}{c}{\textbf{Prefer to See Incentive First}} \\\hline & & & \\"

esttab using  "${appendix}Demand_ChoiceStakes.tex", ///
 se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (commissionlow "Low Incentive    $  \ \ \ \ \ \ \  $" commissionhigh "High Incentive $  \ \ \ \ \ \ \  $" ///
female "Female" age "Age" stdalpha "Selfishness") ///
order (commissionlow commissionhigh stdalpha female age ) ///
star(* 0.10 ** 0.05 *** 0.01)  collabels(none)  ///
drop() ///
nomtitle label substitute(" 0.000 " " " " (.) " " ") ///
prehead("`panel'") posthead("`dv'") postfoot("\hline" "\end{tabular}%" "\captionsetup{width=0.7\textwidth}" "\caption*{\footnotesize \textit{Note:} This table displays the estimated coefficients from linear probability models on the preference to see the incentive first. Low Incentive and High Incentive are indicator variables that take value 1 in the respective treatment, 0 otherwise. Selfishness was elicited at the end of the experiment, using a multiple price list (MPL) with 5 decisions. The variable is a standardized measure of the number of times the advisor chose to recommend the incentivized product in the MPL task. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:demand_stakes}" "\end{table}")
	
	
**************************************************************************
* APPPENDIX TABLE C.23: CHOICESTAKES - RECOMMENDATIONS
**************************************************************************

*get pref
est clear 
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 commissionlowchoicebefore commissionhighchoicebefore if getyourchoice==1, vce(hc3)
test choicebefore+choicebeforenoconflict==0
		
*not get
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict incentiveB $covariates2 commissionlowchoicebefore commissionhighchoicebefore if getyourchoice==0, vce(hc3)

*combined
eststo: reg recommendincentive choicebefore choicebeforenoconflict ///
		noconflict notgetyourchoice choicebeforenotgetyourchoice notgetyourchoicenoconflict incentiveB $covariates2 ///
		commissionlowchoicebefore commissionhighchoicebefore , vce(hc3)
test choicebefore+choicebeforenoconflict==0
test choicebefore+notgetyourchoice+choicebeforenotgetyourchoice==0
test notgetyourchoice+choicebeforenotgetyourchoice==0		

lincom notgetyourchoice+choicebeforenotgetyourchoice


local panel "\begin{table}[h!]" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{10}\selectfont" "\caption{Advisor Recommendations}" "\hspace{-0.5cm}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "&\multicolumn{3}{c}{\textbf{Recommend incentivized product}} \\"
local groups "\multicolumn{1}{r}{\textit{Assignment:}}&\multicolumn{1}{c}{Assigned Pref.}&\multicolumn{1}{c}{Not Assigned Pref.}&\multicolumn{1}{c}{Both} \\\hline &  &     &     \\   "
local conflict "&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict}&\multicolumn{1}{c}{Conflict}&\multicolumn{1}{c}{No Conflict} \\ \hline    & &    &            &     &            &  \\"
	
esttab using  "${appendix}recommendations_pref_assign_stakes.tex",  se r2 replace cells(b(star fmt(4)) se(par fmt(4))) ///
coeflabel (noconflict "No Conflict" choicebefore "Prefer to See Incentive First" getbefore "Assigned to See Incentive First"  getbeforenoconflict "Assigned to See Incentive First X No Conflict" notgetyourchoice "Not Assigned Preference" ///
female "Female" age "Age" commissionlow "Low Incentive" commissionhigh "High Incentive"  incentiveB "Incentive for B" ///
choicebeforenoconflict "No Conflict X Prefer to See Incentive First" ///
choicebeforenotgetyourchoice "Prefer to See Incentive First X Not Assigned Preference" ///
notgetyourchoicenoconflict "No Conflict X Not Assigned Preference" ///
commissionlowchoicebefore "Low Incentive X Prefer to See Incentive First" ///
commissionhighchoicebefore "High Incentive X Prefer to See Incentive First" stdalpha "Selfishness") ///
order (choicebefore notgetyourchoice choicebeforenotgetyourchoice noconflict choicebeforenoconflict notgetyourchoicenoconflict  commissionlow commissionlowchoicebefore commissionhigh commissionhighchoicebefore incentiveB female age) ///
star(* 0.10 ** 0.05 *** 0.01)  title("Advisor Recommendations") ///
drop() ///
mlabels(none) label collabels(none) substitute(" 0.000 " " " " (.) " " ") ///
posthead("`dv'" "`groups'") prehead("`panel'") nolines postfoot("\hline" "\end{tabular}%" "\captionsetup{width=1.1\textwidth}" "\caption*{\footnotesize \textit{Notes:} This table displays the estimated coefficients from linear probability models on the advisor's decision to recommend the incentivized option. Column (1) focuses on individuals who are assigned their preference, while column (2) focuses on individuals who are not assigned their preference. Both groups are merged in column (3). Prefer to See Incentive First is an indicator of the advisor's preference, and Not Assigned Preference is an indicator for not receiving the preferred order. No Conflict is an indicator for the cases in which the signal of quality is not in conflict with the advisor's commission. Low Incentive and High Incentive are indicator variables that take value 1 in the respective treatment, 0 otherwise. Robust standard errors (HC3) in parentheses. * p$<$.10; ** p$<$.05; *** p$<$.01}" "\label{tab:recommendations_stakes}" "\end{table}")
		

********************************************************************************	
********************************************************************************	
* INFORMATION ARCHITECT EXPERIMENT
********************************************************************************	
********************************************************************************

clear
u "${data}InformationArchitect.dta"
***** MAIN TEXT - Excluding participants inattentive in the MPL
tab IAAdvisor if alphavaluefinal!=.

*where advisors’ incentives are aligned with the client (58% vs 44%, N = 498, Z − stat = −3.23, p = 0.001), page 37
prtest choicebefore if alphavaluefinal!=., by(IAAdvisor)


**************************************************************************
* APPPENDIX TABLE C.24: INFORMATION ARCHITECT PREFERENCES BY CONDITION
**************************************************************************

est clear 
eststo: reg choicebefore IAAdvisor age female if alphavaluefinal!=., vce(hc3)
eststo: reg choicebefore IAAdvisor age female , vce(hc3)


local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{9}{10}\selectfont" "\begin{tabular}{l*{3}{c}}\hline" 
local dv "&\multicolumn{2}{c}{\textbf{DM Choice to See Incentive First}} \\"
local pref "\multicolumn{1}{r}{\textit{Sample:}}&\multicolumn{1}{c}{Main Sample}&\multicolumn{1}{c}{Including Inattentive}\\ \hline        &     &        &  \\"

esttab using  "${appendix}IA_Preferences.tex",  se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (IAAdvisor "IA-Advisor" ///
 IAClient "IA-Client" ) ///
order (DMAdvisor) ///
star(* 0.10 ** 0.05 *** 0.01) ///
mlabels(none) label collabels(none) ///
drop(age female) ///
addnotes("Note:  * p$<$.10; ** p$<$.05; *** p$<$.01") posthead("`dv'" "`pref'" ) prehead("`panel'") ///
 postfoot("\hline" "\end{tabular}%" "\captionsetup{width=0.55\textwidth}" ///
"\caption*{\footnotesize \textit{Notes:} This table displays the coefficient estimates of OLS regressions on the Information Architect's preferences to have the advisor see the incentive first for the main sample (Column 1) and the sample that includes inattentive participants who switched multiple times in the selifishness measure. DM-Advisor is an indicator for whether advisors have an incentive to receive information about their incentive first. Robust standard errors in parentheses. \sym{*} \(p<0.10\), \sym{**} \(p<0.05\), \sym{***} \(p<0.01\).}" "\label{tab:dmdemand}" "\end{table}")

**** MAIN TEXT -- Comparing proportion of IA wanting to see info before to main Choice Free experiment
clear
u "${data}InformationArchitect.dta" 
append using "${data}choice_experiments.dta"
*As pre-registered, drop Mturk participant with inconsistent alpha value
drop if study!=1 & alphavaluefinal==. /*(study1 are profs and there's no MPL')*/

tab study
tab condition
tab professionals

gen DMAdvisor=0
replace DMAdvisor=1 if condition=="IA-Advisor"

drop if alphavaluefinal==.

** Section 8.2: "..is similar to the average fraction of advisors who prefer to see the incentive first in the Choice Free treatment of the Choice experiment (56%)(Z − stat = 0.497, p = 0.62)", page 37

prtest choicebefore if professionals==0 & (condition=="ChoiceFree" & Highx10==0 & Highx100==0 )| condition=="IA-Advisor", by(condition) 


** Appendix, page 47: CLients
***we recruited $N=50$ clients for the main task
*** of these 86\% followed the recommendations. 
preserve
u "${data}Clients_InfoArchitectsMain.dta", clear 
tab follow
restore

***: We also recruited an additional $N=50$ advisees for the MPL task that measured advisors' moral costs and matched them with 1 out of 10 Information Architects
*** and an additional $N=50$ advisees for the same task and matched them with 1 out of 10 advisors.
*** Of these, 86\% and 80\% of advisees followed the recommendation. 
preserve
u "${data}Clients_IAInfoArchitects_MPL.dta", clear
tab follow
restore

preserve
u "${data}Clients_IAAdvisors_MPL.dta", clear 
tab follow
restore



********************************************************************************	
********************************************************************************	
* NOCHOICE_SIMOULTANEOUS (APPENDIX)
********************************************************************************	
********************************************************************************



clear
u "${data}NoChoiceSimoultaneous.dta"

tab missingalpha
/* 50.63% of participants (N=283) switched multiple times in the MPL task, and cannot be classified as selfish/moral. By contrast, in the original NoChoice experiment, only

N=28 (8.56%) switched multiple times. As for the othe experiments, we pre-registered that we would drop any participant who switches multiple times. However, in all of our other experiments we always had 

 at the most 15% of participants switching multiple times. At the time we ran he experiment, Cloudresearch changed some of the features it used to filter

 participants (https://urldefense.com/v3/__https://www.cloudresearch.com/resources/blog/cloudresearch-is-retiring-the-block-low-quality-participants-option/__;!!Mih3wA!HOIpQ2WhA_qwbAphb6tUVYcbui2LabnX4Z-MXMgq6RR26RYq6gxyZAkrUUeLXM1zVSY8yQ0x0v9WXa5H0Q$  ) In particular,

 CloudResearch removed their “Block Low Quality Participants” which is what we have used in all prior experiments.  This change resulted in data quality issues

 as, at the time we ran the study, we could not filter out inattentive participants/BOTs as well as before. Due to this changes, we decided to analyze this data in

 two ways: both excluding all participants who switch multiple times as pre-registered, and by keeping them in our sample. In both cases, we merge this data with the 

 first wave of the NoChoice experiment, as pre-registered. */
 
 
*** MERGE with Original Nochoice ***

append using "${data}nochoice.dta"
save "${data}nochoice1_2_merged.dta", replace
 
replace wave=1 if wave==.
replace seeincentivefirst=1 if condition=="BeforeA" | condition=="BeforeB"
replace seeincentivefirst=0 if condition=="AfterA" | condition=="AfterB"
replace Together=0 if wave==1
replace noconflict=1-conflict
replace missingalpha=(alphavaluefinal==.)
replace seeincentivefirst_noconflict= seeincentivefirst*noconflict
gen together_noconflict= Together*noconflict
gen wave2=(wave==2)
drop stdalpha
egen stdalpha=std(alphavaluefinal)


**************************************************************************
* APPPENDIX TABLE D.1: INFORMATION ARCHITECT PREFERENCES BY CONDITION
**************************************************************************


est clear
eststo:reg recommendincentive seeincentivefirst noconflict seeincentivefirst_noconflict Together together_noconflict incentiveB female age   wave2 if missingalpha==0, vce(hc3)
eststo:reg recommendincentive seeincentivefirst noconflict seeincentivefirst_noconflict Together together_noconflict incentiveB female age stdalpha  wave2 if missingalpha==0, vce(hc3)
eststo:reg recommendincentive seeincentivefirst noconflict seeincentivefirst_noconflict Together together_noconflict incentiveB female age wave2 , vce(hc3)



local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{11}\selectfont" "\caption{Advisor Recommendations - No Choice (Simultaneous)}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv "& & & \textbf{Including} \\" "$\ \ \ \ \ \ \ \ \ \ \ \ \ \ $   &\multicolumn{2}{c}{\textbf{Main Sample}}  &\multicolumn{1}{c}{\textbf{Inattentive}}  \\\hline & & & \\"

esttab using  "${appendix}Simultaneous.tex",  se r2 replace lines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel (seeincentivefirst "See Incentive First" noconflict "No Conflict" seeincentivefirst_noconflict "See Incentive First * No Conflict"  ///
Together "Simultaneous" together_noconflict "Simultaneous X No Conflict" incentiveB "Incentive for B" ///
female "Female" age "Age" stdalpha "Selfishness"  ) ///
order ( seeincentivefirst noconflict seeincentivefirst_noconflict Together together_noconflict incentiveB female age stdalpha) ///
drop (wave2 female age) ///
star(* 0.10 ** 0.05 *** 0.01) collabels(none)  ///
nomtitle label substitute(" 0.000 " " " " (.) " " ") ///
prehead("`panel'") posthead("`dv'") postfoot("\hline" "\end{tabular}%" "\captionsetup{width=0.75\textwidth}" "\caption*{\footnotesize Note: This table displays the estimated coefficients from linear probability models on the advisors' recommendations. See Incentive first is a binary indicator coded as 1 for participants who were randomly assigned to see the incentive first. Simultaneous is a binary indicator coded as 1 for participants who saw all infornation at the same time. Selfishness was elicited at the end of the experiment, using a multiple price list (MPL) with 5 decisions. The variable is a standardized measure of the number of times the advisor chose to recommend the incentivized product in the MPL task. The regression models in columns (1) and (2) restrict the analyses to participants who did not switch multiple times in the MPL. Column (3) includes all participants. The regression includes individual controls for the advisor's gender and age, and a binary indicator for the wave in which participants took part in the experiment. Robust standard errors (HC3) in parentheses}" "\label{tab:simultaneous}" "\end{table}")


***** Appendix, page 49: CLients
** The 276 attentive participants were matched with $N=28$ clients for the main task;
** of these 96\% followed the recommendation.
clear
u "${data}Clients_NoChoiceSimultaneousMain.dta" 
tab follow

*** They were also matched with $N=28$ clients for the MPL task
*** of these 79\% followed the recommendation.
clear
u "${data}Clients_NoChoiceSimultaneousMPL.dta" 
tab follow


*******************************************************************************	
********************************************************************************	
* CHOICE DETERMINISTIC (APPENDIX)
********************************************************************************	
********************************************************************************

clear
u "${data}Choice_Deterministic.dta"


tab alphavaluefinal, m
	*** 20.80% of  participants switched multilple times
	*** We pre-registered that, if more than 15% of participants switched twice, 
	*** we would do analysis with and without these participants. 
tab condition if alphavaluefinal!=.
* DEMAND *
tab  condition choicebefore if alphavaluefinal!=., row
tab  condition choicebefore if alphavaluefinal!=., chi2
/* When we drop the inconsistent MPL participants, we have a marginally significant difference 

in the proportion of participants demanding to see the incentive first between the 2 conditions (p<.10) */

tab  condition choicebefore , row
tab  condition choicebefore , chi2
*Including inattentive participants, demand to see the incentive first is 62.9% and 58.7%, respectively, and the difference is not significant (\chi^2-test= 1.66, p=0.197). 	


**************************************************************************
* APPPENDIX FIGURE E.1: RECOMMENDATIONS IN CHOICE DETERMINISTIC EXPERIMENT
**************************************************************************
			
bys condition: egen recbefore_before=mean(recommendincentive) if choicebefore==1 & getbefore==1 & conflict==1
bys condition: egen recbefore_after=mean(recommendincentive) if choicebefore==1 & getbefore==0 & conflict==1
bys condition: egen recafter_before=mean(recommendincentive) if choicebefore==0 & getbefore==1 & conflict==1
bys condition: egen recafter_after=mean(recommendincentive) if choicebefore==0 & getbefore==0 & conflict==1


bys condition: egen sdrecbefore_before=sd(recommendincentive) if choicebefore==1 & getbefore==1 & conflict==1
bys condition: egen sdrecbefore_after=sd(recommendincentive) if choicebefore==1 & getbefore==0 & conflict==1
bys condition: egen sdrecafter_after=sd(recommendincentive) if choicebefore==0 & getbefore==0 & conflict==1
bys condition: egen sdrecafter_before=sd(recommendincentive) if choicebefore==0 & getbefore==1 & conflict==1
bys condition: egen nrecbefore_before=count(recommendincentive) if choicebefore==1 & getbefore==1 & conflict==1
bys condition: egen nrecbefore_after=count(recommendincentive) if choicebefore==1 & getbefore==0 & conflict==1
bys condition: egen nrecafter_after=count(recommendincentive) if choicebefore==0 & getbefore==0 & conflict==1
bys condition: egen nrecafter_before=count(recommendincentive) if choicebefore==0 & getbefore==1 & conflict==1


g lobefore_before=recbefore_before-1.96*((sdrecbefore_before)/sqrt(nrecbefore_before))
g hibefore_before=recbefore_before+1.96*((sdrecbefore_before)/sqrt(nrecbefore_before))
g lobefore_after=recbefore_after-1.96*((sdrecbefore_after)/sqrt(nrecbefore_after))
g hibefore_after=recbefore_after+1.96*((sdrecbefore_after)/sqrt(nrecbefore_after))


g loafter_after=recafter_after-1.96*((sdrecafter_after)/sqrt(nrecafter_after))
g loafter_before=recafter_before-1.96*((sdrecafter_before)/sqrt(nrecafter_before))
g hiafter_after=recafter_after+1.96*((sdrecafter_after)/sqrt(nrecafter_after))
g hiafter_before=recafter_before+1.96*((sdrecafter_before)/sqrt(nrecafter_before))


g treatnumgraph2=1 if  choicebefore==1 & getbefore==1 & condition=="ChoiceFree_Probabilistic" 
replace treatnumgraph2=1.1 if choicebefore==1 & getbefore==0 & condition=="ChoiceFree_Probabilistic" 
replace treatnumgraph2=1.2 if  choicebefore==0 & getbefore==1 & condition=="ChoiceFree_Probabilistic" 
replace treatnumgraph2=1.3 if  choicebefore==0 & getbefore==0 & condition=="ChoiceFree_Probabilistic" 

replace treatnumgraph2=1.8 if  choicebefore==1 & getbefore==1 & condition=="ChoiceFree_Deterministic" 
replace treatnumgraph2=2.1 if  choicebefore==0 & getbefore==0 & condition=="ChoiceFree_Deterministic" 



twoway 	(scatteri 1 0.8 1 1.6, bcolor(gs15) recast(area)) ///
		(rcap lobefore_before hibefore_before treatnumgraph2, lcolor(red  ) lwidth(thin)) ///
		(rcap loafter_after hiafter_after treatnumgraph2, lcolor( black) lwidth(thin)) ///
		(rcap lobefore_after hibefore_after treatnumgraph2, lcolor( red*0.3 ) lwidth(thin)) ///
		(rcap loafter_before hiafter_before treatnumgraph2, lcolor( black*0.3) lwidth(thin)) ///
		(scatter recbefore_before treatnumgraph2 if ///
		condition=="ChoiceFree_Probabilistic", mcolor(red) msize(*0.8) ms(T)) ///
		(scatter recbefore_after treatnumgraph2 if ///
		condition=="ChoiceFree_Probabilistic", mfcolor(white) msize(*0.8) mlcolor(red%50) ms(T)) ///
		(scatter recafter_after treatnumgraph2 if ///
		condition=="ChoiceFree_Probabilistic", mcolor(black) mlcolor(black) msize(*0.8) ms(S)) ///
		(scatter recafter_before treatnumgraph2 if ///
		condition=="ChoiceFree_Probabilistic" , mfcolor(white) mlcolor(black%50) msize(*0.8) ms(S)) ///
		(scatter recbefore_before treatnumgraph2 if ///
		condition=="ChoiceFree_Deterministic" , mcolor(red) msize(*0.8) ms(T)) ///
		(scatter recafter_after treatnumgraph2 if ///
		condition=="ChoiceFree_Deterministic", mcolor(black) msize(*0.8) mlcolor(black) ms(S)) ///
		, graphr(c(white)) plotr(c(white)) ///
		ylabel(0(0.1)1) yscale(r(0.2 1)) 	///
		xtitle(" " "Treatment") ///
		xlabel(none) ///   fgfd                  
		xscale(r(0.8 2.3)) ///
		legend(order( - "{bf:Advisor Prefers to}" "{bf:See Incentive First}" ///
		6 7 - "{bf:Advisor Prefers to}" "{bf:Assess Quality First}" 9 8) ///
		lab(6 " Assigned to See Incentive First") ///
		lab(8 " Assigned to Assess Quality First") ///
		lab(7 " Assigned to Assess Quality First") ///
		lab(9 " Assigned to See Incentive First") ///
		rows(3) colfirst size(*0.9)) ///
		text(0.15 1.15 "{bf: Choice Free}", color(black) size(*0.9)) ///
		text(0.07 1.15 "{bf: Probabilistic}", color(black) size(*0.9)) ///		
		text(0.15 2 "{bf: Choice Free}", color(black) size(*0.9)) ///
		 text(0.07 2 "{bf: Deterministic}", color(black) size(*0.9)) ///
		ytitle("{bf:Incentivized product recommendation}" " " )  

		graph export "${appendix}Deterministic_Recommendations.png", replace


**************************************************************************
* APPPENDIX TABLE E.1: RECOMMENDATIONS 
**************************************************************************

clear
u "${data}Choice_Deterministic.dta" 



tab condition recommendincentive if choicebefore==1 & getbefore==1 & conflict==1, row 
tab condition recommendincentive if choicebefore==1 & getbefore==0 & conflict==1, row
tab condition recommendincentive if choicebefore==1 & getbefore==1 & conflict==0, row
tab condition recommendincentive if choicebefore==1 & getbefore==0 & conflict==0, row


tab condition recommendincentive if choicebefore==0 & getbefore==1 & conflict==1, row 
tab condition recommendincentive if choicebefore==0 & getbefore==0 & conflict==1, row 
tab condition recommendincentive if choicebefore==0 & getbefore==1 & conflict==0 , row 
tab condition recommendincentive if choicebefore==0 & getbefore==0 & conflict==0 , row 


		
*** Recommendation regression (One table with and without participants who switched multiple times in the MPL


est clear
eststo:reg recommendincentive choicebefore noconflict choicebefore_noconflict Deterministic Deterministic_noconflict choicebefore_Deterministic Deterministic_choicebeforeNocon incentiveB female age if getyourchoice==1 & alphavaluefinal!=., vce(hc3)
eststo:reg recommendincentive choicebefore noconflict choicebefore_noconflict Deterministic Deterministic_noconflict choicebefore_Deterministic Deterministic_choicebeforeNocon incentiveB female age stdalpha if getyourchoice==1 & alphavaluefinal!=., vce(hc3)
eststo:reg recommendincentive choicebefore noconflict choicebefore_noconflict Deterministic Deterministic_noconflict choicebefore_Deterministic Deterministic_choicebeforeNocon incentiveB female age if getyourchoice==1, vce(hc3)


local panel "\begin{table}[h!]" "\centering" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}" "\fontsize{10}{11}\selectfont" "\caption{Recommendations: Assigned Preferences}" "\begin{tabular}{l*{3}{c}} \hline" 
local dv " & & & \textbf{Including} \\ $\ \ \ \ \ \ \ \ \ \ \ \ \ \ $    &\multicolumn{2}{c}{\textbf{Main Sample}} &\multicolumn{1}{c}{\textbf{ Inattentve}} \\\hline & & & \\"

esttab using  "${appendix}Deterministic_Recommendations.tex", ///
 se r2 replace nolines cells(b(star fmt(3)) se(par fmt(3))) ///
coeflabel(choicebefore "Prefer to See Incentive First" noconflict "No Conflict" ///
choicebefore_noconflict "Prefer to See Incentive First * No Conflict" ///
Deterministic "Deterministic" Deterministic_noconflict "Deterministic X No Conflict" choicebefore_Deterministic "Deterministic X Prefer to See Incentive First" Deterministic_choicebeforeNocon "Deterministic X Prefer to See Incentive First x No Conflict" ///
female "Female" age "Age" stdalpha "Selfishness"  ///
incentiveB "Incentive for B") ///
order (choicebefore noconflict choicebefore_noconflict Deterministic Deterministic_noconflict choicebefore_Deterministic Deterministic_choicebeforeNocon incentiveB female age stdalpha) ///
star(* 0.10 ** 0.05 *** 0.01)  collabels(none) ///
nomtitle label substitute(" 0.000 " " " " (.) " " ") ///
prehead("`panel'") posthead("`dv'") postfoot("\hline" "\end{tabular}%" "\captionsetup{width=1\textwidth}" "\caption*{\footnotesize Note: This table displays the estimated coefficients from linear probability models on the advisors' recommendations. Deterministic is a binary indicator coded as 1 for participants in the Deterministic treatment. Selfishness was elicited at the end of the experiment, using a multiple price list (MPL) with 5 decisions. The variable is a standardized measure of the number of times the advisor chose to recommend the incentivized product in the MPL task. The regression model in column (3) extends the analyses to included advisors who switched multiple times in the multiple price list eliciting selfishness. The regression includes individual controls for the advisor's gender and age. Robust standard errors (HC3) in parentheses}" "\label{tab:rec_deterministic}" "\end{table}")


***** Appendix, page 52: CLients
**we recruited $N=75$ clients and matched them with 1 out of 10 advisors for the main tas
*** of these 87\% followed the recommendation
preserve
u "${data}Clients_ChoiceDeterministic_Main.dta" 
tab follow
restore

*Advisors were also matched with $N=75$ additional advisees for the MPL task that measured moral costs; 
*of these 84\% followed the recommendation.
preserve
u "${data}Clients_ChoiceDeterministic_MPL.dta" 
tab follow
restore

********************************************************************************	
********************************************************************************	
* PREDICTIONS (APPENDIX)
********************************************************************************	
********************************************************************************


clear
u "${data}predictionsstudy.dta"
tabstat gap if attentivenum==1, s(mean n)	

preserve
u "${data}choice_experiments.dta"
*As pre-registered, drop Mturk participant with inconsistent alpha value
drop if study!=1 & alphavaluefinal==. /*(study1 are profs and there's no MPL')*/
***Check effect of seeing incentive first vs. quality first among those who prefer to see incentive first in the COSTLY version of Choice, AMT-1 wave (to be used in Prediction study)
tabstat recommendincentive if  choicebefore==1 & conflict==1 & wave=="AMT-1" & condition=="PayBefore" & alphavaluefinal!=., by(getbefore) 	stats(mean sd)	
di 0.0515133*sqrt(393)
di sqrt(0.4702^2+0.4084^2)
di (sqrt(0.4702^2+0.4084^2))/sqrt(393)
restore

g meanbeh=.7894737-.6759259
g sebeh=(sqrt(0.4702^2+0.4084^2))/sqrt(393)
g nbeh=393


g red=(gapred!=.)	
ttest gap, by(red)	

ttest gap=0

cdfplot gap, opt1(lcolor(ebblue)) xlabel(-0.75(.25)0.75) graphr(c(white)) ///
			xline(.1135478, lcolor(black)) xline(.0621875, lcolor(red)) ///
			xtitle("Forecasted Effect of Seeing Incentive First") ///
			text(0.95 -0.1 "Mean forecast" "(0.06)", color(red)) ///
			text(0.05 0.31 "Mean actual effect" "(0.11)", color(black))
		graph export "${appendix}/predictionscdf.png", replace

*mentioned in text
ttesti 393 .1135478 .622799 288 .0621875 .2213746

*mentioned in text
tab predictcorrect