materials/vMaterials_2/Paint/Carpaint/Effect_Pigment_Metallic.mdl

/******************************************************************************
 *     Copyright 2024 NVIDIA Corporation. All rights reserved.
 ******************************************************************************
 
Permission is hereby granted by NVIDIA Corporation ("NVIDIA"), free of charge,
to any person obtaining a copy of the sample definition code that uses our 
Material Definition Language (the "MDL Materials"), to reproduce and distribute
the MDL Materials, including without limitation the rights to use, copy, merge,
publish, distribute, and sell modified and unmodified copies of the MDL 
Materials, and to permit persons to whom the MDL Materials is furnished to do
so, in all cases solely for use with NVIDIA's Material Definition Language,
subject to the following further conditions:

1. The above copyright notices, this list of conditions, and the disclaimer
that follows shall be retained in all copies of one or more of the MDL
Materials, including in any software with which the MDL Materials are bundled,
redistributed, and/or sold, and included either as stand-alone text files,
human-readable headers or in the appropriate machine-readable metadata fields
within text or binary files as long as those fields can be easily viewed by the
user, as applicable.
2. The name of NVIDIA shall not be used to promote, endorse or advertise any 
Modified Version without specific prior written permission, except a) to comply
 with the notice requirements otherwise contained herein; or b) to acknowledge
the contribution(s) of NVIDIA.

THE MDL MATERIALS ARE PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
OR IMPLIED, INCLUDING BUT NOT LIMITED TO ANY WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT OF COPYRIGHT, PATENT,
TRADEMARK, OR OTHER RIGHT. IN NO EVENT SHALL NVIDIA CORPORATION BE LIABLE FOR 
ANY CLAIM, DAMAGES OR OTHER LIABILITY, INCLUDING ANY GENERAL, SPECIAL, 
INDIRECT, INCIDENTAL, OR CONSEQUENTIAL DAMAGES, WHETHER IN AN ACTION OF 
CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF THE USE OR INABILITY TO USE
THE MDL MATERIALS OR FROM OTHER DEALINGS IN THE MDL MATERIALS.
*/

mdl 1.4;

import ::state::*;
import ::tex::*;
import ::df::*;
import ::anno::*;
import ::base::*;
import ::math::*;
import ::nvidia::core_definitions::dimension;


const string COPYRIGHT = 
" Copyright 2024 NVIDIA Corporation. All rights reserved.\n"
" MDL MATERIALS ARE PROVIDED PURSUANT TO AN END USER LICENSE  AGREEMENT,\n"
" WHICH WAS ACCEPTED IN ORDER TO GAIN ACCESS TO THIS FILE.  IN PARTICULAR,\n" 
" THE MDL MATERIALS ARE PROVIDED \"AS IS\", WITHOUT WARRANTY OF ANY KIND,\n"
" EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO ANY WARRANTIES OF\n"
" MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT OF\n" 
" COPYRIGHT, PATENT, TRADEMARK, OR OTHER RIGHT. IN NO EVENT SHALL NVIDIA\n"
" CORPORATION BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, INCLUDING ANY\n"
" GENERAL, SPECIAL,  INDIRECT, INCIDENTAL, OR CONSEQUENTIAL DAMAGES, WHETHER IN\n"
" AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF THE USE OR\n"
" INABILITY TO USE THE MDL MATERIALS OR FROM OTHER DEALINGS IN THE MDL MATERIALS.\n";

float remap_exponential_range(float input, float steepness = 10.0f)
{
	return - 1.f / ((input-1.0)*steepness + 0.000001) * input * input;
}

// Flake sizes of a metallic paint vendor
// https://www.onallcylinders.com/2015/02/23/monday-mailbag-tips-spraying-metal-flake-paint/

// Monster	.025 Inch  (0.635 mm)
// Standard .015 Inch  (0.381 mm) 
// Lil'	    .008 Inch  (0.2032mm)  
// Baby		.004 Inch  (0.1016 mm)	 
// Trippin'	.015-.008 Inch	



