azdify

.devcontainer/Dockerfile

@@ -1,5 +1,8 @@
 # See here for image contents: https://github.com/microsoft/vscode-dev-containers/tree/v0.245.0/containers/python-3/.devcontainer/base.Dockerfile
 
 # [Choice] Python version (use -bullseye variants on local arm64/Apple Silicon): 3, 3.10, 3.9, 3.8, 3.7, 3.6, 3-bullseye, 3.10-bullseye, 3.9-bullseye, 3.8-bullseye, 3.7-bullseye, 3.6-bullseye, 3-buster, 3.10-buster, 3.9-buster, 3.8-buster, 3.7-buster, 3.6-buster
-ARG VARIANT="3.10-bullseye"
-FROM mcr.microsoft.com/vscode/devcontainers/python:0-${VARIANT}
+ARG VARIANT=bullseye
+FROM mcr.microsoft.com/vscode/devcontainers/base:0-${VARIANT}
+RUN curl -fsSL https://aka.ms/install-azd.sh | bash
+RUN apt update
+RUN apt-get install --yes libpq-dev

.devcontainer/devcontainer.json

@@ -6,11 +6,11 @@
 	"build": {
 		"dockerfile": "Dockerfile",
 		"context": "..",
-		"args": { 
+		"args": {
 			// Update 'VARIANT' to pick a Python version: 3, 3.10, 3.9, 3.8, 3.7, 3.6
 			// Append -bullseye or -buster to pin to an OS version.
 			// Use -bullseye variants on local on arm64/Apple Silicon.
-			"VARIANT": "3.10-bullseye"
+			"VARIANT": "bullseye"
 		}
 	},
 
@@ -19,7 +19,7 @@
 		// Configure properties specific to VS Code.
 		"vscode": {
 			// Set *default* container specific settings.json values on container create.
-			"settings": { 
+			"settings": {
 				"python.defaultInterpreterPath": "/usr/local/bin/python",
 				"python.linting.enabled": true,
 				"python.linting.pylintEnabled": true,
@@ -39,7 +39,7 @@
 				"python.testing.pytestEnabled": true,
 				"workbench.startupEditor": "newUntitledFile"
 			},
-			
+
 			// Add the IDs of extensions you want installed when the container is created.
 			"extensions": [
 				"ms-python.python",
@@ -48,12 +48,18 @@
 		}
 	},
 
-	// Use 'forwardPorts' to make a list of ports inside the container available locally.
-	// "forwardPorts": [],
-
 	// Use 'postCreateCommand' to run commands after the container is created.
-	"postCreateCommand": "pip install -r requirements-dev.txt && pre-commit install",
+	"postCreateCommand": "pip install -r requirements.txt",
 
 	// Comment out to connect as root instead. More info: https://aka.ms/vscode-remote/containers/non-root.
-	"remoteUser": "vscode"
-}
+	"remoteUser": "vscode",
+
+	"features": {
+        "ghcr.io/devcontainers/features/azure-cli:1": {
+            "version": "latest"
+        },
+        "ghcr.io/devcontainers/features/python:1": {
+            "version": "os-provided"
+        }
+    }
+}

azure.yaml

@@ -0,0 +1,9 @@
+# yaml-language-server: $schema=https://raw.githubusercontent.com/Azure/azure-dev/main/schemas/v1.0/azure.yaml.json
+
+name: flask-db-quiz-example
+
+services:
+  web:
+    project: .
+    language: py
+    host: appservice

infra/main.bicep

@@ -0,0 +1,37 @@
+targetScope = 'subscription'
+
+@minLength(1)
+@maxLength(64)
+@description('Name which is used to generate a short unique hash for each resource')
+param name string
+
+@minLength(1)
+@description('Primary location for all resources')
+param location string
+
+@secure()
+@description('PostGreSQL Server administrator password')
+param databasePassword string
+
+var resourceToken = toLower(uniqueString(subscription().id, name, location))
+var tags = { 'azd-env-name': name }
+
+resource resourceGroup 'Microsoft.Resources/resourceGroups@2021-04-01' = {
+  name: '${name}-rg'
+  location: location
+  tags: tags
+}
+
+module resources 'resources.bicep' = {
+  name: 'resources'
+  scope: resourceGroup
+  params: {
+    name: name
+    location: location
+    resourceToken: resourceToken
+    tags: tags
+    databasePassword: databasePassword
+  }
+}
+
+output AZURE_LOCATION string = location

infra/main.parameters.json

@@ -0,0 +1,15 @@
+{
+    "$schema": "https://schema.management.azure.com/schemas/2019-04-01/deploymentParameters.json#",
+    "contentVersion": "1.0.0.0",
+    "parameters": {
+      "name": {
+        "value": "${AZURE_ENV_NAME}"
+      },
+      "location": {
+        "value": "${AZURE_LOCATION}"
+      },
+      "databasePassword": {
+        "value": "$(secretOrRandomPassword ${AZURE_KEY_VAULT_NAME} databasePassword)"
+      }
+    }
+  }

infra/resources.bicep

