30/replication_package/Dofiles/AppendixC_simulations.do

clear
set more off
set logtype text

********************************************************************************
* This file is the same as rd_simulations__02.do, but cleans up some variable 
* names and labels, only does the analysis for scenarios that eventually make it
* into Appendix version
********************************************************************************


cap log close
log using "$Log/AppendixC_simulations.log", replace


cap prog drop rd_sim
prog def rd_sim, rclass
	version 15.1
	syntax [, nobs(integer 10000) beta_a(real 1.0) beta_b(real 1.0) rho_x(real 0.7) /*

	*/        zbar_R(real 0.5) zbar_D(real -0.5) /*

	*/        alpha_R(real 0.5) alpha_D(real 0.5) /*

	*/        kappa_ksi_R(real 0.0) beta_ksi_R(real 10.0) kappa_ksi_D(real 0.0) beta_ksi_D(real 10.0) /*

	*/        phi0_R(real -1.0) phi1_R(real -1.0) phi0_D(real -1.0) phi1_D(real -1.0)   /*

	*/        kappa_u(real 0.0) beta_u(real 1.0)   /*

	*/        gamma0(real 0.0)  gamma1(real -5.0) gamma2(real 0.0) gamma3(real 0.0)/*

	*/        tau0(real 0.3) tau1(real -1.0)  tau2(real 0.0)]
	drop _all
	set obs `nobs'
	
	* Overall district ideology
    gen z = 2*(rbeta(`beta_a',`beta_b')-0.5)
	gen x = z + (sqrt((1-`rho_x'^2)/`rho_x'^2))*(2*(rbeta(`beta_a',`beta_b')-0.5))
	
	* Ideology of R and candidates: weighted average of national party and local ideology, plus noise	
	gen z_R = `alpha_R'*`zbar_R' + (1-`alpha_R')*z + `kappa_ksi_R'*(rbeta(`beta_ksi_R',`beta_ksi_R')-0.5)
	gen z_D = `alpha_D'*`zbar_D' + (1-`alpha_D')*z + `kappa_ksi_D'*(rbeta(`beta_ksi_D',`beta_ksi_D')-0.5)

	* Gender is correlated with candidate ideology
	gen byte female_D = rnormal(`phi0_D' + `phi1_D'*z_D)>0
	gen byte female_R = rnormal(`phi0_R' + `phi1_R'*z_R)>0
	
	* Voteshare depends on ideology of the candidates plus noise
	gen u = `kappa_u'*(rbeta(`beta_u', `beta_u')-0.5)
	gen voteshare_D = (exp(`gamma0' + `gamma1'*(z - (z_D+z_R)/2) + `gamma2'*female_D - `gamma3'*female_R + u)/    /*

	*/                (1+ exp(`gamma0' + `gamma1'*(z - (z_D+z_R)/2) + `gamma2'*female_D  - `gamma3'*female_R + u )))

	gen voteshare_female = voteshare_D  if female_D==1 & female_R==0
	replace voteshare_female = (1-voteshare_D) if female_D==0 & female_R==1
	
	* Outcome: depends on who is elected
	gen y = `tau0' + `tau1'*abs(z_D) + `tau2'*female_D + rnormal() if voteshare_D>=0.5
	replace y = `tau0' + `tau1'*abs(z_R) +`tau2'*female_R + rnormal() if voteshare_D<0.5
	
	* Now four types of RD analyses
    * (1) Density test
	rddensity voteshare_female, c(0.5)
	local denstest_pval_all = e(pv_q)

	rddensity voteshare_female if voteshare_D>=0.5, c(0.5)
	local denstest_pval_D = e(pv_q)
    
	rddensity voteshare_female if voteshare_D<0.5, c(0.5)
	local denstest_pval_R = e(pv_q)

	* (2) is ideology continuous at the threshold
	rdrobust z voteshare_female, c(0.5)  kernel(uniform)
	mat b = e(b)
	mat V = e(V)
	local b_ideology_all = b[1,1]
    local se_ideology_all = sqrt(V[1,1])
	
	rdrobust z voteshare_female if voteshare_D>=0.5, c(0.5)  kernel(uniform)
	mat b = e(b)
	mat V = e(V)
	local b_ideology_D = b[1,1]
    local se_ideology_D = sqrt(V[1,1])

	rdrobust z voteshare_female if voteshare_D<0.5, c(0.5)  kernel(uniform)
	mat b = e(b)
	mat V = e(V)
	local b_ideology_R = b[1,1]
    local se_ideology_R = sqrt(V[1,1])

	* (3) Estimate treatment effect with simple RD
	rdrobust y voteshare_female, c(0.5) kernel(uniform)
	mat b = e(b)
	mat V = e(V)
	local b_rd_all = b[1,1]
    local se_rd_all = sqrt(V[1,1])
	local band_all = e(h_l)
	
	rdrobust y voteshare_female if voteshare_D>=0.5, c(0.5)  kernel(uniform)
	mat b = e(b)
	mat V = e(V)
	local b_rd_D = b[1,1]
    local se_rd_D = sqrt(V[1,1])
	local band_D = e(h_l)
	
	rdrobust y voteshare_female if voteshare_D<0.5, c(0.5)  kernel(uniform)
	mat b = e(b)
	mat V = e(V)
	local b_rd_R = b[1,1]
    local se_rd_R = sqrt(V[1,1])
	local band_R = e(h_l)
	
	* (4-5) Estimate the treatment effect with weighted RD
	gen byte female = female_D if voteshare_D>=0.5
	replace female = female_R if voteshare_D<0.5
	gen voteshare_female_adj = voteshare_female-0.5
	
	* (4) using x
	probit female x if abs(voteshare_female_adj)<=`band_all'
	predict pscore if e(sample)==1
	gen wt =1/pscore if female==1
	replace wt = 1/(1-pscore) if female==0
    reg y female voteshare_female_adj i.female#c.voteshare_female_adj [aw=wt] if abs(voteshare_female_adj)<=`band_all'
    local b_rdwt_all = _b[female]
	local se_rdwt_all = _se[female]
    drop pscore wt

	probit female x if voteshare_D>=0.5 & abs(voteshare_female_adj)<=`band_D'
	predict pscore if e(sample)==1
	gen wt =1/pscore if female==1
	replace wt = 1/(1-pscore) if female==0
    reg y female voteshare_female_adj i.female#c.voteshare_female_adj [aw=wt] if voteshare_D>=0.5 & abs(voteshare_female_adj)<=`band_D'
    local b_rdwt_D = _b[female]
	local se_rdwt_D = _se[female]
    drop pscore wt
	
	probit female x if voteshare_D<0.5 & abs(voteshare_female_adj)<=`band_R'
	predict pscore if e(sample)==1
	gen wt =1/pscore if female==1
	replace wt = 1/(1-pscore) if female==0
    reg y female voteshare_female_adj i.female#c.voteshare_female_adj [aw=wt] if voteshare_D<0.5 & abs(voteshare_female_adj)<=`band_R'
    local b_rdwt_R = _b[female]
	local se_rdwt_R = _se[female]
    drop pscore wt
	
	
	
	* (5a) using ideology of the district
	probit female z if abs(voteshare_female_adj)<=`band_all'
	predict pscore if e(sample)==1
	gen wt =1/pscore if female==1
	replace wt = 1/(1-pscore) if female==0
    reg y female voteshare_female_adj i.female#c.voteshare_female_adj [aw=wt] if abs(voteshare_female_adj)<=`band_all'
    local b_rdwtideodistrict_all = _b[female]
	local se_rdwtideodistrict_all = _se[female]
    drop pscore wt

	probit female z if voteshare_D>=0.5 & abs(voteshare_female_adj)<=`band_D'
	predict pscore if e(sample)==1
	gen wt =1/pscore if female==1
	replace wt = 1/(1-pscore) if female==0
    reg y female voteshare_female_adj i.female#c.voteshare_female_adj [aw=wt] if voteshare_D>=0.5 & abs(voteshare_female_adj)<=`band_D'
    local b_rdwtideodistrict_D = _b[female]
	local se_rdwtideodistrict_D = _se[female]
    drop pscore wt
	
	probit female z if voteshare_D<0.5 & abs(voteshare_female_adj)<=`band_R'
	predict pscore if e(sample)==1
	gen wt =1/pscore if female==1
	replace wt = 1/(1-pscore) if female==0
    reg y female voteshare_female_adj i.female#c.voteshare_female_adj [aw=wt] if voteshare_D<0.5 & abs(voteshare_female_adj)<=`band_R'
    local b_rdwtideodistrict_R = _b[female]
	local se_rdwtideodistrict_R = _se[female]
    drop pscore wt

	* (5b) using ideology of the elected representative
	gen z_elected = z_D if voteshare_D>=0.5
	replace z_elected = z_R if voteshare_D<0.5
	
	probit female z_elected  if abs(voteshare_female_adj)<=`band_all'
	predict pscore if e(sample)==1
	gen wt =1/pscore if female==1
	replace wt = 1/(1-pscore) if female==0
    reg y female voteshare_female_adj i.female#c.voteshare_female_adj [aw=wt] if abs(voteshare_female_adj)<=`band_all'
    local b_rdwtideoelected_all = _b[female]
	local se_rdwtideoelected_all = _se[female]
    drop pscore wt

	probit female z_elected if voteshare_D>=0.5 & abs(voteshare_female_adj)<=`band_D'
	predict pscore if e(sample)==1
	gen wt =1/pscore if female==1
	replace wt = 1/(1-pscore) if female==0
    reg y female voteshare_female_adj i.female#c.voteshare_female_adj [aw=wt] if voteshare_D>=0.5 & abs(voteshare_female_adj)<=`band_D'
    local b_rdwtideoelected_D = _b[female]
	local se_rdwtideoelected_D = _se[female]
    drop pscore wt
	
	probit female z_elected if voteshare_D<0.5 & abs(voteshare_female_adj)<=`band_R'
	predict pscore if e(sample)==1
	gen wt =1/pscore if female==1
	replace wt = 1/(1-pscore) if female==0
    reg y female voteshare_female_adj i.female#c.voteshare_female_adj [aw=wt] if voteshare_D<0.5 & abs(voteshare_female_adj)<=`band_R'
    local b_rdwtideoelected_R = _b[female]
	local se_rdwtideoelected_R = _se[female]
    drop pscore wt
	
	* (6-7) Propensity score methods
	gen absMV = abs(voteshare_D-0.5)

	* (6a) pscore - x
	cap teffects ipw (y) (female x absMV, probit), pstolerance(1e-6) osample(osample)
	teffects ipw (y) (female x absMV, probit) if osample==0, pstolerance(1e-6)
	drop osample
	mat b = e(b)
	mat V = e(V)
	local b_pscorex_all = b[1,1]
	local se_pscorex_all = sqrt(V[1,1])

	cap teffects ipw (y) (female x absMV, probit) if voteshare_D>=0.5, pstolerance(1e-6) osample(osample)
	teffects ipw (y) (female x absMV, probit) if voteshare_D>=0.5 & osample==0, pstolerance(1e-6)
	drop osample
	mat b = e(b)
	mat V = e(V)
	local b_pscorex_D = b[1,1]
	local se_pscorex_D = sqrt(V[1,1])

	cap teffects ipw (y) (female x absMV, probit) if voteshare_D<0.5, pstolerance(1e-6) osample(osample)
	teffects ipw (y) (female x absMV, probit) if voteshare_D<0.5 & osample==0, pstolerance(1e-6)
	drop osample
	mat b = e(b)
	mat V = e(V)
	local b_pscorex_R = b[1,1]
	local se_pscorex_R = sqrt(V[1,1])


	* (7a) pscore - district ideology
	cap teffects ipw (y) (female z absMV, probit), pstolerance(1e-6) osample(osample)
	teffects ipw (y) (female z absMV, probit) if osample==0, pstolerance(1e-6)
	drop osample
	mat b = e(b)
	mat V = e(V)
	local b_pscoreideodistrict_all = b[1,1]
	local se_pscoreideodistrict_all = sqrt(V[1,1])

	cap teffects ipw (y) (female z absMV, probit) if voteshare_D>=0.5, pstolerance(1e-6) osample(osample)
	teffects ipw (y) (female z absMV, probit) if voteshare_D>=0.5 & osample==0, pstolerance(1e-6)
	drop osample
	mat b = e(b)
	mat V = e(V)
	local b_pscoreideodistrict_D = b[1,1]
	local se_pscoreideodistrict_D = sqrt(V[1,1])

	cap teffects ipw (y) (female z absMV, probit) if voteshare_D<0.5, pstolerance(1e-6) osample(osample)
	teffects ipw (y) (female z absMV, probit) if voteshare_D<0.5 & osample==0, pstolerance(1e-6)
	drop osample
	mat b = e(b)
	mat V = e(V)
	local b_pscoreideodistrict_R = b[1,1]
	local se_pscoreideodistrict_R = sqrt(V[1,1])

	
	* (7b) pscore - elected representative ideology
	cap teffects ipw (y) (female z_elected absMV, probit), pstolerance(1e-6) osample(osample)
	teffects ipw (y) (female z_elected absMV, probit) if osample==0, pstolerance(1e-6)
	drop osample
	mat b = e(b)
	mat V = e(V)
	local b_pscoreideoelected_all = b[1,1]
	local se_pscoreideoelected_all = sqrt(V[1,1])

	cap teffects ipw (y) (female z_elected absMV, probit) if voteshare_D>=0.5, pstolerance(1e-6) osample(osample)
	teffects ipw (y) (female z_elected absMV, probit) if voteshare_D>=0.5 & osample==0, pstolerance(1e-6)
	drop osample
	mat b = e(b)
	mat V = e(V)
	local b_pscoreideoelected_D = b[1,1]
	local se_pscoreideoelected_D = sqrt(V[1,1])

	cap teffects ipw (y) (female z_elected absMV, probit) if voteshare_D<0.5, pstolerance(1e-6) osample(osample)
	teffects ipw (y) (female z_elected absMV, probit) if voteshare_D<0.5 & osample==0, pstolerance(1e-6)
	drop osample
	mat b = e(b)
	mat V = e(V)
	local b_pscoreideoelected_R = b[1,1]
	local se_pscoreideoelected_R = sqrt(V[1,1])

		
	* (8) OLS
	reg y female 
	local b_ols_all =_b[female]
	local se_ols_all = _se[female]
	
	reg y female if voteshare_D>=0.5
	local b_ols_D = _b[female]
    local se_ols_D = _se[female]

	reg y female if voteshare_D<0.5
	local b_ols_R = _b[female]
    local se_ols_R = _se[female]

	* (9) Return 
	return scalar denstest_pval_all = `denstest_pval_all' 
	return scalar denstest_pval_D = `denstest_pval_D' 
	return scalar denstest_pval_R = `denstest_pval_R'
	
	return scalar b_ideology_all = `b_ideology_all'
	return scalar se_ideology_all = `se_ideology_all'
	return scalar b_ideology_D = `b_ideology_D'
	return scalar se_ideology_D = `se_ideology_D'
	return scalar b_ideology_R = `b_ideology_R'
	return scalar se_ideology_R = `se_ideology_R'
	
	return scalar b_rd_all = `b_rd_all'
	return scalar se_rd_all = `se_rd_all'
	return scalar b_rd_D = `b_rd_D'
	return scalar se_rd_D = `se_rd_D'
	return scalar b_rd_R = `b_rd_R'
	return scalar se_rd_R = `se_rd_R'

	return scalar b_rdwt_all = `b_rdwt_all'
	return scalar se_rdwt_all = `se_rdwt_all'
	return scalar b_rdwt_D = `b_rdwt_D'
	return scalar se_rdwt_D = `se_rdwt_D'
	return scalar b_rdwt_R = `b_rdwt_R'
	return scalar se_rdwt_R = `se_rdwt_R'
	
	return scalar b_rdwtideodistrict_all = `b_rdwtideodistrict_all'
	return scalar se_rdwtideodistrict_all = `se_rdwtideodistrict_all'
	return scalar b_rdwtideodistrict_D = `b_rdwtideodistrict_D'
	return scalar se_rdwtideodistrict_D = `se_rdwtideodistrict_D'
	return scalar b_rdwtideodistrict_R = `b_rdwtideodistrict_R'
	return scalar se_rdwtideodistrict_R = `se_rdwtideodistrict_R'
	
	return scalar b_rdwtideoelected_all = `b_rdwtideoelected_all'
	return scalar se_rdwtideoelected_all = `se_rdwtideoelected_all'
	return scalar b_rdwtideoelected_D = `b_rdwtideoelected_D'
	return scalar se_rdwtideoelected_D = `se_rdwtideoelected_D'
	return scalar b_rdwtideoelected_R = `b_rdwtideoelected_R'
	return scalar se_rdwtideoelected_R = `se_rdwtideoelected_R'

	return scalar b_pscorex_all = `b_pscorex_all'
	return scalar se_pscorex_all = `se_pscorex_all'
	return scalar b_pscorex_D = `b_pscorex_D'
	return scalar se_pscorex_D = `se_pscorex_D'
	return scalar b_pscorex_R = `b_pscorex_R'
	return scalar se_pscorex_R = `se_pscorex_R'
	
	return scalar b_pscoreideodistrict_all = `b_pscoreideodistrict_all'
	return scalar se_pscoreideodistrict_all = `se_pscoreideodistrict_all'
	return scalar b_pscoreideodistrict_D = `b_pscoreideodistrict_D'
	return scalar se_pscoreideodistrict_D = `se_pscoreideodistrict_D'
	return scalar b_pscoreideodistrict_R = `b_pscoreideodistrict_R'
	return scalar se_pscoreideodistrict_R = `se_pscoreideodistrict_R'

	return scalar b_pscoreideoelected_all = `b_pscoreideoelected_all'
	return scalar se_pscoreideoelected_all = `se_pscoreideoelected_all'
	return scalar b_pscoreideoelected_D = `b_pscoreideoelected_D'
	return scalar se_pscoreideoelected_D = `se_pscoreideoelected_D'
	return scalar b_pscoreideoelected_R = `b_pscoreideoelected_R'
	return scalar se_pscoreideoelected_R = `se_pscoreideoelected_R'

	return scalar b_ols_all = `b_ols_all'
	return scalar se_ols_all = `se_ols_all'
	return scalar b_ols_D = `b_ols_D'
	return scalar se_ols_D = `se_ols_D'
	return scalar b_ols_R = `b_ols_R'
	return scalar se_ols_R = `se_ols_R'
	
end


********************************************************************************
********************************************************************************
********************************************************************************

* Now actually run the simulations

set seed 1234567

* Run one simulation as a test
rd_sim, beta_a(5) beta_b(5) kappa_ksi_R(0.4) kappa_ksi_D(0.4) kappa_u(1) tau1(-5) rho_x(0.6) nobs(100000) /*

*/       gamma2(0.0) gamma3(0.6) phi1_D(-1) phi1_R(-1)




set seed 1234567

forvalues j = 1/4 {
	if `j'==1 {
		* BASELINE: Everything balanced
		local gamma2 = 0    // No preference for female D
		local gamma3 = 0	// No preference for female R
		local phi1_D = 0		// No relationship between gender and ideology
		local phi1_R = 0
		local DataDescr`j' = "Baseline - Everything Balanced"
	}
	else if `j'==2 {
		* Variant 1: Women are more left-wing, no preference for female candidates
		local gamma2 = 0    // No preference for female D
		local gamma3 = 0	// No preference for female R
		local phi1_D = -1		// No relationship between gender and ideology
		local phi1_R = -1
		local DataDescr`j' = "Variant 1 - Women are more left-wing, no preference for female candidates"
	}
	else if `j'==3 {
		* Variant 2: Women are more left-wing, equal preference for female candidates
		local gamma2 = 0.3    // No preference for female D
		local gamma3 = 0.3	// No preference for female R
		local phi1_D = -1		// No relationship between gender and ideology
		local phi1_R = -1
		local DataDescr`j' = "Variant 2 - Women are more left-wing, equal preference for female candidates"
	}

	else if `j'==4 {
		* Variant 3: Women are more left-wing, only D's prefer female candidates
		local gamma2 = 0.6    // No preference for female D
		local gamma3 = 0	// No preference for female R
		local phi1_D = -1		// No relationship between gender and ideology
		local phi1_R = -1
		local DataDescr`j' = "Variant 3 - Women are more left-wing, only Ds prefer female candidates"
	}
	
	simulate denstest_pval_all=r(denstest_pval_all) denstest_pval_D=r(denstest_pval_D) denstest_pval_R=r(denstest_pval_R) /*

	*/       b_ideology_all=r(b_ideology_all) se_ideology_all=r(se_ideology_all) /*

	*/       b_ideology_D=r(b_ideology_D) se_ideology_D=r(se_ideology_D)  /*

	*/       b_ideology_R=r(b_ideology_R) se_ideology_R=r(se_ideology_R)  /*

	*/       b_rd_all=r(b_rd_all) se_rd_all=r(se_rd_all) /*

	*/       b_rd_D=r(b_rd_D) se_rd_D=r(se_rd_D)  /*

	*/       b_rd_R=r(b_rd_R) se_rd_R=r(se_rd_R)  /*

	*/       b_rdwt_all=r(b_rdwt_all) se_rdwt_all=r(se_rdwt_all) /*

	*/       b_rdwt_D=r(b_rdwt_D) se_rdwt_D=r(se_rdwt_D)  /*

	*/       b_rdwt_R=r(b_rdwt_R) se_rdwt_R=r(se_rdwt_R)  /*

	*/       b_rdwtideodistrict_all=r(b_rdwtideodistrict_all) se_rdwtideodistrict_all=r(se_rdwtideodistrict_all)  /*

	*/       b_rdwtideodistrict_D=r(b_rdwtideodistrict_D) se_rdwtideodistrict_D=r(se_rdwtideodistrict_D)  /*

	*/       b_rdwtideodistrict_R=r(b_rdwtideodistrict_R) se_rdwtideodistrict_R=r(se_rdwtideodistrict_R)  /*

	*/       b_rdwtideoelected_all=r(b_rdwtideoelected_all) se_rdwtideoelected_all=r(se_rdwtideoelected_all)  /*

	*/       b_rdwtideoelected_D=r(b_rdwtideoelected_D) se_rdwtideoelected_D=r(se_rdwtideoelected_D)  /*

	*/       b_rdwtideoelected_R=r(b_rdwtideoelected_R) se_rdwtideoelected_R=r(se_rdwtideoelected_R)  /*

	*/       b_pscorex_all=r(b_pscorex_all) se_pscorex_all=r(se_pscorex_all)  /*

	*/       b_pscorex_D=r(b_pscorex_D) se_pscorex_D=r(se_pscorex_D)  /*

	*/       b_pscorex_R=r(b_pscorex_R) se_pscorex_R=r(se_pscorex_R)  /*

	*/       b_pscoreideodistrict_all=r(b_pscoreideodistrict_all) se_pscoreideodistrict_all=r(se_pscoreideodistrict_all)  /*

	*/       b_pscoreideodistrict_D=r(b_pscoreideodistrict_D) se_pscoreideodistrict_D=r(se_pscoreideodistrict_D)  /*

	*/       b_pscoreideodistrict_R=r(b_pscoreideodistrict_R) se_pscoreideodistrict_R=r(se_pscoreideodistrict_R)  /*

	*/       b_pscoreideoelected_all=r(b_pscoreideoelected_all) se_pscoreideoelected_all=r(se_pscoreideoelected_all)  /*

	*/       b_pscoreideoelected_D=r(b_pscoreideoelected_D) se_pscoreideoelected_D=r(se_pscoreideoelected_D)  /*

	*/       b_pscoreideoelected_R=r(b_pscoreideoelected_R) se_pscoreideoelected_R=r(se_pscoreideoelected_R)  /*

	*/       b_ols_all=r(b_ols_all) se_ols_all=r(se_ols_all)  /*

	*/       b_ols_D=r(b_ols_D) se_ols_D=r(se_ols_D)  /*

	*/       b_ols_R=r(b_ols_R) se_ols_R=r(se_ols_R)  /*

	*/       , reps(1000) saving("$AppendixC_simulations/rd_simulations`j'.dta", replace): /*

	*/         rd_sim, beta_a(5) beta_b(5) kappa_ksi_R(0.4) kappa_ksi_D(0.4) kappa_u(1) tau1(-5) rho_x(0.6) nobs(10000) /*

	*/                 gamma2(`gamma2') gamma3(`gamma3') phi1_D(`phi1_D') phi1_R(`phi1_R')

	gen gamma2 = `gamma2'
	gen gamma3 = `gamma3'
	gen phi1_D = `phi1_D'
	gen phi1_R = `phi1_R'
	label data "`DataDescr`j''"
	save "$AppendixC_simulations/rd_simulations`j'.dta", replace
	
	foreach type in "rd" "rdwt" "rdwtideodistrict" "rdwtideoelected" "pscorex" "pscoreideodistrict" "pscoreideoelected" "ols" {
		di ""
		di ""
		di in ye "type = `type'"
		foreach party in "all" "D" "R" {
			gen byte hit_`type'_`party' = b_`type'_`party' - 1.96*se_`type'_`party'<=0 & /*

			*/                            b_`type'_`party' + 1.96*se_`type'_`party'>=0
		}
		sum b_`type'_D se_`type'_D hit_`type'_D b_`type'_R se_`type'_R hit_`type'_R
	}
}



********************************************************************************
********************************************************************************
********************************************************************************

* From here on, display results
clear

foreach j of numlist 1 2 4 {
	if `j'<=2 {
		local jtex = `j'
	}
	else if `j'==4 {
		local jtex = `j'-1
	}
	use "$AppendixC_simulations/rd_simulations`j'.dta", clear
	foreach type in "ideology" "rd" "rdwt" "rdwtideodistrict" "rdwtideoelected" "pscorex" "pscoreideodistrict" "pscoreideoelected" "ols" {
		di ""
		di ""
		di in ye "type = `type'"
		foreach party in "all" "D" "R" {
			gen byte rejrate_`type'_`party' = b_`type'_`party' - 1.96*se_`type'_`party'>0 | /*

			*/                            b_`type'_`party' + 1.96*se_`type'_`party'<0
		}
	}
	foreach party in "all" "D" "R" {
		gen denstest_reject_`party' = denstest_pval_`party'<0.05
	}
	
	foreach esttype in "ideology" "rd" "rdwt" "rdwtideodistrict" "rdwtideoelected" "pscorex" "pscoreideodistrict" "pscoreideoelected" "ols"{
		ren b_`esttype'_all `esttype'1
		ren rejrate_`esttype'_all `esttype'2
		ren b_`esttype'_D `esttype'3
		ren rejrate_`esttype'_D `esttype'4
		ren b_`esttype'_R `esttype'5
		ren rejrate_`esttype'_R `esttype'6
	}

	ren denstest_pval_all denstest1
	ren denstest_reject_all denstest2
	ren denstest_pval_D denstest3
	ren denstest_reject_D denstest4
	ren denstest_pval_R denstest5
	ren denstest_reject_R denstest6
	
	gen iterno=_n
	drop se_*
	reshape long denstest ideology rd rdwt rdwtideodistrict rdwtideoelected pscorex pscoreideodistrict pscoreideoelected ols, i(iterno) j(stype)
	label def stype 1 "All - estimate" 2 "All - Rej.Rate" 3 "D - estimate" 4 "D - Rej.Rate" 5 "R - estimate" 6 "R - Rej.Rate"
	label value stype stype
	
	label var denstest "Density test (p-value)"
	label var ideology "Discontinuity in ideology"
	label var rd "RD - simple"
	label var rdwt "P-score weighted RD - x"
	label var rdwtideodistrict "P-score weighted RD - district ideology"
	label var rdwtideoelected "P-score weighted RD - ideology of elected representative"
	label var pscorex "P-score weighted, x"  
	label var pscoreideodistrict "P-score weighted, district ideology" 
	label var pscoreideoelected "P-score weighted, ideology of elected representative" 
	label var ols "OLS"

	estpost tabstat denstest ideology rd rdwt rdwtideodistrict rdwtideoelected /*

	*/              pscorex pscoreideodistrict pscoreideoelected ols, by(stype) column(statistics) nototal
	esttab using "$AppendixC_simulations/results_AppendixTableC`jtex'.tex", main(mean %6.3f) unstack tex replace noobs nomtitles nonumbers nonotes label	
}