// This is basically the same material as above. However, i chose a different
// method to expose the transparency / coverage of the flakes that might be more
// intuitive to use
// chameleon_pigment_paint_V2()
export material Effect_Pigment_Metallic(
// Base color
// Base color does base color falloff
	color base_color = color(0.04f, 0.073828f , 0.219520f)
	[[
		::anno::display_name("Base Color"),
		::anno::description("The base color, underneath the flakes."),
		::anno::in_group("Base Layer")
	]],
// Flakes (with 5 Colors)
//
//
	uniform float flakes_coverage = 1.0f
	[[
		::anno::display_name("Flakes Coverage"),
		::anno::description("When this value is decreased, flakes will be rendered smaller, revealing the base ."
		" layer underneath."),
		::anno::hard_range(0.0f, 1.0f),
		::anno::in_group("Flakes Layer")
	]],
	uniform float flakes_scale = 0.015f
	[[
		::anno::display_name("Flakes Scale"),
		::anno::description("A logarithmic slider, setting the scale of the metallic flakes."),
		::anno::hard_range(0.0f, 1.0f),
		::anno::in_group("Flakes Layer")
	]],
	uniform float3 texture_scale = float3(1.0f)
	[[
		::anno::hidden(),
		::anno::display_name("Scale"),
		::anno::description("An additional linear controller for controlling the size of the flaes."),
		::anno::in_group("Flakes Layer"),
		::nvidia::core_definitions::dimension(float3(1.0f, 1.0f, 1.0f))
		
	]],
	
	uniform float flakes_orientation_random = 0.5f
	[[
		::anno::display_name("Flakes Random Orientation"),
		::anno::description("The higher the value, the more randomly oriented the flakes will appear, creating "
		"a stronger scinillation effect."),
		::anno::hard_range(0.0f, 1.0f),
		::anno::in_group("Flakes Layer")
	]],
	float flakes_roughness = 0.15f
	[[
		::anno::display_name("Flakes Roughness"),
		::anno::description("The roughness of the metallic flakes."),
		::anno::hard_range(0.0f, 1.0f),
		::anno::in_group("Flakes Layer")
	]],
	uniform float flakes_transparency = 0.0f
	[[
		::anno::display_name("Flakes Transparency"),
		::anno::description("Sets an overall transparency value for the metallic flakes."),
		::anno::in_group("Flakes Layer")
	]],

// Clearcoat (orange peel)
//
	float clearcoat_roughness = 0.0f
	[[
		::anno::display_name("Clearcoat Roughness"),
		::anno::description("The roughness of the clearcoat layer."),
		::anno::hard_range(0.f, 1.f),
		::anno::in_group("Clearcoat Layer")
	]],
	uniform float orange_peel_amount = 0.025f
	[[
		::anno::display_name("Orange Peel Amount"),
		::anno::description("The strength of the orange peel effect on the clearcoat."),
		//::anno::hard_range(0.f, 1.f),
		::anno::in_group("Clearcoat Layer")
	]],
	uniform float orange_peel_scale = 0.08f
	[[
		::anno::display_name("Orange Peel Scale"),
		::anno::description("Scales the size of the orange peel effect."),
		::anno::in_group("Clearcoat Layer")
	]],
	float clearcoat_ior = 1.45f
	[[
		::anno::display_name("Clearcoat IOR"),
		::anno::description("The index of refraction of the clearcoat of tzhe carpaint."),
		::anno::in_group("Clearcoat Layer")
	]],
	
	
	// Flakes colorshift colors
	color flakes_paint_color_1 =  color(0.0720070004f, 0.738844991f, 0.738844991f) //color(0.297f, 0.66f, 0.875f)
	[[
		::anno::display_name("Paint Color 1"),
		::anno::description("First Color of the effect paint."),
		::anno::in_group("Flakes Gradient Colors")
	]],
	color flakes_paint_color_2 = color(0.127330005f, 0.106539004f, 1.f) //color(0.392f, 0.36f, 1.f)
	[[
		::anno::display_name("Paint Color 2"),
		::anno::description("Second color of the effect paint."),
		::anno::in_group("Flakes Gradient Colors")
	]],
	color flakes_paint_color_3 = color(0.522521973f, 0.0414360017f, 0.368261993f) //color(0.75f, 0.225f, 0.64f)
	[[
		::anno::display_name("Paint Color 3"),
		::anno::description("Third color of the effect paint."),
		::anno::in_group("Flakes Gradient Colors")
	]],
	color flakes_paint_color_4 = color(0.522521973f, 0.221992999f, 0.f) //color(0.750f, 0.508f, 0.0f)
	[[
		::anno::display_name("Paint Color 4"),
		::anno::description("Fourth Color of the effect paint."),
		::anno::in_group("Flakes Gradient Colors")
	]],
	color flakes_paint_color_5 = color(0.266786009f, 0.522521973f, 0.0441490002f) //color(0.553f, 0.75f, 0.232f)
	[[
		::anno::display_name("Paint Color 5"),
		::anno::description("Fifth color of the effect paint."),
		::anno::in_group("Flakes Gradient Colors")
	]]
)
[[
    ::anno::display_name("Effect Pigment Paint - Purple Blue"),
    ::anno::description("A clearcoated metallic effect pigment paint with an orange peel effect."),
    ::anno::author("NVIDIA Corporation"),
	::anno::created(2020, 3, 17, ""),
    ::anno::key_words(string[]("design", "paint", "metallic", "flipflop", "carpaint", "automotive", "peel", "orange peel", "flake", "flakes", "multicolor", "clearcoat", "coated", "new", "purple", "blue")),
	::anno::thumbnail("./.thumbs/Effect_Pigment_Metallic.Effect_Pigment_Metallic.png"),
    ::anno::copyright_notice(COPYRIGHT)
]] = let {
	// Parameter remapping
	float flake_scale_remapped = remap_exponential_range(flakes_scale, 10.f);
	float orange_peel_scale_remapped = remap_exponential_range(orange_peel_scale, 10.f);
	float flakes_orientation_random_remapped = flakes_orientation_random * 2.5f;
	float flakes_roughness_remapped = flakes_roughness * 0.5f;
	// remapping necessary to give parameter a linear feel when tweaking it
	float flakes_coverage_remapped = ::math::pow(flakes_coverage, .5f); 
	float flakes_transparency_inv = 1.0 - flakes_transparency;
	
	
	// get object coordinates
	::base::texture_coordinate_info uvw = ::base::coordinate_source(
											coordinate_system: ::base:: texture_coordinate_object
	);
	
	::base::texture_coordinate_info transformed_uvw = 
								::base::transform_coordinate(
									transform: ::base::rotation_translation_scale(
												rotation: float3(0.0f),
												translation: float3(0.0f),
												scaling: texture_scale
									),
									coordinate: uvw
	);
									
	
	
	::base::texture_return flakes = ::base::flake_noise_texture(
		uvw: transformed_uvw,
		scale: flake_scale_remapped,
		intensity: 1.f,
		density: flakes_transparency_inv, 
		noise_type: 1, //worley
		maximum_size: flakes_coverage_remapped
	);
	
	float3 flakes_norm = ::base::flake_noise_bump_texture(
		uvw: transformed_uvw,
		scale: flake_scale_remapped,
		strength: flakes_orientation_random_remapped,
		noise_type: 1,
		maximum_size: flakes_coverage_remapped
	);
	
	// Layer the flakes on base layer, tint them with the colors
	bsdf flakes_bsdf = ::df::microfacet_ggx_smith_bsdf(
		roughness_u: flakes_roughness_remapped * flakes_roughness_remapped,
		tint: color(1.0f)
	);
	
	bsdf chameleon_flakes = ::df::measured_curve_factor(
		curve_values: color[](flakes_paint_color_1, flakes_paint_color_1, flakes_paint_color_2, flakes_paint_color_3, flakes_paint_color_4, flakes_paint_color_5),
		base: flakes_bsdf
		
	);
	
	bsdf base_layer_bsdf = ::df::diffuse_reflection_bsdf(
		tint: base_color
	);
	
	float flakes_weight = (flakes.mono <= 0.0001f) ? 0.0f :
						((flakes_transparency_inv < 0.5) ? 0.f :
							(flakes_transparency_inv - 0.5f) * 2.0f);
							
	// float flakes_weight = (flakes_transparency_inv < 0.5) ? 0.f :
							// (flakes_transparency_inv - 0.5f) * 2.0f;
							
	bsdf base_n_flakes_bsdf = ::df::weighted_layer(
		// flakes_transparency 
		weight: ::math::lerp(flakes.mono, 1.0, flakes_weight),
		layer: chameleon_flakes,
		base: base_layer_bsdf,
		normal: flakes_norm
	);
	
	// Clearcoat
	
	// Orange Peel bump
	float3 orange_peel_normal = ::base::perlin_noise_bump_texture(
		uvw: transformed_uvw,
		factor: orange_peel_amount,
		size: orange_peel_scale_remapped,
		noise_levels: 2
	);
	
	bsdf clearcoat_bsdf = ::df::microfacet_ggx_smith_bsdf(
		roughness_u: clearcoat_roughness,
		tint: color(1.0f),
		mode: ::df::scatter_reflect
	);
	
	bsdf final_bsdf = ::df::fresnel_layer(
		ior: clearcoat_ior,
		layer: clearcoat_bsdf,
		base: base_n_flakes_bsdf,
		normal: orange_peel_normal
	);
	
} 
in material(
	surface: material_surface(
		scattering: final_bsdf
	)
);