@@ -0,0 +1,221 @@
+param name string
+param location string
+param resourceToken string
+@secure()
+param databasePassword string
+param tags object
+
+var prefix = '${name}-${resourceToken}'
+
+var pgServerName = '${prefix}-postgres-server'
+var databaseSubnetName = 'database-subnet'
+var webappSubnetName = 'webapp-subnet'
+
+resource virtualNetwork 'Microsoft.Network/virtualNetworks@2019-11-01' = {
+  name: '${prefix}-vnet'
+  location: location
+  tags: tags
+  properties: {
+    addressSpace: {
+      addressPrefixes: [
+        '10.0.0.0/16'
+      ]
+    }
+    subnets: [
+      {
+        name: databaseSubnetName
+        properties: {
+          addressPrefix: '10.0.0.0/24'
+          delegations: [
+            {
+              name: '${prefix}-subnet-delegation'
+              properties: {
+                serviceName: 'Microsoft.DBforPostgreSQL/flexibleServers'
+              }
+            }
+          ]
+        }
+      }
+      {
+        name: webappSubnetName
+        properties: {
+          addressPrefix: '10.0.1.0/24'
+          delegations: [
+            {
+              name: '${prefix}-subnet-delegation-web'
+              properties: {
+                serviceName: 'Microsoft.Web/serverFarms'
+              }
+            }
+          ]
+        }
+      }
+    ]
+  }
+  resource databaseSubnet 'subnets' existing = {
+    name: databaseSubnetName
+  }
+  resource webappSubnet 'subnets' existing = {
+    name: webappSubnetName
+  }
+}
+
+resource privateDnsZone 'Microsoft.Network/privateDnsZones@2020-06-01' = {
+  name: '${pgServerName}.private.postgres.database.azure.com'
+  location: 'global'
+  tags: tags
+  dependsOn: [
+    virtualNetwork
+  ]
+}
+
+resource privateDnsZoneLink 'Microsoft.Network/privateDnsZones/virtualNetworkLinks@2020-06-01' = {
+  parent: privateDnsZone
+  name: '${pgServerName}-link'
+  location: 'global'
+  properties: {
+    registrationEnabled: false
+    virtualNetwork: {
+      id: virtualNetwork.id
+    }
+  }
+}
+
+resource web 'Microsoft.Web/sites@2022-03-01' = {
+  name: '${prefix}-app-service'
+  location: location
+  tags: union(tags, { 'azd-service-name': 'web' })
+  kind: 'app,linux'
+  properties: {
+    serverFarmId: appServicePlan.id
+    siteConfig: {
+      alwaysOn: true
+      linuxFxVersion: 'PYTHON|3.10'
+      ftpsState: 'Disabled'
+    }
+    httpsOnly: true
+  }
+  identity: {
+    type: 'SystemAssigned'
+  }
+
+  resource appSettings 'config' = {
+    name: 'appsettings'
+    properties: {
+      DBHOST: postgresServer.name
+      DBNAME: djangoDatabase.name
+      DBUSER: postgresServer.properties.administratorLogin
+      DBPASS: databasePassword
+      SCM_DO_BUILD_DURING_DEPLOYMENT: 'true'
+    }
+  }
+
+  resource logs 'config' = {
+    name: 'logs'
+    properties: {
+      applicationLogs: {
+        fileSystem: {
+          level: 'Verbose'
+        }
+      }
+      detailedErrorMessages: {
+        enabled: true
+      }
+      failedRequestsTracing: {
+        enabled: true
+      }
+      httpLogs: {
+        fileSystem: {
+          enabled: true
+          retentionInDays: 1
+          retentionInMb: 35
+        }
+      }
+    }
+  }
+
+  resource webappVnetConfig 'networkConfig' = {
+    name: 'virtualNetwork'
+    properties: {
+      subnetResourceId: virtualNetwork::webappSubnet.id
+    }
+  }
+
+  dependsOn: [virtualNetwork]
+
+}
+
+resource appServicePlan 'Microsoft.Web/serverfarms@2021-03-01' = {
+  name: '${prefix}-service-plan'
+  location: location
+  tags: tags
+  sku: {
+    name: 'B1'
+  }
+  properties: {
+    reserved: true
+  }
+}
+
+resource logAnalyticsWorkspace 'Microsoft.OperationalInsights/workspaces@2020-03-01-preview' = {
+  name: '${prefix}-workspace'
+  location: location
+  tags: tags
+  properties: any({
+    retentionInDays: 30
+    features: {
+      searchVersion: 1
+    }
+    sku: {
+      name: 'PerGB2018'
+    }
+  })
+}
+
+resource postgresServer 'Microsoft.DBforPostgreSQL/flexibleServers@2022-01-20-preview' = {
+  location: location
+  tags: tags
+  name: pgServerName
+  sku: {
+    name: 'Standard_D2ds_v4'
+    tier: 'GeneralPurpose'
+  }
+  properties: {
+    version: '13'
+    administratorLogin: 'django'
+    administratorLoginPassword: databasePassword
+    availabilityZone: '1'
+    storage: {
+      storageSizeGB: 128
+    }
+    backup: {
+      backupRetentionDays: 7
+      geoRedundantBackup: 'Disabled'
+    }
+    network: {
+      delegatedSubnetResourceId: virtualNetwork::databaseSubnet.id
+      privateDnsZoneArmResourceId: privateDnsZone.id
+    }
+    highAvailability: {
+      mode: 'Disabled'
+    }
+    maintenanceWindow: {
+      customWindow: 'Disabled'
+      dayOfWeek: 0
+      startHour: 0
+      startMinute: 0
+    }
+  }
+
+  dependsOn: [
+    privateDnsZoneLink
+  ]
+}
+
+
+resource djangoDatabase 'Microsoft.DBforPostgreSQL/flexibleServers/databases@2022-01-20-preview' = {
+  parent: postgresServer
+  name: 'django'
+}
+
+output WEB_URI string = 'https://${web.properties.defaultHostName}'