@echo off
rem onw AMD - Ore no NPU ga konna ni ugoku wake nai: run the server once from a console (Windows).
rem   start.bat                                   qwen3-it-4b-FLM (default)
rem   start.bat llama3.2-3b-FLM                   any model name from "onw list"
rem   start.bat MODEL --port 8080                 further options go to "onw serve"
rem First run: finds / installs Python, creates .venv, downloads FastFlowLM and the model.
rem For the resident tray app with a model manager use setup.bat instead.
setlocal
cd /d "%~dp0"
set PYTHONUTF8=1
set "MODEL=qwen3-it-4b-FLM"
set "FIRST=%~1"
if not "%FIRST%"=="" if not "%FIRST:~0,1%"=="-" (
    set "MODEL=%FIRST%"
    shift
)

if exist ".venv\installed.txt" goto args
if exist ".venv\Scripts\python.exe" goto install
call "%~dp0find_python.bat"
if not defined PY (
    pause
    exit /b 1
)
echo [setup] creating Python environment in .venv ...
%PY% -m venv .venv
if errorlevel 1 (
    echo [setup] could not create the Python environment.
    pause
    exit /b 1
)
:install
".venv\Scripts\python.exe" -m pip install -U pip
".venv\Scripts\python.exe" -m pip install -e .
if errorlevel 1 (
    echo [setup] package installation failed.
    pause
    exit /b 1
)
echo ok> ".venv\installed.txt"

:args
set "ARGS="
:collect
if "%~1"=="" goto run
set "ARGS=%ARGS% %1"
shift
goto collect
:run
echo [start] %MODEL% (first time: NPU engine + model download, please wait) ...
".venv\Scripts\onw.exe" serve %MODEL% --open %ARGS%
pause