// Chameleon Paint effect presets
export material Chameleon_Pigment_Desert_Fire(*) 
[[
    ::anno::display_name("Effect Pigment Paint - Desert Fire"),
    ::anno::description("A clearcoated metallic effect pigment paint with an orange peel effect."),
    ::anno::author("NVIDIA Corporation"),
	::anno::created(2020, 3, 17, ""),
    ::anno::key_words(string[]("design", "paint", "metallic", "flipflop", "carpaint", "automotive", "peel", "orange peel", "flake", "flakes", "multicolor", "clearcoat", "coated", "new", "orange", "warm")),
	::anno::thumbnail("./.thumbs/Effect_Pigment_Metallic.Chameleon_Pigment_Desert_Fire.png"),
    ::anno::copyright_notice(COPYRIGHT)
]]
 = Effect_Pigment_Metallic(
	base_color: 			color(0.348865,	0.082414,	0.028991),
	flakes_coverage: 		1.0f,
	flakes_scale:			0.02f,
	flakes_orientation_random: 0.5f,
	flakes_roughness:		0.15f,
	flakes_transparency: 	0.3f,
	clearcoat_roughness: 	0.0f,
	orange_peel_amount:		0.025f,
	orange_peel_scale:		0.08f,
	clearcoat_ior: 			1.45f,
	flakes_paint_color_1: color(0.737205f,	0.517401f,	0.069727f),
	flakes_paint_color_2: color(1.000000f,	0.459080f,	0.106156f),
	flakes_paint_color_3: color(0.529523f,	0.080219f,	0.037029f),
	flakes_paint_color_4: color(0.529523f,	0.010398f,	0.010398f),
	flakes_paint_color_5: color(0.529523f,	0.039947f,	0.039947f)	
);

