Upload menu.bat

menu.bat

@@ -0,0 +1,51 @@
+@echo off
+setlocal
+rem cd /d %~dp0
+chcp 65001 > nul
+set target_dir=%~dp0
+set custom_n=%target_dir%ComfyUI\custom_nodes
+set py=%target_dir%python_embeded\
+set gi=%target_dir%git\bin\
+set PATH=%target_dir%git\bin;%target_dir%git\libexec;%py%Scripts;%py%Library\bin;%PATH%;
+
+call :ColorText "=============================================================" "Yellow"
+call :ColorText ".bat file install custom_nodes for ComfyUI by Skiffbox" "Green"
+call :ColorText "telegram @Skiffbox or https://t.me/Skiffbox" "blue"
+call :ColorText "=============================================================" "red"
+
+call :check_and_clone https://github.com/ltdrdata/ComfyUI-Manager ComfyUI-Manager
+call :check_and_clone https://github.com/crystian/ComfyUI-Crystools ComfyUI-Crystools
+call :check_and_clone https://github.com/11cafe/comfyui-workspace-manager comfyui-workspace-manager
+call :check_and_clone https://github.com/hayden-fr/ComfyUI-Model-Manager ComfyUI-Model-Manager
+call :check_and_clone https://github.com/talesofai/comfyui-browser comfyui-browser
+
+:end
+call :ColorText "=============================================================" "Yellow"
+call :ColorText "install custom_nodes for ComfyUI by Skiffbox .bat file" "Green"
+call :ColorText "telegram @Skiffbox or https://t.me/Skiffbox" "blue"
+call :ColorText "=============================================================" "red"
+call :ColorText "Завершение установки кастомных нод..." "magenta"
+rem del /f /q %target_dir%menu.bat
+endlocal
+pause
+exit /b
+
+:check_and_clone
+if exist %custom_n%\%2 ( 
+    call :ColorText "%2 уже установлено, пропуск..." "yellow"
+) else (
+    %gi%git clone %1 %custom_n%\%2
+    if exist %custom_n%\%2\requirements.txt (
+        %py%python -m pip install -r %custom_n%\%2\requirements.txt
+    )
+)
+exit /b
+
+:ColorText
+setlocal
+set text=%~1
+set color=%~2
+powershell -NoProfile -ExecutionPolicy Bypass -Command "Write-Host '%text%' -ForegroundColor %color%"
+endlocal
+exit /b
+