scripts/experiments/run_analyzer_local.bat

@echo off
REM ============================================================
REM  PoolCoach Analyzer local (ban giao 24, 11/08/2026)
REM  MOT lenh keo du bo demo tab Analyzer:
REM    1) Redis      - docker compose (service redis)
REM    2) CV worker  - venv CUDA poolcoach-cv-env, CUA SO RIENG
REM                    (phuc vu ca scan lan analyze tu ban giao 24)
REM    3) Web app    - venv app, mode queue, cua so nay, port 8000
REM  Xong mo http://localhost:8000 -> tab Analyzer.
REM  JIT Numba ~40s lan dau (FE hien banner); worker load YOLO vai giay.
REM  Ctrl+C o day tat app; cua so worker dong bang Ctrl+C rieng
REM  (worker tu xoa heartbeat khi thoat sach).
REM ============================================================
set PYTHONUTF8=1
if "%REDIS_URL%"=="" set REDIS_URL=redis://localhost:6379/0

docker compose -f "D:\Khoa luan\poolcoach-rl\docker-compose.dev.yml" up -d redis
if errorlevel 1 (
  echo [LOI] Khong bat duoc Redis - Docker Desktop co dang chay khong?
  pause
  exit /b 1
)

start "poolcoach-cv-worker" cmd /k "D:\Khoa luan\run_cv_worker.bat"

call "D:\Khoa luan\poolcoach-env\Scripts\activate.bat"
cd /d "D:\Khoa luan\poolcoach-rl"
python -m uvicorn app.main:app --port 8000
pause