export material Chameleon_Pigment_Goblin_Fire(*)
[[
    ::anno::display_name("Effect Pigment Paint - Goblin Fire"),
    ::anno::description("A clearcoated metallic effect pigment paint with an orange peel effect."),
    ::anno::author("NVIDIA Corporation"),
	::anno::created(2020, 3, 17, ""),
    ::anno::key_words(string[]("design", "paint", "metallic", "flipflop", "carpaint", "automotive", "peel", "orange peel", "flake", "flakes", "multicolor", "clearcoat", "coated", "new", "red", "green")),
	::anno::thumbnail("./.thumbs/Effect_Pigment_Metallic.Chameleon_Pigment_Goblin_Fire.png"),
    ::anno::copyright_notice(COPYRIGHT)
]]
 = Effect_Pigment_Metallic(
	base_color: 			color(0.431340f, 0.311180f,	0.042987f),
	flakes_coverage: 		1.0f,
	flakes_scale:			0.02f,
	flakes_orientation_random: 0.5f,
	flakes_roughness: 		0.15f,
	flakes_transparency: 	0.05f,
	clearcoat_roughness:	0.0f,
	orange_peel_amount:		0.025f,
	orange_peel_scale:		0.08f,
	clearcoat_ior: 			1.45f,
	flakes_paint_color_1: color(0.737205f,	0.027755f,	0.027755f),
	flakes_paint_color_2: color(1.000000f,	0.242796f,	0.054592f),
	flakes_paint_color_3: color(0.219520f,	0.529523f,	0.037029f),
	flakes_paint_color_4: color(0.010398f,	0.529523f,	0.041452f),
	flakes_paint_color_5: color(0.035614f,	0.201096f,	0.015175f)	
);


export material Chameleon_Pigment_Borealis(*)
[[
    ::anno::display_name("Effect Pigment Paint - Borealis"),
    ::anno::description("A clearcoated metallic effect pigment paint with an orange peel effect."),
    ::anno::author("NVIDIA Corporation"),
	::anno::created(2020, 3, 17, ""),
    ::anno::key_words(string[]("design", "paint", "metallic", "flipflop", "carpaint", "automotive", "peel", "orange peel", "flake", "flakes", "multicolor", "clearcoat", "coated", "new", "blue", "cool")),
	::anno::thumbnail("./.thumbs/Effect_Pigment_Metallic.Chameleon_Pigment_Borealis.png"),
    ::anno::copyright_notice(COPYRIGHT)
]]
 = Effect_Pigment_Metallic(
	base_color: 			color(0.069727f,	0.047776f, 	0.415148),
	flakes_coverage: 		1.0f,
	flakes_scale:			0.02f,
	flakes_orientation_random: 0.60f,
	flakes_roughness: 		0.301f,
	flakes_transparency: 	0.111f,
	clearcoat_roughness: 	0.0f,
	orange_peel_amount: 	0.025f,
	orange_peel_scale: 		0.08f,
	clearcoat_ior: 			1.45f,
	flakes_paint_color_1: color(0.267358f,	0.612066f,	0.547994f),
	flakes_paint_color_2: color(0.127530f,	0.659224f,	0.378676f),
	flakes_paint_color_3: color(0.006585f,	0.163641f,	0.399293f),
	flakes_paint_color_4: color(0.011126f,	0.013473f,	0.535642f),
	flakes_paint_color_5: color(0.056374f,	0.015175f,	0.201096f)	
);


export material Chameleon_Pigment_Candytron(*) 
[[
    ::anno::display_name("Effect Pigment Paint - Candytron"),
    ::anno::description("A clearcoated metallic effect pigment paint with an orange peel effect."),
    ::anno::author("NVIDIA Corporation"),
	::anno::created(2020, 3, 17, ""),
    ::anno::key_words(string[]("design", "paint", "metallic", "flipflop", "carpaint", "automotive", "peel", "orange peel", "flake", "flakes", "multicolor", "clearcoat", "coated", "new", "orange", "pink", "warm")),
	::anno::thumbnail("./.thumbs/Effect_Pigment_Metallic.Chameleon_Pigment_Candytron.png"),
    ::anno::copyright_notice(COPYRIGHT)
]]
 = Effect_Pigment_Metallic(
	base_color: 			color(0.645555f, 0.183549f, 0.042987f),
	flakes_coverage: 		1.0f,
	flakes_scale:			0.02f,
	flakes_orientation_random: 0.39f,
	flakes_roughness: 		0.286f,
	flakes_transparency: 	0.03f,
	clearcoat_roughness: 	0.0f,
	orange_peel_amount: 	0.025f,
	orange_peel_scale:		0.08f,
	clearcoat_ior: 			1.45f,
	flakes_paint_color_1: color(0.481952f,	0.025371f,	0.612066f),
	flakes_paint_color_2: color(0.781751f,	0.259027f,	0.007155f),
	flakes_paint_color_3: color(0.694081f,	0.208360f,	0.011881f),
	flakes_paint_color_4: color(0.554227f,	0.566810f,	0.020951f),
	flakes_paint_color_5: color(0.899385f,	0.907547f,	0.052842f)	
);


export material Chameleon_Pigment_Deep_Purple(*)
[[
    ::anno::display_name("Effect Pigment Paint - Deep Purple"),
    ::anno::description("A clearcoated metallic effect pigment paint with an orange peel effect."),
    ::anno::author("NVIDIA Corporation"),
	::anno::created(2020, 3, 17, ""),
    ::anno::key_words(string[]("design", "paint", "metallic", "flipflop", "carpaint", "automotive", "peel", "orange peel", "flake", "flakes", "multicolor", "clearcoat", "coated", "new", "purple")),
	::anno::thumbnail("./.thumbs/Effect_Pigment_Metallic.Chameleon_Pigment_Deep_Purple.png"),
    ::anno::copyright_notice(COPYRIGHT)
]]
 = Effect_Pigment_Metallic(
	base_color: 			color(0.415148f, 0.047776f, 0.378676f),
	flakes_coverage: 		1.0f,
	flakes_scale:			0.02f,
	flakes_orientation_random: 0.39f,
	flakes_roughness: 		0.286f,
	flakes_transparency:	0.06f,
	clearcoat_roughness: 	0.0f,
	orange_peel_amount:		0.025f,
	clearcoat_ior:			1.45f,
	orange_peel_scale:		0.08f,
	flakes_paint_color_1: color(0.612066f,	0.054592f,	0.329729f),
	flakes_paint_color_2: color(0.523443f,	0.127530f,	0.659224f),
	flakes_paint_color_3: color(0.073828f,	0.006585f,	0.399293f),
	flakes_paint_color_4: color(0.011126f,	0.013473f,	0.535642f),
	flakes_paint_color_5: color(0.022013f,	0.015175f,	0.201096f)	
);

export material Chameleon_Pigment_Scarabeus(*)
[[
    ::anno::display_name("Effect Pigment Paint - Scarabeus"),
    ::anno::description("A clearcoated metallic effect pigment paint with an orange peel effect."),
    ::anno::author("NVIDIA Corporation"),
	::anno::created(2020, 3, 17, ""),
    ::anno::key_words(string[]("design", "paint", "metallic", "flipflop", "carpaint", "automotive", "peel", "orange peel", "flake", "flakes", "multicolor", "clearcoat", "coated", "new", "green")),
	::anno::thumbnail("./.thumbs/Effect_Pigment_Metallic.Chameleon_Pigment_Scarabeus.png"),
    ::anno::copyright_notice(COPYRIGHT)
]]
 = Effect_Pigment_Metallic(
	base_color: color(0.378676f, 0.250840f, 0.047776f),
	flakes_coverage:		1.0f,
	flakes_scale:			0.02f,
	flakes_orientation_random: 0.367f,
	flakes_roughness:		0.535f,
	flakes_transparency:	0.06f,
	clearcoat_roughness:	0.0f,
	orange_peel_amount:		0.025f,
	orange_peel_scale:		0.08f,
	clearcoat_ior:			1.45f,
	flakes_paint_color_1:	color(0.238828f,	0.638779f,	0.004116f),
	flakes_paint_color_2:	color(0.003697f,	0.409826f,	0.003697f),
	flakes_paint_color_3:	color(0.012664f,	0.353741f,	0.223310f),
	flakes_paint_color_4:	color(0.006041f,	0.173439f,	0.130352f),
	flakes_paint_color_5:	color(0.003697f,	0.024223f,	0.190463f)	
);


export material Chameleon_Pigment_Golden_Lavender(*)
[[
    ::anno::display_name("Effect Pigment Paint - Golden Lavender"),
    ::anno::description("A clearcoated metallic effect pigment paint with an orange peel effect."),
    ::anno::author("NVIDIA Corporation"),
	::anno::created(2020, 3, 17, ""),
    ::anno::key_words(string[]("design", "paint", "metallic", "flipflop", "carpaint", "automotive", "peel", "orange peel", "flake", "flakes", "multicolor", "clearcoat", "coated", "new", "gold", "lavender")),
	::anno::thumbnail("./.thumbs/Effect_Pigment_Metallic.Chameleon_Pigment_Golden_Lavender.png"),
    ::anno::copyright_notice(COPYRIGHT)
]]
 = Effect_Pigment_Metallic(
	base_color: 			color(0.136099f, 0.026549f, 0.673049f),
	flakes_coverage: 		1.0f,
	flakes_scale:			0.02f,
	flakes_orientation_random: 0.306f,
	flakes_roughness:		0.317f,
	flakes_transparency:	0.093f,
	clearcoat_roughness:	0.0f,
	orange_peel_amount:		0.025f,
	orange_peel_scale:		0.08f,
	clearcoat_ior:			1.45f,
	flakes_paint_color_1:	color(0.638779f,	0.638779f,	0.638779f),
	flakes_paint_color_2:	color(0.573159f,	0.373615f,	0.201096f),
	flakes_paint_color_3:	color(0.511398f,	0.288816f,	0.019918f),
	flakes_paint_color_4:	color(0.344026f,	0.160444f,	0.006041f),
	flakes_paint_color_5:	color(0.388910f,	0.060032f,	0.011126f)	
);


export material Chameleon_Pigment_Pink_Slip(*) 
[[
    ::anno::display_name("Effect Pigment Paint - Pink Slip"),
    ::anno::description("A clearcoated metallic effect pigment paint with an orange peel effect."),
    ::anno::author("NVIDIA Corporation"),
	::anno::created(2020, 3, 17, ""),
    ::anno::key_words(string[]("design", "paint", "metallic", "flipflop", "carpaint", "automotive", "peel", "orange peel", "flake", "flakes", "multicolor", "clearcoat", "coated", "new", "gold", "pink", "orange", "warm")),
	::anno::thumbnail("./.thumbs/Effect_Pigment_Metallic.Chameleon_Pigment_Pink_Slip.png"),
    ::anno::copyright_notice(COPYRIGHT)
]] 
 = Effect_Pigment_Metallic(
	base_color:				color(0.511398f, 0.019918f, 0.067725f),
	flakes_coverage: 		1.0f,
	flakes_scale:			0.02f,
	flakes_orientation_random: 0.663f,
	flakes_roughness: 		0.383f,
	flakes_transparency:	0.05f,
	clearcoat_roughness:	0.0f,
	orange_peel_amount:		0.025f,
	orange_peel_scale:		0.08f,
	clearcoat_ior: 			1.45f,
	flakes_paint_color_1: color(0.409826f,	0.008373f,	0.154152f),
	flakes_paint_color_2: color(0.302125f,	0.009021f,	0.108711f),
	flakes_paint_color_3: color(0.612066f,	0.080219f,	0.010398f),
	flakes_paint_color_4: color(0.645555f,	0.638779f,	0.011126f),
	flakes_paint_color_5: color(0.404541f,	0.404541f,	0.009021f)	
);


export material Chameleon_Pigment_Aqua_Racer(*)
[[
    ::anno::display_name("Effect Pigment Paint - Aqua Racer"),
    ::anno::description("A clearcoated metallic effect pigment paint with an orange peel effect."),
    ::anno::author("NVIDIA Corporation"),
	::anno::created(2020, 3, 17, ""),
    ::anno::key_words(string[]("design", "paint", "metallic", "flipflop", "carpaint", "automotive", "peel", "orange peel", "flake", "flakes", "multicolor", "clearcoat", "coated", "new", "green", "blue", "cool")),
	::anno::thumbnail("./.thumbs/Effect_Pigment_Metallic.Chameleon_Pigment_Aqua_Racer.png"),
    ::anno::copyright_notice(COPYRIGHT)
]]
 = Effect_Pigment_Metallic(
	base_color: 			color(0.511398f, 0.019918f, 0.067725),
	flakes_coverage: 		1.0f,
	flakes_scale:			0.02f,
	flakes_orientation_random: 0.663f,
	flakes_roughness: 		0.383f,
	flakes_transparency:	0.0f,
	clearcoat_roughness:	0.0f,
	orange_peel_amount:		0.025f,
	orange_peel_scale:		0.08f,
	clearcoat_ior:			1.45f,
	flakes_paint_color_1: color(0.173439f,	0.409826f,	0.031551f),
	flakes_paint_color_2: color(0.031551f,	0.302125f,	0.009021f),
	flakes_paint_color_3: color(0.035614f,	0.612066f,	0.271577f),
	flakes_paint_color_4: color(0.042987f,	0.481952f,	0.645555f),
	flakes_paint_color_5: color(0.000367f,	0.160444f,	0.170138f)	
);


export material Chameleon_Pigment_Golden_Green(*)
[[
    ::anno::display_name("Effect Pigment Paint - Golden Green"),
    ::anno::description("A clearcoated metallic effect pigment paint with an orange peel effect."),
    ::anno::author("NVIDIA Corporation"),
	::anno::created(2020, 3, 17, ""),
    ::anno::key_words(string[]("design", "paint", "metallic", "flipflop", "carpaint", "automotive", "peel", "orange peel", "flake", "flakes", "multicolor", "clearcoat", "coated", "new", "green", "gold")),
	::anno::thumbnail("./.thumbs/Effect_Pigment_Metallic.Chameleon_Pigment_Golden_Green.png"),
    ::anno::copyright_notice(COPYRIGHT)
]] = Effect_Pigment_Metallic(
	base_color:				color(0.511398f, 0.019918f,	0.067725f),
	flakes_coverage:		1.0f,
	flakes_scale:			0.02f,
	flakes_orientation_random: 0.663f,
	flakes_roughness:		0.383f,
	flakes_transparency:	0.0f,
	clearcoat_roughness:	0.0f,
	orange_peel_amount:		0.025f,
	orange_peel_scale:		0.08f,
	clearcoat_ior:			1.45f,
	flakes_paint_color_1: color(0.573159f,	0.348865f,	0.013473f),
	flakes_paint_color_2: color(0.470440f,	0.344026f,	0.013473f),
	flakes_paint_color_3: color(0.103634f,	0.246800f,	0.020951f),
	flakes_paint_color_4: color(0.058187f,	0.157281f,	0.007751f),
	flakes_paint_color_5: color(0.024223f,	0.101145f,	0.003697f)	
);